Something

STARTUP(fredtool.o)
ENTRY(fredtool_entry)

MEMORY
{
    ram : ORIGIN = 0xB0002000, LENGTH = 0x0080000
    rom : ORIGIN = 0xA0020000, LENGTH = 0x0020000
}

SECTIONS
{
    .debug_aranges 0 : { *(.debug_aranges) } 
    .debug_pubnames 0 : { *(.debug_pubnames) } 
    .debug_info 0 : { *(.debug_info) } 
    .debug_abbrev 0 : { *(.debug_abbrev) } 
    .debug_line 0 : { *(.debug_line) } 
    .debug_frame 0 : { *(.debug_frame) } 
    .debug_str 0 : { *(.debug_str) } 
    .debug_loc 0 : { *(.debug_loc) } 
    .debug_macinfo 0 : { *(.debug_macinfo) } 

    .note.arm.ident 0 : { KEEP (*(.note.arm.ident)) }
    .rom_vectors 0xA0020000 : { __rom_vectors_vma = ABSOLUTE(.); . = .; KEEP (*(.vectors)) } > rom
     __rom_vectors_lma = LOADADDR(.rom_vectors);
     
    .fredtool_entry 0xA0021020 : { fredtool.o . = .; KEEP (*(.fredtool_entry)) } > rom

    .text ALIGN (0x4) : { 
	_stext = ABSOLUTE(.); 
	PROVIDE (__stext = ABSOLUTE(.)); 
	*(.text*) *(.gnu.warning) *(.gnu.linkonce.t.*) *(.init) *(.glue_7) *(.glue_7t) 
	} > rom 

    _etext = .; PROVIDE (__etext = .);

    .rel.text : { *(.rel.text) *(.rel.text.*) *(.rel.gnu.linkonce.t*) } > rom
    .rela.text : { *(.rela.text) *(.rela.text.*) *(.rela.gnu.linkonce.t*) } > rom
    .rel.data : { *(.rel.data) *(.rel.data.*) *(.rel.gnu.linkonce.d*) } > rom
    .rela.data : { *(.rela.data) *(.rela.data.*) *(.rela.gnu.linkonce.d*) } > rom
    .rel.rodata : { *(.rel.rodata) *(.rel.rodata.*) *(.rel.gnu.linkonce.r*) } > rom
    .rela.rodata : { *(.rela.rodata) *(.rela.rodata.*) *(.rela.gnu.linkonce.r*) } > rom
    .rel.got : { *(.rel.got) } > rom .rela.got : { *(.rela.got) } > rom
    .rel.ctors : { *(.rel.ctors) } > rom .rela.ctors : { *(.rela.ctors) } > rom
    .rel.dtors : { *(.rel.dtors) } > rom .rela.dtors : { *(.rela.dtors) } > rom
    .rel.init : { *(.rel.init) } > rom .rela.init : { *(.rela.init) } > rom
    .rel.fini : { *(.rel.fini) } > rom .rela.fini : { *(.rela.fini) } > rom
    .rel.bss : { *(.rel.bss) } > rom .rela.bss : { *(.rela.bss) } > rom
    .rel.plt : { *(.rel.plt) } > rom .rela.plt : { *(.rela.plt) } > rom
    .rel.dyn : { *(.rel.dyn) } > rom
    .fini ALIGN (0x4) : { . = .; *(.fini) } > rom
    .rodata ALIGN (0x4) : { . = .; *(.rodata*) *(.gnu.linkonce.r.*) } > rom
    .rodata1 ALIGN (0x4) : { . = .; *(.rodata1) } > rom

    .got ALIGN (0x4) : { 
	. = .; 
	*(.got.plt) *(.got) _GOT1_START_ = ABSOLUTE (.); 
	*(.got1) _GOT1_END_ = ABSOLUTE (.);
	_GOT2_START_ = ABSOLUTE (.);
	*(.got2) _GOT2_END_ = ABSOLUTE (.);
     } > rom
    
    .fixup ALIGN (0x4) : { . = .; *(.fixup) } > rom
    .gcc_except_table ALIGN (0x4) : { . = .; KEEP(*(.gcc_except_table)) *(.gcc_except_table.*) } > rom
    .eh_frame ALIGN (0x4) : { . = .; __EH_FRAME_BEGIN__ = .; KEEP(*(.eh_frame)) __FRAME_END__ = .; . = . + 8; } > rom = 0
    
    .data : AT ((LOADADDR (.eh_frame) + SIZEOF (.eh_frame) + 4 - 1) & ~ (4 - 1)) { 
	__ram_data_start = ABSOLUTE (.); 
	*(.data*) *(.data1) *(.gnu.linkonce.d.*) . = ALIGN (4); KEEP(*( SORT (.ecos.table.*))) ;
	. = ALIGN (4); __CTOR_LIST__ = ABSOLUTE (.); 
	KEEP (*(SORT (.ctors*))) __CTOR_END__ = ABSOLUTE (.); 
	__DTOR_LIST__ = ABSOLUTE (.); 
	KEEP (*(SORT (.dtors*))) __DTOR_END__ = ABSOLUTE (.); 
	*(.dynamic) *(.sdata*) *(.gnu.linkonce.s.*) . = ALIGN (4); *(.2ram.*) 
     } > ram

     __rom_data_start = LOADADDR (.data); __ram_data_end = .; 
     PROVIDE (__ram_data_end = .);
     _edata = .; 
     PROVIDE (edata = .); 
     PROVIDE (__rom_data_end = LOADADDR (.data) + SIZEOF(.data));

    .bss ALIGN (0x4) : { 
	__bss_start = ABSOLUTE (.);
	*(.scommon) *(.dynsbss) *(.sbss*) *(.gnu.linkonce.sb.*) *(.dynbss) *(.bss*) *(.gnu.linkonce.b.*) *(COMMON) __bss_end = ABSOLUTE (.);
    } > ram

    __heap1 = ALIGN (0x8);

    . = ALIGN(4); _end = .; PROVIDE (end = .);
}