Miscellany

Alias GreetL { 
  if (!$hget(Greet)) { 
    hmake Greet 
  } 
  if ($exists(Greet.txt)) { 
    hload Greet Greet.txt 
  } 
} 
Alias GreetS { 
  hsave Greet Greet.txt 
} 
ON *:START:{ GreetL } 
ON *:EXIT:{ GreetS } 
ON $*:TEXT:/^[!@.](Set|Add)Greet/i:#:{ 
  if (!$2) { 
    hdel Greet $+($network,:,$wildsite) 
    notice $nick Greet Unset 
  } 
  else { 
    hadd Greet $+($network,:,$wildsite) $remove($2-,$) 
    notice $nick Greet Saved to $qt($remove($2-,$)) $+([,$wildsite,]) 
  } 
} 
ON $*:TEXT:/^[!@.](Del|Rem)Greet/i:#:{ 
  if (!$hget(Greet,$+($network,:,$wildsite))) { 
    notice $nick No greet to delete! 
  } 
  else { 
    hdel Greet $+($network,:,$wildsite) 
    notice $nick Greet Deleted $+([,$wildsite,]) 
  } 
} 
ON $*:TEXT:/^[!@.]Greet/i:#:{ 
  if ($2 && $address($2,2) == $null) { 
    notice $nick I do not know who $2 is. 
  } 
  elseif (!$hget(Greet,$+($network,:,$iif($2,$address($2,2),$wildsite)))) { 
    notice $nick No greet for $iif($2,$2,you) 
  } 
  else { 
    notice $nick $+([,$iif($2,$2,$nick),]) $hget(Greet,$+($network,:,$iif($2,$address($2,2),$wildsite))) 
  } 
} 
ON *:JOIN:#:{ 
  if ($hget(Greet,$+($chan,:,$network)) || $nick == $me) { halt } 
  elseif (!$hget(Greet,$+($network,:,$wildsite))) { 
    notice $nick You don't have a saved greet! Syntax: !SetGreet <Greet Here> 
  } 
  else { 
    msg $chan $+([,$nick,]) $hget(Greet,$+($network,:,$wildsite)) 
  } 
} 
ON $*:TEXT:/^[!@.]Greets ?Off/i:#:{ 
  if ($nick isop $chan || $nick ishop $chan) { 
    hadd Greet $+($chan,:,$network) OFF 
    notice $nick Greets for $chan are now OFF 
  } 
} 
ON $*:TEXT:/^[!@.]Greets ?On/i:#:{ 
  if ($nick isop $chan || $nick ishop $chan) { 
    hdel Greet $+($chan,:,$network) 
    notice $nick Greets for $chan are now ON 
  } 
}