Miscellany

dialog qmd {
  title "Query Manager"
  size -1 -1 248 73
  option dbu
  box "Query From", 1, 2 1 59 23
  edit "", 2, 6 10 50 9, read autohs
  box "Date/Time Of Query", 3, 63 1 59 23
  edit "", 4, 67 10 50 9, read autohs
  box "Blocked Users", 5, 124 1 70 23
  combo 6, 129 10 50 27, drop
  button "R", 7, 181 10 9 9, flat
  box "Query Message And Functions", 8, 2 25 192 46
  edit "", 9, 6 36 183 20, read multi hsbar
  button "Accept", 10, 6 58 30 10, flat
  button "Deny", 11, 56 58 30 10, flat
  button "Block", 12, 107 58 30 10, flat
  button "UnBlock", 13, 158 58 30 10, flat
  box "Manager On/Off", 14, 196 1 50 34
  check "Manager On", 15, 199 10 41 9
  check "Manager Off", 16, 199 22 41 9
  box "AwayLog On/Off", 17, 196 36 50 35
  check "AwayLog On", 18, 199 45 41 9
  check "AwayLog Off", 19, 199 57 43 9
}
;($dialog(qmd)) {;
alias qmd { dialog $iif($dialog(qmd),-v,-md) qmd qmd }
menu menubar,channel {
  .Query Manager { qmd }  
}
on *:dialog:qmd:init:0:{
  if (%qmd) { did -c qmd 15 }
  if (!%qmd) { did -c qmd 16 }
  if (%p2plogger) { did -c qmd 18 }
  if (!%p2plogger) { did -c qmd 19 }
  if (!$did(2)) { did -b qmd 10-12 }
  if (!$read(queryblock.txt)) { 
    did -ra qmd 6 List Is Empty 
    did -b qmd 13 
  } 
  elseif ($read(queryblock.txt)) { 
    did -e qmd 13
    var %x = 1
    while ( %x <= $lines(queryblock.txt)) {
      did -ra qmd 6 $read(queryblock.txt,%x)
      inc %x
    }
  }
}
on *:dialog:qmd:sclick:*:{
  if ($did == 19) { did -u qmd 18 | unset %p2plogger }
  if ($did == 18) { set %p2plogger on | unset %qmd | did -u qmd 19,15 | did -c qmd 16 }
  if ($did == 15) { set %qmd on | did -u qmd 16,18 | did -c qmd 19 | unset %p2plogger }
  if ($did == 16) { unset %qmd | did -u qmd 15 }
  if ($did == 10) { .msg $did(2).text 14,1[12,1»0,1::Ur P2P Has Been::12,1«14,1]14,1[12,1»0,1::Accepted::12,1«14,1] | .query $did(2).text | dialog -c qmd }
  if ($did == 11) { .msg $did(2).text 14,1[12,1»0,1::Sorry $did(2).text But Ur P2P Has Been::12,1«14,1]14,1[12,1»0,1::Denied::12,1«14,1] | .close -m $did(2).text | dialog -c qmd }
  if ($did == 12) { .write queryblock.txt $did(2).text | .msg $did(2).text 14,1[12,1»0,1::Sorry $did(2).text But U Have Been::12,1«14,1]14,1[12,1»0,1::Blocked::12,1«14,1] | .ignore -p $address($did(2).text,2) | .close -m $did(2).text | dialog -c qmd }
  if ($did == 13) {
    if (!$did(6).seltext) {
      noop $input(Please Select A Nick To UnBlock,uwo,Error) 
    }
    elseif ($did(6).seltext) {
      .ignore -r $address($did(6).seltext,2)
      var %dblocked $read(queryblock.txt,w,$did(6).seltext) 
      if (%dblocked == $did(6).seltext) { 
        write -dl [ $+ [ $readn ] ] queryblock.txt 
        did -d qmd 6 $did(6).seltext 
        noop $input($did(6).seltext Has Been Taken Off P2P Block,uwo,Query Manager)
        did -r qmd 6
        if (!$read(queryblock.txt)) {
          did -ra qmd 6 List Is Empty 
          did -b qmd 13
        }
        else {
          var %x = 1
          while ( %x <= $lines(queryblock.txt)) {
            did -a qmd 6 $read(queryblock.txt,%x)
            inc %x
          }
        }
      }
    }
  }
  if ($did == 7) {
    if (!$read(queryblock.txt)) { 
      did -ra qmd 6 List Is Empty 
      did -b qmd 13 
    }
    elseif ($read(queryblock.txt)) {
      did -e qmd 13
      did -r qmd 6
      var %x = 1
      while ( %x <= $lines(queryblock.txt)) {
        did -a qmd 6 $read(queryblock.txt,%x)
        inc %x
      }
    }
  }
}
on *:open:?:{
  if (%qmd) {
    var %anopenicks nickserv chanserv memoserv
    if ($istok(%anopenicks,$nick,32)) || ($dialog(qmd)) {
      halt
    }
    else {
      qmd
      window -h $nick
      .did -a qmd 2 $nick
      .did -a qmd 4 $time(mmm dd h:nn tt)
      .did -a qmd 9 $1-
      .did -e qmd 10-12
      .close -m $nick
      .msg $nick 14,1[12,1»0,1::You are currently speaking with::12,1«14,1]14,1[12,1»0,1:: $+ $me $+ ::12,1«14,1]
      .msg $nick 14,1[12,1»0,1::I currently have::12,1«14,1]14,1[12,1»0,1:: $+ $query(0) Querie $+ $iif($query(0) > 1,s) Open::12,1«14,1]
      .msg $nick 14,1[12,1»0,1::Please Wait To See If Ur p2p Will Be Accepted::12,1«14,1]
    }  
  }
}
on *:text:*:?:{
  if (%p2plogger) {
    var %anopenicks nickserv chanserv memoserv
    if ($istok(%anopenicks,$nick,32)) || ($dialog(qmd)) {
      halt
    }
    else {
      inc -u60 $+(%,p2pmessage,.,$nick)
      if ($($+(%,p2pmessage,.,$nick),2) = 1) {
        .msg $nick 14,1[12,1»0,1::Sorry Im currently Away::12,1«14,1]
        .msg $nick 14,1[12,1»0,1::But Please Leave A Short Message::12,1«14,1]
        .msg $nick 14,1[12,1»0,1::You Have 60 Seconds To Do So::12,1«14,1]14,1[12,1»0,1::Or The p2p Will Auto Close::12,1«14,1]
        window @AwayLogger
        aline @AwayLogger $nick p2p'ed you $time(mmm-d-yy @ h:nn tt) and said---------- $1-
        .timer 1 60 .close -m $nick
      }
      elseif ($($+(%,p2pmessage,.,$nick),2) = 2) {
        .msg $nick 14,1[12,1»0,1::Thank you For Leaving A Message::12,1«14,1]14,1[12,1»0,1::P2P Will Now Be Closed::12,1«14,1]
        window @AwayLogger
        aline @AwayLogger Message From $nick ---- $1-
        unset $+(%,p2pmessage,.,$nick)
        .close -m $nick
      }
    }
  }
}