Something

on *:start: {
  nicktracker
}
on ^*:join:#: {
  if (!$hget(join)) nicktracker
  hinc join $address($nick,2) $+ $chan $+ .num
  if ($hget(join,$address($nick,2) $+ $chan $+ .last)) echo 3 -t # * $nick ( $+ $address $+ ) has joined # $hget(join,$address($nick,2) $+ $chan $+ .num) times, Last as: $hget(join,$address($nick,2) $+ $chan) $duration($calc($ctime - $hget(join,$address($nick,2) $+ $chan $+ .last))) ago
  else echo 3 -t # * $nick ( $+ $address $+ ) has joined #
  hadd join $address($nick,2) $+ $chan $nick
  hadd join $address($nick,2) $+ $chan $+ .last $ctime
  var %a = 1,%n = 0,%b = 1
  while $hget(join,$address($nick,2) $+ .nicknum. $+ %a) {
    if ($v1 == $nick) %n = 1 
    inc %a
  }
  if (%n == 0) hadd join $address($nick,2) $+ .nicknum. $+ %a $nick
  while $nick(#,%b) {
    if ($nick(#,%b) != $nick) && ($address($nick(#,%b),2) == $address($nick,2)) echo # 4 $+ $nick(#,%b) is the clone of $nick $+ !
    inc %b
  }
  haltdef
}
on *:nick: {
  if (!$hget(join)) nicktracker
  var %a = 1,%n = 0
  while $hget(join,$address($newnick,2) $+ .nicknum. $+ %a) {
    if ($v1 == $newnick) %n = 1 
    inc %a
  }
  if (%n == 0) hadd join $address($newnick,2) $+ .nicknum. $+ %a $newnick
}
menu nicklist {
  Previous nicks:/nicks $$1
}
alias nicks {
  if (!$hget(join)) nicktracker
  if ($hget(join,$address($1,2) $+ .nicknum. $+ 1) == $null) { echo -a ***2 $1 has not been tracked. | halt }
  var %a = 1,%s
  while $hget(join,$address($1,2) $+ .nicknum. $+ %a) {
    %s = %s $v1
    inc %a
  }
  echo -a ***2 $1 has used the nicks:2 %s
}
alias nicktracker {
  hmake join 1000
  hload join join.hsh
  .timer 0 600 hsave join join.hsh
}