Miscellany

on *:start: {
  hmake Addtrack 100
  if ($isfile(Addtrack.hsh)) hload Addtrack Addtrack.hsh
}
on *:exit: if ($hget(Addtrack)) hsave -o Addtrack Addtrack.hsh

#Addtrack on
on *:join:#: {
  if ($wildsite iswm $address($me,5)) return
  var %mask = $mask($fulladdress,3)
  if ($hget(Addtrack,%mask)) {
    var %usednicks = $ifmatch
    if (%usednicks != $nick) msg $chan 07 $nick 05has also used the nicks:07 $remtok(%usednicks,$nick,1,44)
    if (!$istok(%usednicks,$nick,44)) hadd Addtrack %mask $addtok(%usednicks,$nick,44)
    if ($numtok(%usednicks,44) > 10) hadd Addtrack %mask $deltok(%usednicks,1,44)
  }
  else {
    hadd Addtrack %mask $nick
  }
}
on *:nick: {
  if ($wildsite iswm $address($me,5)) return
  var %mask = $mask($fulladdress,3)
  if ($hget(Addtrack,%mask)) {
    var %usednicks = $ifmatch
    if (!$istok(%usednicks,$newnick,44)) hadd Addtrack %mask $addtok(%usednicks,$newnick,44)
    if ($numtok(%usednicks,44) > 10) hadd Addtrack %mask $deltok(%usednicks,1,44)
  }
  else {
    hadd Addtrack %mask $newnick
  }
}
alias nicks {
  if (*!*@* iswm $1) {
    if (!$hget(Addtrack,$1)) echo 4 -ta No entry found for $1
    else echo 10 -ta Address $1 has used the nicks: $hget(Addtrack,$1)
  }
  elseif (!$hget(Addtrack,$address($1,3))) echo 4 -ta No Entry found for $1
  elseif ($hget(Addtrack,$address($1,3)) != $1) {
    var %usednicks = $ifmatch
    echo 10 -ta $1 has also used the nicks $remtok(%usednicks,$1,1,43)
  }
  else echo 10 -ta $1 has not been seen on any other nicks
}
#addtrack end