cellkyborg

on *:text:.add *:#: {
  if (@ $+ $nick $+ @ isin %users.allow) {
    var %kom $2
    var %fkom $read(koms1.txt,s,$2)
    %fkom = $readn
    if (!%fkom) {
      write koms1.txt $2
      write all.txt $2
      msg $chan I sarasa ideta nauja komanda ( $+ $2 $+ ).
    }
    else  msg $chan Si komanda jau egzistuoja sarase 
  }
  else msg $nick Tau nesuteikta teise naudoti sia komanda
}

on *:text:.find *:#: {
  if (@ $+ $nick $+ @ isin %users.allow) {
    var %ff koms $+ $2 $+ .txt
    var %team1 $read(%ff)
    %team1 = $read(%ff,$readn)
    if (%team1 != $null) { write -dl $+ $readn %ff }
    var %team2 $read(%ff)
    %team2 = $read(%ff,$readn)
    if (%team2 != $null) { write -dl $+ $readn %ff }
    if ($2 isnum) && (%team1) && (%team2) && ($3-) {
      msg $chan Nauja kova tarp %team1 ir %team2
      writeini fights.ini %team1 vs %team2
      writeini fights.ini %team1 id $2
      writeini fights.ini %team1 time $3-
      writeini fights.ini %team2 vs %team1
      writeini fights.ini %team2 id $2
      writeini fights.ini %team2 time $3-
    }
    else { msg $nick Blogai ivesti duomenys | write %ff %team1 | write %ff %team2 }
  }
  else msg $nick Tau nesuteikta teise naudoti sia komanda
}

on *:text:.suzaide *:#: {
  if (@ $+ $nick $+ @ isin %users.allow) {
    var %rez1 $gettok($3,1,58)
    var %rez2 $gettok($3,2,58)
    if ($2 == $readini(fights.ini,$4,vs)) && ($4 == $readini(fights.ini,$2,vs)) && ($readini(fights.ini,$4,id)==$readini(fights.ini,$2,id)) && (%rez1 isnum) && (%rez2 isnum) {
      var %f.id $calc($readini(fights.ini,$4,id)+1)
      remini fights.ini $4
      remini fights.ini $2
      var %played $calc($readini(suzaistos.ini,$2,gm)+1)
      writeini suzaistos.ini $2 gm %played
      writeini suzaistos.ini $2 game $+ %played $2 $3 $4
      %played = $calc($readini(suzaistos.ini,$4,gm)+1)
      writeini suzaistos.ini $4 gm %played
      writeini suzaistos.ini $4 game $+ %played $2 $3 $4
      if ($champ(%f.id)) {
        msg $chan Sveikiname $iif(%rez1>%rez2,$2,$4) komanda, laimejusia si turnyra!!
        var %temp 1
        while (%temp <= %f.id) {
          remove koms $+ %temp $+ .txt
          inc %temp
        }
        remove all.txt
        remove fights.ini
        remove suzaistos.ini
      }
      else {
        if (%rez1 > %rez2) {
          write koms $+ %f.id $+ .txt $2
          msg $chan Laimejo $2 komanda! Ji patenka i %f.id etapa!
        }
        else {
          write koms $+ %f.id $+ .txt $4
          msg $chan Laimejo $4 komanda! Ji patenka i %f.id etapa!
        }
      }
    }
    else msg $chan Nesutampa duomenys! Patikrinkite ar viska gerai ivedete!
  }
  else msg $nick Tau nesuteikta teise naudoti sia komanda
}

on *:text:.komandos:#: {
  var %temp 1
  var %msg
  var %lin
  var %id 1
  while (%temp <= $lines(all.txt)) {
    %lin = $read(all.txt,%temp)
    if ($len(%msg) >= 400) {
      msg $chan $iif(%id == 1,Komandos: %msg,%msg)
      inc %id
      %msg = $null
    }
    else {
      %msg = $replace(%msg ,.,$chr(44)) %lin $+ .
    }
    inc %temp
  }
  if (%msg != $null) msg $chan $iif(%id == 1,Komandos: %msg,%msg)
}

on *:text:.suzaistos *:#: {
  var %temp 1
  var %gm $readini(suzaistos.ini,$2,gm)
  var %msg
  var %id 1
  var %lin
  while (%temp <= %gm) {
    %lin = $readini(suzaistos.ini,$2,game $+ %temp )
    if ($len(%msg) >= 400) {
      msg $chan $iif(%id == 1,Suzaista: %msg,%msg)
      inc %id
      %msg = $null
    }
    else {
      %msg = $replace(%msg ,.,$chr(44)) %lin $+ .
    }
    inc %temp
  }
  if (%msg != $null) { msg $chan $iif(%id == 1,Suzaista: %msg,%msg) }
  if (!%gm) msg $chan Si komanda dar nesuzaide jokiu rungtyniu arba nedalyvauja turnyre!
}


on *:text:.zais *:#: {
  var %msg $readini(fights.ini,$2,time)
  var %enem $readini(fights.ini,$2,vs)
  $iif(%msg,msg $chan $2 zais su %enem %msg,msg $chan Si komanda neegzistuoja kovu sarase arba kovos laikas nenustatytas)
}

on *:text:.zais:#: {
  var %temp 1
  var %lin
  var %team1
  var %team2
  var %time
  var %done @
  while (%temp <= $lines(fights.ini)) {
    %lin = $read(fights.ini,%temp)
    if ($left(%lin,1) == [) {
      %team1 = $mid(%lin,2,$calc($len(%lin)-2))
      echo -a team1 suteikta %team1
    }
    if ($left(%lin,3) == vs=) {
      %team2 = $remove(%lin,vs=)
      echo -a team2 suteikta %team2
    }
    if ($left(%lin,5) == time=) {
      %time = $remove(%lin,time=)
      if (@ $+ %team1 $+ @ !isin %done) && (@ $+ %team2 $+ @ !isin %done) {
        msg $chan %team1 kausis pries %team2 %time
        %done = %done $+ %team1 $+ @ $+ %team2 $+ @
      }
    }
    inc %temp
  }
}

on *:text:.reg *:#: {
  if (@ $+ $nick $+ @ isin %users.allow) {
    set %sock.team $gettok($2-,1,32)
    set %sock.chan $remove($gettok($2-,2,32),$chr(35))
    set %sock.plr1 $gettok($2-,3,32)
    set %sock.plr2 $gettok($2-,4,32)
    if (%sock.team) && (%sock.chan) && (%sock.plr1) && (%sock.plr2) {
      sockopen 2x2 texas.dtiltas.lt 80
    }
    else msg $chan Blogai ivesti duomenys!
  }
  else msg $nick Jums nesuteikta teise naudoti sia komanda!
}

on *:sockopen:2x2: {
  if ($sockerr) { echo -a Ivyko klaida! | return }
  else { 
    sockwrite -n $sockname GET /fwrite.php?team= $+ %sock.team $+ &chan= $+ %sock.chan $+ &plr1= $+ %sock.plr1 $+ &plr2= $+ %sock.plr2 HTTP/1.0
    sockwrite -n $sockname Accept: */*
    sockwrite -n $sockname Host: texas.dtiltas.lt
    sockwrite -n $sockname Connection: close
    sockwrite -n $sockname
  }
}


alias champ {
  var %tmp 1
  if ($lines(fights.ini) != 0) {
    return $false
    halt
  }
  while (%tmp <= $1) {
    if ($lines(koms $+ %tmp $+ .txt) != 0) {
      return $false
      halt
    }
    inc %tmp
  }
  return $true
}