Untitled

on $*:TEXT:/^[!@]clan/Si:#:{
  var %sname = $+(clans,.,$ticks)
  if ($2) {
    hadd -m %sname name $replace($2-,$chr(32),+,_,+,-,+)
    hadd -m %sname disp $iif($left($1,1) == !,.notice $nick,msg $chan)
  }
  else {
    hadd -m %sname name $nick
    hadd -m %sname disp $iif($left($1,1) == !,.notice $nick,msg $chan)
  }
  sockopen %sname www.runehead.com 80
}
on *:SOCKOPEN:clans.*:{
  sockwrite -nt $sockname GET /clans/search.php?search= $+ $hget($sockname,name) $+ &searchtype=exact HTTP/1.1
  sockwrite -nt $sockname HOST: www.runehead.com
  sockwrite -nt $sockname $crlf
}
on *:SOCKREAD:clans.*:{
  var %read | sockread -f %read
  if ($htmlfree(%read) == $replace($hget($sockname,name),+,$chr(32),-,$chr(32),_,$chr(32))) {
    sockread -f %read
    var %rdy = $hget($sockname,line) $iif($hget($sockname,line),~,Clans:) $replace($hget($sockname,name),+,$chr(32),-,$chr(32),_,$chr(32)) Is In $htmlfree(%read)
    hdel $sockname line
    hadd -m $sockname line %rdy
  }    
  if (returned isin %read) {
    $hget($sockname,disp) clan results for $replace($hget($sockname,name),+,$chr(32),-,$chr(32),_,$chr(32)) $+ : $count($hget($sockname,line),$replace($hget($sockname,name),+,$chr(32),-,$chr(32),_,$chr(32)))
    $hget($sockname,disp) $hget($sockname,line)
    hfree $sockname
    sockclose $sockname
  }
  if (*http://validator.w3.org/check?uri=referer* iswm %read) {
    $hget($sockname,disp) I could not find $replace($hget($sockname,name),+,$chr(32),-,$chr(32),_,$chr(32)) in any clan on www.runehead.com
    hfree $sockname
    sockclose $sockname
  }
}
alias -l htmlfree { 
  var %x, %i = $regsub($1-,/(^[^<]*>|<[^>]*>|<[^>]*$)/g,$null,%x), %x = $remove(%x,&nbsp;) 
  return %x 
}