lovely lovely

;put into aliases
cap { return $upper($left($1-,1)) $+ $lower($right($1-,-1)) }

;put into remotes

alias thmhl {
  if ($1- != $null) {
    return 12(14 $+ $1- $+ 12)
  }
}

alias getcountry {
  if ($sock(getcountry)) { echo -ta 14there is another request running, please wait for it to finish before starting another one. }
  else {
    if ($ial($1)) { var %p = $gettok($v1,2,64),%d = $1 }
    elseif (. isin $1) { var %p = $1,%d = %p }
    else {
      echo -ta 14you entered a user who is not in your IAL! Please turn on the automatic filling of the IAL in the NoNameScript setup.
      return
    }
    if (*.users.quakenet.org iswm %p) || (*.user.gamesurge iswm %p) || (*.users.undernet.org iswm %p) {
      echo -ta 14the user has registered so you can not see his IP and are unable to resolve where he's coming from.
      return
    }
    echo -ta 14Looking up $thmhl(%d) $+ 14's country...
    set -u10 %getcountry %p
    sco getcountry nnscript.com 80
    .timergetcountry.timeout -io 1 6 getcountry.timeout
  }
}
alias getcountry.timeout {
  echo -ta 14an error occured while connecting to the server!
  sockclose getcountry
  unset %getcountry
}
on *:sockopen:getcountry:{
  if ($sockerr) || ($sock($sockname).status != active) { getcountry.timeout }
  else {
    sockwrite -n $sockname GET /lookup.php?ip= $+ %getcountry HTTP/1.0
    sockwrite -n $sockname Host: nnscript.com
    sockwrite -n $sockname User-Agent: Mozilla/5.0 (Windows; U; Windows NT 5.1; en-US; rv:1.6)
    sockwrite -n $sockname
  }
}
on *:sockread:getcountry:{
  var %g
  sockread %g
  while ($sockbr) {
    if ($regex(getc,%g,^([^ ]+)\x09(.+)$)) {
      .timergetcountry.timeout off
      sockclose $sockname
      if ($regml(getc,2) != UNKNOWN) { echo -ta 14Country lookup for $thmhl(%getcountry) $+ $iif($regml(getc,1) != %getcountry, $+ 14/12 $+ $thmhl($v1)) 14finished successfully: $thmhl($cap($regml(getc,2))) }
      else { echo -ta 14Country for $thmhl(%getcountry) $+ $iif($regml(getc,1) != %getcountry, $+ $thmhl($v1)) is unknown. }
      unset %getcountry
    }
    else { sockread %g }
  }
}