rendered paste bodyon *:input:*:{
if ($left($1,1) isin /~) {
var %type = $right($1,-1), %goal = $iif($left($2,1) == $chr(35) && $right($2,-1) isnum 1-99,$right($2,-1)), %rsn = $iif(%goal,$3-,$2-)
if (?stats iswm $1 || $setskill(%type) || $regex(%type,/^c(mb|ombat)$/Si)) {
set %stats.rsn $iif(%rsn,$v1,$iif(%defname,$v1,$$?="What is your rsn?"))
set %stats.type $iif($setskill(%type),single,$iif($regex(%type,/^c(mb|ombat)$/Si),cmb,all))
set %stats.goal %goal
set %stats.style $iif($left($1,1) == $chr(47),echo -at,msg $target)
$iif(!%defname && %stats.rsn,set %defname %stats.rsn)
$iif($setskill(%type),set %stats.num $setskill($v1).num)
sockopen stats hiscore.runescape.com 80
halt
}
}
}
on *:sockopen:stats:{
sockwrite -nt $sockname GET $+(/index_lite.ws?player=,%stats.rsn) HTTP/1.1
sockwrite -nt $sockname Host: hiscore.runescape.com
sockwrite -nt $sockname $crlf
%id = 1
}
on *:sockread:stats:{
if ($sockerr) halt
else {
var %sockreader
sockread %sockreader
tokenize 44 %sockreader
if (*404 Not found iswm %sockreader) {
%stats.style $c1(The nick) $c2(%stats.rsn) $c1(does not appear in the highscores for any skills.)
unset %stats.* %id
sockclose stats
halt
}
else {
if (%id isnum 12-35) {
var %ranked = $iif($1 > 0,$true), %goal = $iif(%stats.goal && %stats.goal > $calc($2 + 1),$v1,$calc($2 + 1)), %next = $iif(%id != 12 && $2 isnum 1-98,$true)
if (%stats.type == all) {
%stats.intro = $c1(Stats for) $+($c2(%stats.rsn),$c1(:))
%stats.stats = %stats.stats $iif(%ranked,$c1($setskill(%id)) $c2($bytes($2,b)))
}
if (%stats.type == single) && (%id == %stats.num) {
if (%ranked) {
%stats.intro = $c2($setskill(%stats.num)) $c1(stats for) $+($c2(%stats.rsn),$c1(:))
%stats.stats = $c1(Rank:) $c2($bytes($1,b)) $c1(Level:) $c2($bytes($2,b)) $c1(Exp:) $c2($bytes($3,b)) $iif(%next,$c1(Exp to lvl) $+($c2(%goal),$c1(:)) $c2($bytes($calc($xp(%goal) - $3),b)))
%stats.next = $iif(%next,$c1($+(,[,)) $c1(For level) $c2(%goal) $c1($+(,],)) $read(stats.txt,s,$setskill(%stats.num),1))
}
else {
%stats.intro = $c1(The nick) $c2(%stats.rsn) $c1(does not appear in the highscores for) $+($c2($setskill(%stats.num)),$c1(.))
}
}
if (%stats.type == cmb) {
if (%id isnum 13-19) {
set $+($(%stats.cmb.,0),$setskill(%id)) $abs($2)
}
if (%id == 19) {
var %a.mult = .32707, %s.mult = .324, %d.mult = .25, %h.mult = .25, %p.mult = .124, %r.mult = .487, %m.mult = .487
var %a = %stats.cmb.attack, $&
%s = %stats.cmb.strength, $&
%d = %stats.cmb.defence, $&
%h = %stats.cmb.hitpoints, $&
%r = %stats.cmb.ranged, $&
%m = %stats.cmb.magic, $&
%p = %stats.cmb.prayer
if ($calc(%a + %s + %d + %h + %r + %m + %p) == 7) {
%stats.style $c1(The nick) $c2(%stats.rsn) $c1(does not appear in the highscores for any combat skills)
unset %stats.* %id
sockclose stats
halt
}
var %meleecombat = $calc(%a * %a.mult + %s * %s.mult + %d * %d.mult + %h * %h.mult + %p * %p.mult), $&
%RangedCombat = $calc(%r * %r.mult + %p * %p.mult + %d * %d.mult + %h * %h.mult), $&
%MagicCombat = $calc(%m * %m.mult + %p * %p.mult + %d * %d.mult + %h * %h.mult)
if (%MagicCombat == %RangedCombat) && (%MeleeCombat == %RangedCombat) {
%stats.display $c1(The nick) $c2(%rsn) $c1(does not appear in the hiscores for any combat skills)
}
elseif (%MagicCombat > %RangedCombat) && (%MagicCombat > %MeleeCombat) var %cmbstyle = Magic, %Combat = %MagicCombat
elseif (%RangedCombat > %MeleeCombat) && (%RangedCombat > %MagicCombat) var %cmbstyle = Ranged, %Combat = %RangedCombat
else var %cmbstyle = melee, %combat = %MeleeCombat
var %cmb.temp = $abs($calc($int($calc(%combat +1)) - %combat)), $&
%a.2lvl = $ceil($calc(%cmb.temp / %a.mult)), %s.2lvl = $ceil($calc(%cmb.temp / %s.mult)), $&
%d.2lvl = $ceil($calc(%cmb.temp / %d.mult)), %m.2lvl = $ceil($calc(%cmb.temp / %m.mult)), $&
%r.2lvl = $ceil($calc(%cmb.temp / %r.mult)), %p.2lvl = $ceil($calc(%cmb.temp / %p.mult))
if (%cmbstyle == magic) var %dynamic.2lvl = $c1(Magic:) $c2(%m.2lvl)
elseif (%cmbstyle == Ranged) var %dynamic.2lvl = $c1(Ranged:) $c2(%r.2lvl)
else var %dynamic.2lvl = $c1(Att:) $c2(%a.2lvl) $c1(Str:) $c2(%s.2lvl)
var %combat = $round(%combat,2), %next = $ceil(%combat)
%stats.style $c2(%stats.rsn) $c1(is) $c2(%combat) $c1(%cmbstyle style combat)
%stats.style $c1(Attack:) $c2(%a) $c1(Defence:) $c2(%d) $c1(Strength:) $c2(%s) $c1(Hits:) $c2(%h) $&
$c1(Mage:) $c2(%m) $c1(Range:) $c2(%r) $c1(Pray:) $c2(%p)
$iif(%combat < 126,%stats.style $c1(Levels for) $c2(%next) $+ $c1(:) %dynamic.2lvl $&
$c1(Def/Hp:) $c2(%d.2lvl) $c1(Prayer:) $c2(%p.2lvl))
}
}
}
if (%id == 35) {
$iif(%stats.intro,%stats.style $v1)
$iif(%stats.stats,%stats.style $v1)
$iif(%stats.next,%stats.style $v1)
unset %stats.* %id
sockclose stats
halt
}
}
inc %id
}
}
alias setskill {
if ($1 == 12) || ($regex($1,/^(st|(skill)?total|overall)$/Si)) return $iif($prop,12,Overall)
elseif ($1 == 13) || ($regex($1,/^at(t|k|tack)$/Si)) return $iif($prop,13,Attack)
elseif ($1 == 14) || ($regex($1,/^def(en[cs]e)?$$/Si)) return $iif($prop,14,Defence)
elseif ($1 == 15) || ($regex($1,/^str(ength)?$/Si)) return $iif($prop,15,Strength)
elseif ($1 == 16) || ($regex($1,/^h(p|it(s|points?))$/Si)) return $iif($prop,16,Hitpoints)
elseif ($1 == 17) || ($regex($1,/^rang(e(d?)|ing)$/Si)) return $iif($prop,17,Ranged)
elseif ($1 == 18) || ($regex($1,/^pray(er)?$$/Si)) return $iif($prop,18,Prayer)
elseif ($1 == 19) || ($regex($1,/^mag(e|ic)$$/Si)) return $iif($prop,19,Magic)
elseif ($1 == 20) || ($regex($1,/^cook(ing)?$/Si)) return $iif($prop,20,Cooking)
elseif ($1 == 21) || ($regex($1,/^w(c|ood(cut(ting)?))$/Si)) return $iif($prop,21,Woodcutting)
elseif ($1 == 22) || ($regex($1,/^fletch(ing)?$/Si)) return $iif($prop,22,Fletching)
elseif ($1 == 23) || ($regex($1,/^fish(ing)?$/Si)) return $iif($prop,23,Fishing)
elseif ($1 == 24) || ($regex($1,/^f(m|iremak(e|ing))$/Si)) return $iif($prop,24,Firemaking)
elseif ($1 == 25) || ($regex($1,/^craft(ing)?$/Si)) return $iif($prop,25,Crafting)
elseif ($1 == 26) || ($regex($1,/^(smith|smelt)(ing)?$/Si)) return $iif($prop,26,Smithing)
elseif ($1 == 27) || ($regex($1,/^min(e|ing)$/Si)) return $iif($prop,27,Mining)
elseif ($1 == 28) || ($regex($1,/^herb(law|lore)?$/Si)) return $iif($prop,28,Herblore)
elseif ($1 == 29) || ($regex($1,/^agil(ity)?$/Si)) return $iif($prop,29,Agility)
elseif ($1 == 30) || ($regex($1,/^(thie(f|v(e|ing)))$/Si)) return $iif($prop,30,Thieving)
elseif ($1 == 31) || ($regex($1,/^slay(er|ing)?$/Si)) return $iif($prop,31,Slayer)
elseif ($1 == 32) || ($regex($1,/^farm(er|ing)?$/Si)) return $iif($prop,32,Farming)
elseif ($1 == 33) || ($regex($1,/^(rc|runecraft)(ing)?$/Si)) return $iif($prop,33,Runecraft)
elseif ($1 == 34) || ($regex($1,/^hunt(er|ing)?$/Si)) return $iif($prop,34,Hunter)
elseif ($1 == 35) || ($regex($1,/^con(struct(ion|ing))?$/Si)) return $iif($prop,35,Construction)
}
alias xp return $gettok(0 83 174 276 388 512 650 801 969 1154 1358 1584 1833 2107 2411 2746 3115 3523 3973 4470 5018 5624 6291 7028 7842 8740 9730 10824 12031 13363 14833 16456 18247 20224 22406 24815 27473 30408 33648 37224 41171 45529 50339 55649 61512 67983 75127 83014 91721 101333 111945 123660 136594 150872 166636 184040 203254 224466 247886 273742 302288 333804 368599 407015 449428 496254 547953 605032 668051 737627 814445 899257 992895 1096278 1210421 1336443 1475581 1629200 1798808 1986068 2192818 2421087 2673114 2951373 3258594 3597792 3972294 4385776 4842295 5346332 5902831 6517253 7195629 7944614 8771558 9684577 10692629 11805606 13034431,$1,32)
alias c1 return $+(14,$1-,)
alias c2 return $+(03,$1-,)