Miscellany

on ^*:TEXT:*:#: {
  if ($nick == *savebuff) {
    var %nick = $gettok($2,1,$asc(!))
    if ($3 == MODE)     echo $color(mode) # $asctime($1, $timestampfmt) * %nick sets mode: $4-
    elseif ($3 == JOIN) echo $color(join) # $asctime($1, $timestampfmt) * %nick ( $+ $gettok($2,2,$asc(!)) $+ ) has joined #
    elseif ($3 == QUIT) echo $color(quit) # $asctime($1, $timestampfmt) * %nick ( $+ $gettok($2,2,$asc(!)) $+ ) Quit ( $+ $4- $+ )
    elseif ($3 == PART) echo $color(part) # $asctime($1, $timestampfmt) * %nick ( $+ $gettok($2,2,$asc(!)) $+ ) has left #
    elseif ($3 == NICK) echo $color(nick) # $asctime($1, $timestampfmt) * %nick is now known as $4
    elseif ($3 == KICK) echo $color(kick) # $asctime($1, $timestampfmt) $2 was kicked by %nick ( $+ $5- $+ )
    else                echo 4 # *** UNHANDLED LINE <12 $+ $1- $+ >
    halt
  }
  elseif ($nick == ***) {
    if ($1- === Buffer Playback...) {
      set %temp.buffer. [ $+ # ] playback
      timestamp off #
    } 
    else {
      unset %temp.buffer. [ $+ # ]
      timestamp on #
    }
    echo $color(notice) # *** $1-
    halt
  } 
  elseif (%temp.buffer. [ $+ # ] === playback) {
    echo -l # $1 < $+ $nick $+ > $2-
    halt
  }
}

on ^*:ACTION:*:#: {
  if (%temp.buffer. [ $+ # ] === playback) {
    echo $color(action) -l # $1  * $nick $2-
    halt
  }
}