Someone

menu channel,status { 
  PM Accepter/Blocker: { pmd } 
} 
alias pmd { 
  dialog -m pmd pmd 
} 
dialog pmd { 
  title "PM Blocker" 
  size -1 -1 200 120 
  option dbu 
  box "PM Accepter" 1, 30 2 140 56 
  text "Received Message:" 2, 35 10 47 8 
  edit "PM Received - Please Wait...", 3, 83 9 80 8 
  text "Accept Message:" 4, 35 21 45 8 
  edit "[Accepted]" 5, 77 19 86 9 
  text "Decline Message:" 6, 35 32 46 8 
  edit "[Declined]" 7, 77 32 86 9 
  button "Turn ON" 8, 65 43 35 12 
  button "Turn OFF" 9, 100 43 35 12 
  box "PM Blocker" 10, 30 59 140 36 
  text "Block Message:" 11, 35 68 45 8 
  edit "I am [Blocking] all PMs" 12, 72 66 92 9 
  button "Block ALL ON" 13, 60 77 40 14 
  button "Block ALL OFF" 14, 100 77 40 14 
  box "Status" 15, 45 95 110 20 
  text "Status:" 16, 50 103 20 8 
  text "" 17, 70 103 80 9 
} 
on *:DIALOG:pmd:init:0: { 
  if (%accept != on || %blocker != on) { 
    did -r $dname 17 
    did -a $dname 17 PM Accepter/Blocker is DISABLED 
  } 
  if (%accept == on) { 
    did -r $dname 17 
    did -a $dname 17 PM Accepter is ENABLED 
  } 
  if (%blocker == on) { 
    did -r $dname 17 
    did -a $dname 17 PM Blocker is ENABLED 
  } 
} 
on *:DIALOG:pmd:sclick:8: { 
  if (%accept != on && %blocker != on) { 
    set %received $did(3) 
    set %accepted $did(5) 
    set %declined $did(7) 
    set %accept on 
    echo -at PM Accepter is now 12ON 
    dialog -x pmd 
  } 
  elseif (%accept == on || %blocker == on) { 
    did -a $dname 17 PM Accept/Blocker is already ON 
  } 
} 
on *:DIALOG:pmd:sclick:9: { 
  if (%accept == on) { 
    unset %accept 
    unset %received 
    unset %accepted 
    unset %declined 
    echo -at PM Accepter is now 12OFF 
    dialog -x pmd 
  } 
  else { 
    did -a $dname 17 PM Accepter is DISABLED 
  } 
} 
on *:DIALOG:pmd:sclick:13: { 
  if (%accept != on && %blocker != on) { 
    set %blocked $did(12) 
    set %blocker on 
    echo -at PM Blocker is now 12ON 
    dialog -x pmd 
  } 
  elseif (%accept == on || %blocker == on) { 
    did -a $dname 17 PM Accept/Blocker is already ON 
  } 
} 
on *:DIALOG:pmd:sclick:14: { 
  if (%blocker == on) { 
    unset %blocker 
    unset %blocked 
    echo -at PM Blocker is now 12OFF 
    dialog -x pmd 
  } 
  else { 
    did -a $dname 17 PM Blocker is DISABLED 
  } 
} 
on *:OPEN:?: { 
  if (%accept == on) { 
    msg $nick %received 
    .timer 1 0 accepter $nick 
  } 
  if (%blocker == on) { 
    msg $nick %blocked 
    ignore -pu300 $nick 
    window -c $nick 
  } 
} 
alias accepter { 
  set %accepter $input(Accept query from $1 $+ ?,y) 
  answer $1 
} 
alias answer { 
  if (%accepter == $true) { 
    msg $1 %accepted 
    window -a $1 
  } 
  if (%accepter == $false) { 
    msg $1 %declined 
    ignore -pu300 $1 
    window -c $1 
  } 
  unset %accepter 
}