Untitled

menu Nicklist {
  -
  owwScript
  $iif((($me isop $chan) || ($me ishop $chan)) && ($1 != $null),Control):dialog -m os_control os_control
  -
}

dialog os_control {
  title $snick($active,1)
  size -1 -1 213 113
  option dbu
  tab "Kicks", 1, 2 2 209 92
  box "Kick", 4, 5 21 100 57, tab 1
  box "Ban", 5, 108 21 100 57, tab 1
  check "Kick User", 6, 9 33 50 10, tab 1
  edit "", 7, 9 64 92 10, tab 1 autohs
  text "Message:", 8, 9 55 25 8, tab 1
  check "Ban", 9, 112 33 44 10, tab 1
  check "Timed ban", 10, 112 45 44 10, tab 1
  edit "", 11, 112 64 92 10, tab 1 limit 2
  text "Time (in minutes):", 12, 112 55 46 8, tab 1
  button "Ok", 13, 60 80 45 12, tab 1
  button "Cancel", 14, 108 80 45 12, tab 1
  check "Gag", 35, 157 33 48 10, tab 1
  check "Un-gag", 36, 157 45 48 10, tab 1
  tab "Modes", 2
  check "Op", 15, 58 28 43 10, tab 2
  check "De-op", 16, 58 39 43 10, tab 2
  check "Halfop", 17, 110 28 43 10, tab 2
  check "De-halfop", 18, 110 39 43 10, tab 2
  check "Voice", 19, 162 28 43 10, tab 2
  check "De-voice", 20, 162 39 43 10, tab 2
  button "Ok", 21, 60 80 45 12, tab 2
  button "Cancel", 22, 108 80 45 12, tab 2
  check "Add all", 23, 6 63 43 10, tab 2
  check "Remove all", 24, 6 74 43 10, tab 2
  box "Mass", 31, 4 54 50 32, tab 2
  box "Op", 26, 56 20 50 32, tab 2
  box "Halfop", 27, 108 20 50 32, tab 2
  box "Voice", 28, 160 20 50 32, tab 2
  box "Except", 32, 4 20 50 32, tab 2
  check "Except", 33, 6 29 43 10, tab 2
  check "Un-except", 34, 6 40 43 10, tab 2
  button "Change Name", 25, 60 98 93 12
}

on *:dialog:os_control:*:*:{
  if ($devent == init) {
    set %os.control.nick $snick($active,1)
    set %os.control.chan $active
    did -m $dname 7,11
    dialog -t $dname Options for $snick($active,1)
  }
  if ($devent == sclick) {
    if ($did == 25) {
      set %os.control.nick $snick($active,1)
      set %os.control.chan $active
      dialog -t $dname Options for $snick($active,1)
    }
    ;--------------------
    ;--------Tab1--------
    ;--------------------
    {
      ;--------------------
      ;-----Checkboxes-----
      ;--------------------
      if ($did == 6) did $iif($did(6).state == 1,-n,-m) $dname 7
      if ($did == 9) {
        did -u $dname 10,35,36
        did -m $dname 11
      }
      if ($did == 10) {
        did -u $dname 9,35,36
        did $iif($did(10).state == 1,-n,-m) $dname 11
      }
      if ($did == 35) {
        did -u $dname 9,10,36
        did -m $dname 11
      }
      if ($did == 36) {
        did -u $dname 9,10,35
        did -m $dname 11
      }
      ;--------------------
      ;------Buttons-------
      ;--------------------
      if ($did == 14) {
        dialog -x $dname
        unset %os.control.*
      }
      if ($did == 13) {
        if ($did(9).state == 1) mode %os.control.chan b $iif(.ipt.aol.com isin $address(%os.control.nick,2),$address(%os.control.nick,3),$address(%os.control.nick,2))
        if ($did(10).state == 1) ban -u $+ $calc($did(11)*60) %os.control.chan $iif(.ipt.aol.com isin $address(%os.control.nick,2),$address(%os.control.nick,3),$address(%os.control.nick,2))
        if ($did(35).state == 1) mode %os.control.chan b-v ~q: $+ $iif(.ipt.aol.com isin $address(%os.control.nick,2),$address(%os.control.nick,3),$address(%os.control.nick,2)) %os.control.nick
        if ($did(36).state == 1) mode %os.control.chan -b ~q: $+ $iif(.ipt.aol.com isin $address(%os.control.nick,2),$address(%os.control.nick,3),$address(%os.control.nick,2))
        if ($did(6).state == 1) kick %os.control.chan %os.control.nick $iif($did(7) == $&
          $null,$read(kickmessage.txt),$did(7)) $+ . $+ $iif($did(10).state == 1, $+ $&
          $chr(32) $+ Temp-ban for: $duration($calc($did(11)*60))) [12owwScript]
        dialog -x $dname
        unset %os.control.*        
      }
    }
    ;--------------------
    ;--------Tab2--------
    ;--------------------
    {
      ;--------------------
      ;-----Checkboxes-----
      ;--------------------
      if ($did == 33) did -u $dname 34,24,23
      if ($did == 34) did -u $dname 33,24,23
      if ($did == 15) did -u $dname 16,24,23
      if ($did == 16) did -u $dname 15,23,24
      if ($did == 17) did -u $dname 18,24,23
      if ($did == 18) did -u $dname 17,23,24
      if ($did == 19) did -u $dname 20,24,23
      if ($did == 20) did -u $dname 19,23,24
      if ($did == 23) {
        did $iif($did(23).state == 1,-c,-u) $dname 15,17,19,33
        did -u $dname 16,18,20,24,34
      }
      if ($did == 24) {
        did $iif($did(24).state == 1,-c,-u) $dname 16,18,20,34
        did -u $dname 15,17,19,23,33
      }
      ;--------------------
      ;------Buttons-------
      ;--------------------
      if ($did == 22) {
        dialog -x $dname
        unset %os.control.*
      }
      if ($did == 21) {
        mode %os.control.chan $&
          $iif($did(33).state == 1,+e) $+ $iif($did(34).state == 1,-e) $+ $&
          $iif($did(15).state == 1,+o) $+ $iif($did(16).state == 1,-o) $+ $&
          $iif($did(17).state == 1,+h) $+ $iif($did(18).state == 1,-h) $+ $&
          $iif($did(19).state == 1,+v) $+ $iif($did(20).state == 1,-v) $&
          $iif($did(33).state == 1 || $did(34).state == 1,$iif(.ipt.aol.com isin $address(%os.control.nick,2),$address(%os.control.nick,3),$address(%os.control.nick,2))) $&
          %os.control.nick %os.control.nick %os.control.nick
        dialog -x $dname
        unset %os.control.*
      }
    }
  }
  if ($devent == close) unset %os.control.*
}