Untitled

on *:PART:#:{
  if ((!$istok(#MightScript #MSCR #tdc,$chan,32)) && ($nick($chan,0) < 5) && ($nick != $me)) {
    part $chan You need at least 5 users to keep me in your channel!
  }
}
on *:QUIT:{
  var %c 1
  while ($comchan($nick,%c)) {
    if (!$istok(#MightScript #MSCR #tdc,$comchan($nick,%c),32) && ($nick($comchan($nick,%c),0) < 5) && ($nick != $me)) {
      part $comchan($nick,%c) You need at least 5 users to keep me in your channel!
    }
    inc %c
  }
}
on ^*:OPEN:?:{
  .ignore -pu60 $nick
  haltdef
  msg $nick $+($c1,[,$c2,Hello,$c1 $nick,$c2,! Please do not send me private messages in the future. If you need help,$chr(44) join,$c1 #MightScript,$c2,. My commands are located at,$c1,])
}
on *:INVITE:#:{
  msg #MSCR !invite $nick $chan
}

on *:CONNECT:{
  if ($scon(0) == 1) {
    nick [MAC]MightScript
    .timer 1 1 server -m irc.swiftirc.net
    .timer 1 3 scon 2 nick [NL]MightScript
    .timer 1 3 server -m irc.swiftirc.net
    .timer 1 5 scon 3 nick [MOO]MightScript
    .timer 1 7 scon -at1 join #MightScript,#MSCR,#bots
    .timer 1 7 scon -at1 ns id Patje`-DoucheBag
    .timer 1 7 scon -at1 mode $me +pB
  }
}

on *:sockopen:urban.*:{
  sockwrite -nt $sockname GET /define.php?term= $+ $hr($hget($sockname,lookup)) HTTP/1.1
  sockwrite -nt $sockname Host: www.urbandictionary.com
  sockwrite -nt $sockname $crlf
}
on *:sockread:urban.*:{
  var %urbread
  sockread %urbread
  if (*isn't defined* iswm %urbread) {
    $hget($sockname,sendway) $+($c1,[,$c2,No definition of,$c1 $flc($hget($sockname,lookup)) $c2,was found on $c1,urbandictionary.com])
    .hdel -sw $sockname *
    sockclose $sockname
  }
  if (*<p>* iswm %urbread) {
    hadd -m $sockname def $replace($htmlfree(%urbread),</p,$null,<br,$null,</ br,$null)
  }
  if (*<p style="font-style:* iswm %urbread) {
    $hget($sockname,sendway) $+($c1,[,$c2,Definition of,$c1 $flc($hget($sockname,lookup)),$c2,:,$c1 $hget($sockname,def),])
    $hget($sockname,sendway) $+($c1,[,$c2,Example:,$c1 $replace($gettok(%urbread,2,62),&quot;,",</p,$null,<br,$null,</ br,$null,/,$null),])
    .hdel -sw $sockname *
    sockclose $sockname
  }
}

on *:sockopen:price.*:{
  sockwrite -nt $sockname GET /priceguide.php?search_terms= $+ $hr($hget($sockname,lookup)) $+ &search_area=1&price_low=&price_high=&member=1 HTTP/1.1
  sockwrite -nt $sockname Host: www.zybez.net
  sockwrite -nt $sockname $crlf
}
on *:sockread:price.*:{
  var %priceread
  sockread %priceread
  if (*Your search did not* iswm %priceread) {
    $hget($sockname,sendway) $+($c1,[,$c2,Your search for,$c1 $flc($hget($sockname,lookup)) $c2,didn't return any results,$c1,])
    .hdel -sw $sockname *
    sockclose $sockname
  }
  if (*<!--name-->* iswm %priceread) {
    if ($hget($sockname,counter) != 10) {
      hadd -m $sockname counter $calc($hget($sockname,counter) + 1) 
      hadd -m $sockname name $htmlfree(%priceread)
      sockread %p2 | hadd -m $sockname out $hget($sockname,out) $+($c2,$hget($sockname,name),:,$c1 $htmlfree(%p2) |)
    }  
  }
  if (<!-- Search Results: End --> iswm %priceread) || ($hget($sockname,counter) == 10) {
    $hget($sockname,sendway) $+($c1,[,$c2,Results for,$c1 $flc($hget($sockname,lookup)),] [,$replace($left($hget($sockname,out),-2),$+($chr(44),000,$chr(44),000gp),m,$+($chr(44),000gp),k),])
    unset %p2
    .hdel -sw $sockname *
    sockclose $sockname
  }
}

on *:sockopen:clan.*:{
  sockwrite -nt $sockname GET /clans/search.php?search= $+ $hr($hget($sockname,lookup)) HTTP/1.1
  sockwrite -nt $sockname Host: runehead.com
  sockwrite -nt $sockname $crlf
}
on *:sockread:clan.*:{
  var %clanreader
  sockread %clanreader
  if (*No results were found* iswm %clanreader) {
    $hget($sockname,sendway) $+($c1,[,$c2,$flc($hget($sockname,lookup)),$c1 does not feature in the,$c2 Runehead.com Database,$c1,])
    .hdel -sw $sockname *    
    sockclose $sockname
  }
  if (*<td class='tableborder'><a href='ml.php?* iswm %clanreader) {
    hadd -m $sockname clan $hget($sockname,clan) $+($c2,$htmlfree(%clanreader),$c1 |)
  }
  if (*</table>* iswm %clanreader) {
    $hget($sockname,sendway) $+($c1,[,$c2,Clans for,$c1 $flc($hget($sockname,lookup)),] [,$left($hget($sockname,clan),-2),])
    .hdel -sw $sockname *
    sockclose $sockname
  }
}

on *:sockopen:google.*:{
  sockwrite -nt $sockname GET /search?hl=en&q= $+ $hr($hget($sockname,lookup)) HTTP/1.0
  sockwrite -nt $sockname Host: www.google.com
  sockwrite -nt $sockname $crlf
}
on *:sockread:google.*:{
  while ($sock($sockname).rq) {
    sockread &google
    bwrite $sockname -1 -1 &google
  }
  bread $sockname 0 $file($sockname).size &google
  if ($bfind(&google,1,</html>)) {
    if ($bfind(&google,1,did not match)) $hget($sockname,sendway) $+($c1,[,$c2,No results were found for,$c1 $flc($hget($sockname,lookup)),])
    else $hget($sockname,sendway) $+($c1,[,$c2,Link:,$c1 $bvar(&google,$calc($bfind(&google,1,<h2 class=r><a href=") + 21),$calc($bfind(&google,$calc($bfind(&google,1,<h2 class=r><a href=") + 21),34) - $calc($bfind(&google,1,<h2 class=r><a href=") + 21))).text |,$c2 Name:,$c1 $htmlfree($bvar(&google,$calc($bfind(&google,1,class=l>) + 8),$calc($bfind(&google,$calc($bfind(&google,1,class=l>) + 9),</a></h2>) - $calc($bfind(&google,1,class=l>) + 8))).text) |,$c2 Description:,$c1 $htmlfree($bvar(&google,$calc($bfind(&google,1,class="j">) + 24),$calc($bfind(&google,$calc($bfind(&google,1,class="j">) + 24),<br>) - $calc($bfind(&google,1,class="j">) + 24))).text),])
    .hdel -sw $sockname *
    .remove $sockname
    sockclose $sockname
  }
}

on *:SOCKOPEN:compare.*:{
  sockwrite -nt $sockname GET /aff/runescape/compare.ws?user1= $+ $hr($hget($sockname,user0)) $+ &user2= $+ $hr($hget($sockname,user1)) $+ &submit=Compare HTTP/1.0
  sockwrite -nt $sockname Host: $+(hiscore-web.runescape.com,$str($crlf,2))
}
on *:SOCKREAD:compare.*:{
  while ($sock($sockname).rq) {
    sockread &compare
    bwrite $sockname -1 -1 &compare
  }
  bread $sockname 0 $file($sockname).size &compare
  if ($bfind(&compare,1,</HTML>)) {
    if ($bfind(&compare,1,$hget($sockname,user0) does not feature)) hadd -m $sockname result0 User not ranked
    if ($bfind(&compare,1,$hget($sockname,user1) does not feature)) hadd -m $sockname result1 User not ranked
    if (($hget($sockname,result0) == user not ranked) && ($hget($sockname,result1) == user not ranked)) $hget($sockname,sendway) $+($c1,[,$c2,Both users are not ranked in the,$c1 RuneScape Highscores,$c1,])
    else {
      hadd -m $sockname pos $bfind(&compare,1,$hget($sockname,skill) $+ 1.gif"></td>)
      hadd -m $sockname result0 $iif($remove($gettok($htmlfree($replace($bvar(&compare,$hget($sockname,pos),300).text,$chr(10),$chr(32))),3-5,32),$chr(44),$chr(32)) !isnum,User not ranked,$gettok($htmlfree($replace($bvar(&compare,$hget($sockname,pos),300).text,$chr(10),$chr(32))),3-5,32))
      hadd -m $sockname result1 $iif($remove($gettok($htmlfree($replace($bvar(&compare,$bfind(&compare,$calc($hget($sockname,pos) + 10),$hget($sockname,skill) $+ 1.gif"></td>),300).text,$chr(10),$chr(32))),3-5,32),$chr(44),$chr(32)) !isnum,User not ranked,$gettok($htmlfree($replace($bvar(&compare,$bfind(&compare,$calc($hget($sockname,pos) + 10),$hget($sockname,skill) $+ 1.gif"></td>),300).text,$chr(10),$chr(32))),3-5,32))
      $hget($sockname,sendway) $+($c1,[,$c2,$flc($hget($sockname,skill)) for,$c1 $flc($hget($sockname,user0)),] [,$iif($hget($sockname,result0) == user not ranked,$+($c2,User,$c1 $hget($sockname,user0) $c2,not ranked),$+($c2,Level:,$c1 $gettok($v1,2,32) |,$c2 Rank:,$c1 $gettok($v1,1,32) |,$c2 Exp:,$c1 $gettok($v1,3,32))),$c1,])
      $hget($sockname,sendway) $+($c1,[,$c2,$flc($hget($sockname,skill)) for,$c1 $flc($hget($sockname,user1)),] [,$iif($hget($sockname,result1) == user not ranked,$+($c2,User,$c1 $hget($sockname,user1) $c2,not ranked),$+($c2,Level:,$c1 $gettok($v1,2,32) |,$c2 Rank:,$c1 $gettok($v1,1,32) |,$c2 Exp:,$c1 $gettok($v1,3,32))),$c1,])
      if (($remove($hget($sockname,result0),$chr(32)) isalpha) || ($remove($hget($sockname,result1),$chr(32)) isalpha)) hadd -m $sockname winner $iif($remove($hget($sockname,result0),$chr(32)) isalpha,1,0)
      else hadd -m $sockname winner $iif($remove($gettok($hget($sockname,result0),3,32),$chr(44)) > $remove($gettok($hget($sockname,result1),3,32),$chr(44)),0,1)
      $hget($sockname,sendway) $+($c1,[,$c2,Winner:,$c1 $flc($hget($sockname,user $+ $hget($sockname,winner))),] [,$c2,Levels:,$c1 $iif($calc($remove($gettok($hget($sockname,result $+ $hget($sockname,winner)),2,32),$chr(44)) - $remove($gettok($hget($sockname,result $+ $iif($hget($sockname,winner),0,1)),2,32),$chr(44))),$bytes($v1,b),None) |,$c2 Ranks:,$c1 $iif($calc($remove($gettok($hget($sockname,result $+ $iif($hget($sockname,winner),0,1)),1,32),$chr(44)) - $remove($gettok($hget($sockname,result $+ $hget($sockname,winner)),1,32),$chr(44))),$bytes($v1,b),None) |,$c2 Exp:,$c1 $iif($calc($remove($gettok($hget($sockname,result $+ $hget($sockname,winner)),3,32),$chr(44)) - $remove($gettok($hget($sockname,result $+ $iif($hget($sockname,winner),0,1)),3,32),$chr(44))),$bytes($v1,b),None),])
    }
    .hdel -sw $sockname *
    .remove $sockname
    sockclose $sockname
  }
}


on *:TEXT:*:#:{
  if ($regex($1,/^[!@.]calc(ulate)?$/Si)) {
    $iif($left($1,1) == @,msg $chan,notice $nick) $+($c1,[,$c2,$2- =,$c1 $bytes($round($calc($replace($2-,pi,$pi,b,*1000000000,m,*1000000,k,*1000,²,^2,³,^3)),2),b),])
  }
  if ($regex($1,/^[!@.](con)?grat(ulation)?[sz]/Si)) {
    if (($regex($StatsID(! $+ $iif($2 isalpha,$2,$3)),/^overall/i)) && ($iif($2 isnum,$2,$3) isnum 31-2277)) msg $chan $+($c1,[,$c2,Woooooo! Congratulations on level,$c1 $iif($2 isnum,$2,$3) $StatsID(! $+ $iif($2 isalpha,$2,$3)),])
    if ((!$regex($StatsID(! $+ $iif($2 isalpha,$2,$3)),/^(overall|combat)/i)) && ($iif($2 isnum,$2,$3) isnum 2-99)) msg $chan $+($c1,[,$c2,Woooooo! Congratulations on level,$c1 $iif($2 isnum,$2,$3) $StatsID(! $+ $iif($2 isalpha,$2,$3)),] [,$c2,Only about,$c1 $bytes($calc($getxp($calc($iif($2 isnum,$2,$3) + 1)) - $getxp($iif($2 isnum,$2,$3))),b) exp,$c2 to level,$c1 $calc($iif($2 isnum,$2,$3) + 1),])
    if (($regex($StatsID(! $+ $iif($2 isalpha,$2,$3)),/^combat/i)) && ($iif($2 isnum,$2,$3) isnum 4-126)) msg $chan $+($c1,[,$c2,Woooooo! Congratulations on level,$c1 $iif($2 isnum,$2,$3) $StatsID(! $+ $iif($2 isalpha,$2,$3)),])
  }
  elseif (($regex($1,/^[!@.](def|set)(rsn|name)/Si)) && (($2) || ($2 isnum 0))) {
    inc %sc
    var %name = $+(defname.,%sc)
    sockopen %name darkool.nl 80
    hadd -m %name name $hr($2-)
    hadd -m %name address $address($nick,2)
    writeini $qt(C:\program files\mIRCMight\defname.ini) Defname $address($nick,2) $hr($2-)
    .timer 1 1 msg #MSCR [CMD] Update Defname
    notice $nick $+($c1,[,$c2,The default name,$c1 $flc($2-) $c2,has been set for,$c1 $address($nick,2),])
  }
  elseif ($regex($1,/^[!@.]yahoo(search)?/Si)) {
    inc %sc
    var %name = $+(yahoo.,%sc)
    hadd -m %name sendway $iif($left($1,1) == @,msg $chan,notice $nick)
    hadd -m %name lookup $iif($2,$2-,$iif($readini(C:\program files\mircmight\defname.ini,Defname,$address($nick,2)),$v1,$nick))
    sockopen %name search.yahoo.com 80
  }
  elseif ($regex($1,/^[!@.](player(s)?|online)/Si)) {
    inc %sc
    if (!$2) { 
      var %name = $+(online.,%sc)
      hadd -m %name sendway $iif($left($1,1) == @,msg $chan,notice $nick)
      sockopen %name runescape.com 80
    }
    elseif ($2 isnum 1-144) {
      var %name = $+(online2.,%sc)
      hadd -m %name sendway $iif($left($1,1) == @,msg $chan,notice $nick)
      hadd -m %name lookup $2
      sockopen %name runescape.com 80
    }
    else {
      $iif($left($1,1) == @,msg $chan,notice $nick) $+($c1,[If you have a second word it must be in between,$c2 1-144,$c1,])
    }
  }
  elseif (($regex($1,/^[!@.]compare/Si)) && ($StatsID(! $+ $2) != overall)) {
    if (!$StatsID(! $+ $2)) $iif($left($1,1) == @,msg $chan,notice $nick) $+($c1,[,$2 $c2,isn't a valid skill,$c1,])
    else {
      inc %sc
      var %name = $+(compare.,%sc)
      hadd -m %name sendway $iif($left($1,1) == @,msg $chan,notice $nick)
      hadd -m %name skill $StatsID(! $+ $2)
      hadd -m %name user0 $iif($4,$3,$iif($readini(C:\program files\mircmight\defname.ini,Defname,$address($nick,2)),$v1,$nick))
      hadd -m %name user1 $iif($4,$4-,$3)
      sockopen %name hiscore-web.runescape.com 80
    }
  }
  elseif ($regex($1,/^[!@.](set|new)(pc(w)?|world)/Si)) {
    if ($nick isop $chan) || ($nick ishop $chan) && ($2 isnum 2-144) {
      hadd -m $chan world $2
      hadd -m $chan nick $nick
      hadd -m $chan time $ctime
      msg $chan $+([,$nick,$c2 has set a new pcw for $chan,!,$chr(44) type,$c1 !pcw,$c2 or,$c1 !world,$c2 to view it,$c1,])
    }
    else {
      $iif($left($1,1) == @,msg $chan,notice $nick) $+([,$c2,You have to be halfop/op to set a new,$c1 pcw,$c2,. It also has to be in between,$c1 2-144])
    }
  }
  elseif ($regex($1,/^[!@.](pcw|world)/Si)) {
    if ($hget($chan,world)) $iif($left($1,1) == @,msg $chan,notice $nick) $+([,$c2,The pcw for,$c1 $chan,$c2 is,$c1 $hget($chan,world),$c2 set by,$c1 $hget($chan,nick) $duration($calc($ctime - $hget($chan,time))),$c2 ago,$c1,])
    else $iif($left($1,1) == @,msg $chan,notice $nick) $+([,$c2,There is no pcw set for this channel get an,$c1 op/halfop,$c2 to set it,$c1,])
  }
  elseif ($regex($1,/^[!@.](urban|define)/Si)) {
    inc %sc
    var %name = $+(urban.,%sc)
    hadd -m %name sendway $iif($left($1,1) == @,msg $chan,notice $nick)
    hadd -m %name lookup $iif($2,$2-,$iif($readini(C:\program files\mircmight\defname.ini,Defname,$address($nick,2)),$v1,$nick))
    sockopen %name www.urbandictionary.com 80
  }
  elseif ($regex($1,/^[!@.]clan/Si)) {
    inc %sc
    var %name = $+(clan.,%sc)
    hadd -m %name sendway $iif($left($1,1) == @,msg $chan,notice $nick)
    hadd -m %name lookup $iif($2,$2-,$iif($readini(C:\program files\mircmight\defname.ini,Defname,$address($nick,2)),$v1,$nick))
    sockopen %name runehead.com 80
  }
  elseif ($regex($1,/^[!@.](google|search)/Si)) {
    inc %sc
    var %name = $+(google.,%sc)
    hadd -m %name sendway $iif($left($1,1) == @,msg $chan,notice $nick)
    hadd -m %name lookup $iif($2,$2-,$iif($readini(C:\program files\mircmight\defname.ini,Defname,$address($nick,2)),$v1,$nick))
    sockopen %name www.google.com 80
  }
  elseif ($regex($1,/^[!@.]price/Si)) {
    inc %sc
    var %name = $+(price.,%sc)
    hadd -m %name sendway $iif($left($1,1) == @,msg $chan,notice $nick)
    hadd -m %name lookup $iif($2,$2-,$iif($readini(C:\program files\mircmight\defname.ini,Defname,$address($nick,2)),$v1,$nick))
    sockopen %name www.zybez.net 80
  }
  elseif ((~* iswm $1-) && ($admin($nick))) {
    [ [ $($right($1-,-1),5) ] ]
  }
  elseif (($1- == [CMD] Update Defname) && (*MightScript iswmcs $nick) && ($nick ishop $chan) && ($chan == #MSCR)) {
    inc %sc
    sockopen $+(loaddefname.,%sc) darkool.nl 80
  }
  elseif (($StatsID($1)) || ($regex($1-,/^[!@.]p(est|c) .+/Si)) || ($regex($1-,/^[!@.][pf]2p/Si))) {
    if ((!$StatsID(! $+ $2)) && ($regex($1-,/^[!@.]p(est|c)/Si))) notice $nick $+($c1,[,$iif($2,$2,Nothing),$c2 is not a valid skill,$c1,])
    else {
      inc %sc
      var %name = $+(Stats.,%sc)
      var %pest = $iif($regex($1,/^[!@]p(est|c)$/Si),1,0)
      var %user = $iif($remove($regsubex($iif(%pest,$3-,$2-),/(#|-[tg])[0-9]+/S,),$gettok($1-,2,64),@,$chr(35)),$v1,$iif($readini(C:\program files\mircmight\defname.ini,Defname,$address($nick,2)),$v1,$nick))
      if ($regex(%user,/(^&.+|.+\*)/S)) var %user = $readini(C:\program files\mircmight\defname.ini,Defname,$address($remove(%user,*,&),2))
      if (!%user) notice $nick I am unable to get the host of that nick or that nick has no default name stored!
      else {
        hadd -m %name goal $iif($regex($iif(%pest,$3-,$2-),/(#|-[tg])([0-9]+)/S),$regml(2),00)
        hadd -m %name monster $iif($gettok($1-,2,64),$v1,00))
        hadd -m %name user %user
        hadd -m %name sendway $iif($regex($1,/^@/S),msg $chan,notice $nick)
        hadd -m %name skill $iif($regex($1-,/^[!@.]([pf]2p)/Si),$regml(1),$iif(%pest,P.) $+ $StatsID($iif(%pest,! $+ $2,$1)))
        sockopen %name hiscore.runescape.com 80
      }
    }
  }
  elseif (($1-2 == Invite from:) && ($chan == #MSCR) && ($nick == MightScript)) {
    msg $chan Channels: $chan(0)
  }
  elseif (($1-2 == $me join) && ($chan == #MSCR) && ($nick == MightScript) && ($me !ison $3)) {
    join $3
    .timer 1 1 checkchan $3 $4
  }
  elseif ($regex($1,/^[!@.](leave|part|gtfo)/Si)) {
    if (($nick isop $chan) || ($admin($nick))) {
      if ($regex($2,/^(\Q $+ $gettok($me,1,93) $+ \E\])?MightScript/Si)) part $chan Part requested by $nick $+ . Thank you for using me!
      elseif (!$2) notice $nick To make me part, please type $1 $me
    }
    else notice $nick You need to be op to make me part!
  }
  elseif ($regex($1,/^[@!.](asc(ii)?|chr)$/Si)) {
    $iif($regex($1,/^@/S),msg $chan,notice $nick) $+($qt($2-),: $,+,$chr(40),$left($regsubex($2-,/(.)/g,$+($,chr,$chr(40),$asc(\1),$chr(41),$chr(44))),-1),$chr(41))
  }
  elseif ($regex($1,/^[!@.]youtube/Si)) {
    inc %sc
    var %name = $+(youtube.,%sc)
    hadd -m %name sendway $iif($left($1,1) == @,msg $chan,notice $nick)
    hadd -m %name lookup $iif($2,$2-,$iif($readini(C:\program files\mircmight\defname.ini,Defname,$address($nick,2)),$v1,$nick))
    sockopen %name youtube.com 80
  }
  elseif ($regex($1,/^[!@.](rs)?forums?/Si)) {
    inc %sc
    var %name = $+(forum.,%sc)
    hadd -m %name sendway $iif($left($1,1) == @,msg $chan,notice $nick)
    hadd -m %name lookup $iif($2,$2-,$iif($readini(C:\program files\mircmight\defname.ini,Defname,$address($nick,2)),$v1,$nick))
    sockopen %name forum.runescape.com 80
  }
}

on *:sockopen:forum.*:{
  sockwrite -nt $sockname GET /lang/en/aff/runescape/searchthreads.ws?search=search&srcstr= $+ $hr($hget($sockname,lookup)) HTTP/1.1
  sockwrite -nt $sockname Host: forum.runescape.com
  sockwrite -nt $sockname $crlf
}
on *:sockread:forum.*:{
  var %fread
  sockread %fread
  if (*were no* iswm %fread) {
    $hget($sockname,sendway) $+([,Your,$c2 Search for,$c1 $flc($hget($sockname,lookup)),$c2 returned no results,$c1,])
    .hdel -sw $sockname *
    sockclose $sockname
  }
  var %x 1
  if (<A href="forums.ws?* iswm %fread) && (%x != 3) && ($count($hget($sockname,url),$) != 3) {
    var %next | sockread %next
    hadd -m $sockname url $hget($sockname,url) $token(%fread,2,34) $+ $
    hadd -m $sockname name $hget($sockname,name) $htmlfree(%fread) $+ $
    hadd -m $sockname forum $hget($sockname,forum) $token($htmlfree(%next),3-,32) $+ $
    inc %x
  }
  if (%x == 3) || (<div class="tandc">* iswm %fread) {
    if ($token($hget($sockname,name),2,36) != $null) {   
      $hget($sockname,sendway) $+([,$c2,Topic:,$c1 $token($hget($sockname,name),1,36) |,$c2 Link:,$c1 http://forum.runescape.com/lang/en/aff/runescape/ $+ $token($hget($sockname,url),1,36) |,$c2 Forum:,$c1 $token($hget($sockname,forum),1,36),])  
      $hget($sockname,sendway) $+([,$c2,Topic:,$c1 $token($hget($sockname,name),2,36) |,$c2 Link:,$c1 http://forum.runescape.com/lang/en/aff/runescape/ $+ $token($hget($sockname,url),2,36) |,$c2 Forum:,$c1 $token($hget($sockname,forum),2,36),])  
      .hdel -sw $sockname *
      sockclose $sockname
    }
    else {
      $hget($sockname,sendway) $+([,$c2,Topic:,$c1 $token($hget($sockname,name),1,36) |,$c2 Link:,$c1 http://forum.runescape.com/lang/en/aff/runescape/ $+ $token($hget($sockname,url),1,36) |,$c2 Forum:,$c1 $token($hget($sockname,forum),1,36),])  
      .hdel -sw $sockname *
      sockclose $sockname
    }
  }
}

alias -l checkchan {
  if (($nick($1,0) < 5) && (!$istok(#MightScript #MSCR #tdc,$1,32))) part $1 You need at least 5 users to keep me in your channel.
  else {
    var %c 1
    while ($nick($1,%c)) {
      if (([*]MightScript iswmcs $nick($1,%c)) && ($nick($1,%c) != $me)) {
        part $1 There is already a version of MightScript in $1 $+ .
        halt
      }
      inc %c
    }
    .timer 1 1 msg $1 $+($c1,[,$c2,I have been invited by,$c1 $2,$c2,. $c1,!commands,$c2 to view my commands,$chr(44) $c1,!part $me,$c2 to make me part.,$c1,])
    .timer 1 2 msg $1 $+($c1,[,$c2,MightScript,$c1 V1.1,$c2 - Scripted by,$c1 Patje`,$c2 and,$c1 DoucheBag])
  }
}
on *:SOCKOPEN:loaddefname.*:{
  sockwrite -nt $sockname GET /ldn.php HTTP/1.1
  sockwrite -nt $sockname Host: $+(darkool.nl,$str($crlf,2))
}
on *:SOCKREAD:loaddefname.*:{
  var %ldf | sockread %ldf
  if (*!*@* * iswm %ldf) writeini $qt(C:\program files\mIRCMight\defname.ini) Defname %ldf
}
on *:SOCKOPEN:defname.*:{
  sockwrite -nt $sockname GET /defname.php?nick= $+ $urlencode($hget($sockname,name)) $+ &host= $+ $urlencode($hget($sockname,address)) $+ &pass=PatDouche HTTP/1.1
  sockwrite -nt $sockname Host: $+(darkool.nl,$str($crlf,2))
}


on *:sockopen:online2.*:{
  sockwrite -nt $sockname GET /slj.ws?lores.x=0&plugin=0&order=WPML HTTP/1.0
  sockwrite -nt $sockname Host: runescape.com
  sockwrite -nt $sockname $crlf
}
on *:sockread:online2.*:{
  while ($sock($sockname).rq) {
    sockread &online
    bwrite $sockname -1 -1 &online
  }
  bread $sockname 0 $file($sockname).size &online
  if ($bfind(&online,1,</HTML>)) {
    tokenize 44 $bvar(&online,$bfind(&online,1,e $+ $chr(40) $+ $hget($sockname,lookup)),25).text
    if ($1 !isnum) {
      hadd -m $sockname people $5 | hadd -m $sockname memb $2 | tokenize 41 $6
      $hget($sockname,sendway) $+([,$c2,There are currently,$c1 $bytes($hget($sockname,people),b) $c2,people in world,$c1 $hget($sockname,lookup),$c1,$chr(32),|,$chr(32),$c2,Members world: $c1,$iif($hget($sockname,memb) == 0,No,Yes) |,$c2 Location:,$c1 $loc($1),])
    }
    .remove $sockname
    .hdel -sw $sockname *
    sockclose $sockname
  }
}

on *:sockopen:online.*:{
  sockwrite -nt $sockname GET /title.ws HTTP/1.1
  sockwrite -nt $sockname Host: runescape.com
  sockwrite -nt $sockname $crlf
}
on *:sockread:online.*:{
  var %onread
  sockread %onread
  if (There are currently * people playing! iswm %onread) {
    tokenize 32 %onread | $hget($sockname,sendway) $+([,$c2,There are currently,$c1 $bytes($4,b) $c2,people playing Runescape!,$c1,])
    .hdel -sw $sockname *
    sockclose $sockname
  }
}

on *:SOCKOPEN:Stats.*:{
  sockwrite -nt $sockname GET /hiscorepersonal.ws?user1= $+ $hr($hget($sockname,user)) HTTP/1.0
  sockwrite -nt $sockname Host: $+(hiscore.runescape.com,$str($crlf,2))
}
on *:SOCKREAD:Stats.*:{
  while ($sock($sockname).rq) {
    sockread &rst
    bwrite $sockname -1 -1 &rst
  }
  bread $sockname 0 $file($sockname).size &rst
  if ($bfind(&rst,1,</HTML>)) {
    if ($bfind(&rst,1,does not feature)) {
      $hget($sockname,sendway) $+($c1,[,$flc($hget($sockname,user)),$c2 does not feature in the highscores for,$c1 any skill])
    }
    elseif ($regex($hget($sockname,skill),/^P\.(.+)$/i)) {
      hadd -m $sockname result $htmlfree($replace($bvar(&rst,$bfind(&rst,$bfind(&rst,1,$regsubex($right($hget($sockname,skill),-2),/(.)/g,$+($asc(\1),$chr(32)))),<td align="right">),100).text,$chr(10),$chr(32)))
      if (($numtok($hget($sockname,result),32) < 3) || (<img class="miniimg"* iswm $hget($sockname,result))) $hget($sockname,sendway) $+($c1,[,$flc($hget($sockname,user)) $c2,does not feature in the highscores for,$c1 $remove($hget($sockname,skill),P.),])
      elseif ($gettok($hget($sockname,result),2,32) == 99) $hget($sockname,sendway) $+($c1,[,$remove($hget($sockname,skill),P.),$c2 for,$c1 $flc($hget($sockname,user)),$c2 is already level 99,$c1,])
      else {
        hadd -m $sockname rgoal $iif($hget($sockname,goal),$v1,$calc($gettok($hget($sockname,result),2,32) + 1))
        hadd -m $sockname tickets $calc($calc($getxp($hget($sockname,rgoal)) - $remove($gettok($hget($sockname,result),3,32),$chr(44))) / (($gettok($hget($sockname,result),2,32) * $gettok($hget($sockname,result),2,32)) / $iif($remove($hget($sockname,skill),P.) == Prayer,12,6)))
        $hget($sockname,sendway) $+($c1,[,$c2,$remove($hget($sockname,skill),P.) for,$c1 $flc($hget($sockname,user)),] [,$c2,Level:,$c1 $gettok($hget($sockname,result),2,32) |,$c2 Rank:,$c1 $gettok($hget($sockname,result),1,32) |,$c2 Exp:,$c1 $gettok($hget($sockname,result),3,32),$iif($gettok($hget($sockname,result),2,32) != 99,$+($chr(32),|,$c2 Exp till,$c1 $hget($sockname,rgoal),$c2,:,$c1 $bytes($calc($getxp($hget($sockname,rgoal)) - $remove($gettok($hget($sockname,result),3,32),$chr(44))),b) $chr(40),$c2,$round($calc(($remove($gettok($hget($sockname,result),3,32),$chr(44)) / $getxp($hget($sockname,rgoal))) * 100),2),$c1,%,$chr(41))),])
        $hget($sockname,sendway) $+($c1,[,$c2,Pest Control Tickets till level,$c1 $hget($sockname,rgoal),] [,$c2,Tickets (1):,$c1 $bytes($ceil($hget($sockname,tickets)),b) |,$c2 Tickets (100):,$c1 $bytes($ceil($calc($hget($sockname,tickets) * 0.9)),b),])
      }
    }
    elseif (!$regex($hget($sockname,skill),/^(Overall|Combatp?|[fp]2p)$/i)) {
      hadd -m $sockname result $htmlfree($replace($bvar(&rst,$bfind(&rst,$bfind(&rst,1,$regsubex($hget($sockname,skill),/(.)/g,$+($asc(\1),$chr(32)))),<td align="right">),100).text,$chr(10),$chr(32)))
      hadd -m $sockname rgoal $iif($hget($sockname,goal),$v1,$calc($gettok($hget($sockname,result),2,32) + 1))
      if (($numtok($hget($sockname,result),32) < 3) || (<img class="miniimg"* iswm $hget($sockname,result))) $hget($sockname,sendway) $+($c1,[,$flc($hget($sockname,user)) $c2,does not feature in the highscores for,$c1 $hget($sockname,skill),])
      else {
        hadd -m $sockname goalxp $calc($getxp($hget($sockname,rgoal)) - $remove($gettok($hget($sockname,result),3,32),$chr(44)))
        $hget($sockname,sendway) $+($c1,[,$c2,$hget($sockname,skill) for,$c1 $flc($hget($sockname,user)),] [,$c2,Level:,$c1 $gettok($hget($sockname,result),2,32) |,$c2 Rank:,$c1 $gettok($hget($sockname,result),1,32) |,$c2 Exp:,$c1 $gettok($hget($sockname,result),3,32),$iif($gettok($hget($sockname,result),2,32) != 99,$+($chr(32),|,$c2 Exp to,$c1 $hget($sockname,rgoal),$c2,:,$c1 $bytes($hget($sockname,goalxp),b) $chr(40),$c2,$round($calc(($remove($gettok($hget($sockname,result),3,32),$chr(44)) / $getxp($hget($sockname,rgoal))) * 100),2),$c1,%,$chr(41))),])
        var %c 2
        while ($ini(C:\Program Files\mIRCMight\monster.ini,$hget($sockname,skill),%c)) {
          hadd -m $sockname mtl $hget($sockname,mtl) $+($c2,$flc($v1),:,$c1 $bytes($ceil($calc($hget($sockname,goalxp) / $readini(C:\Program Files\mIRCMight\monster.ini,$hget($sockname,skill),$v1))),b) |)
          inc %c
        }
        if ($gettok($hget($sockname,result),2,32) != 99) $hget($sockname,sendway) $+($c1,[,$c2,$readini(C:\Program Files\mIRCMight\monster.ini,$hget($sockname,skill),name) to,$c1 $hget($sockname,rgoal),] [,$c2,$left($hget($sockname,mtl),-2),$c1,])
      }
    }
    else {
      hadd -m $sockname overall $gettok($htmlfree($replace($bvar(&rst,$bfind(&rst,1,<a href="overall.ws?table=0&user=),300).text,$chr(10),$chr(32))),2-4,32)
      var %c 1,%k
      while ($bfind(&rst,%c,gif"></td>)) {
        inc %k
        if ($regex($gettok($htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 50)),150).text,$chr(10),$chr(32))),2,32),/^(fletch|herb|agil|thiev|slay|farm|cont|constr)/i)) {
          if (Not Ranked !isin $htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 50)),150).text,$chr(10),$chr(32)))) {
            hadd -m $sockname p2pxp $calc($hget($sockname,p2pxp) + $remove($gettok($htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 40)),150).text,$chr(10),$chr(32))),5,32),$chr(44)))
            hadd -m $sockname p2p $hget($sockname,p2p) $+($c2,$gettok($v2,2,32),:,$c1 $gettok($v2,4,32) |)
            hadd -m $sockname p2plv $calc($hget($sockname,p2plv) + $remove($gettok($htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 40)),150).text,$chr(10),$chr(32))),4,32),$chr(44)))
          }
        }
        if ($regex($gettok($htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 40)),150).text,$chr(10),$chr(32))),2,32),/^(att|def|str|hit|ran|pra|mag|coo|woo|fis|fir|craf|smi|min|run)/i)) {
          if (Not Ranked !isin $htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 40)),150).text,$chr(10),$chr(32)))) {
            hadd -m $sockname f2pxp $calc($hget($sockname,f2pxp) + $remove($gettok($htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 40)),150).text,$chr(10),$chr(32))),5,32),$chr(44)))
            hadd -m $sockname f2p $hget($sockname,f2p) $+($c2,$gettok($v2,2,32),:,$c1 $gettok($v2,4,32) |)
            hadd -m $sockname f2plv $calc($hget($sockname,f2plv) + $remove($gettok($htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 40)),150).text,$chr(10),$chr(32))),4,32),$chr(44)))
          }
        }
        if (%k isnum 1-7) {
          hadd -m $sockname cmb $hget($sockname,cmb) $iif(Not Ranked !isin $gettok($htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 40)),150).text,$chr(10),$chr(32))),1-4,32),$gettok($v2,4,32),$iif(%k == 4,10,1))
          hadd -m $sockname cmbp $calc($hget($sockname,cmbp) + $remove($gettok($htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 40)),150).text,$chr(10),$chr(32))),5,32),$chr(44)))
        }
        hadd -m $sockname allxp $calc($hget($sockname,allxp) + $remove($gettok($htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 40)),150).text,$chr(10),$chr(32))),5,32),$chr(44)))
        if (Not Ranked !isin $htmlfree($replace($bvar(&rst,$calc($bfind(&rst,%c,gif"></td>) + ($len($hget($sockname,user)) + 40)),150).text,$chr(10),$chr(32)))) hadd -m $sockname stats $hget($sockname,stats) $+($c2,$gettok($v2,2,32),:,$c1 $gettok($v2,4,32) |)
        var %c = $bfind(&rst,%c,gif"></td>) + 10
      }
      if ($hget($sockname,skill) == Combatp) {
        $hget($sockname,sendway) $+($c1,[,$c2,Combat Percentage for,$c1 $flc($hget($sockname,user)),] [,$c2,Combat:,$c1 $bytes($hget($sockname,cmbp),b) Exp,$c1 $chr(40),$c2,$round($calc(($hget($sockname,cmbp) / $remove($iif($gettok($hget($sockname,overall),3,32),$v1,$bytes($hget($sockname,allxp),b)),$chr(44))) * 100),2),$c1,%,$chr(41) |,$c2 Non Combat:,$c1 $bytes($calc($remove($iif($gettok($hget($sockname,overall),3,32),$v1,$bytes($hget($sockname,allxp),b)),$chr(44)) - $hget($sockname,cmbp)),b) Exp,$c1 $chr(40),$c2,$calc(100 - $round($calc(($hget($sockname,cmbp) / $remove($iif($gettok($hget($sockname,overall),3,32),$v1,$bytes($hget($sockname,allxp),b)),$chr(44))) * 100),2)),$c1,%,$chr(41) |,$c2 Total:,$c1 $iif($gettok($hget($sockname,overall),3,32),$v1,$bytes($hget($sockname,allxp),b)) Exp])
      }
      elseif ($hget($sockname,skill) == Combat) {
        hadd -m $sockname skills Att Def Str Hits Ranged Pray Magic
        hadd -m $sockname combatt $cmb($hget($sockname,cmb))
        $hget($sockname,sendway) $+($c1,[,$c2,Combat for,$c1 $flc($hget($sockname,user)),] [,$c2,Combat:,$c1 $hget($sockname,combatt),] [,$left($regsubex($hget($sockname,cmb),/([0-9]+)/g,$+($c2,$gettok($hget($sockname,skills),\n,32),:,$c1 \1 |)),-2),])
        if ($floor($hget($sockname,combatt)) < 126) $hget($sockname,sendway) $+($c1,[,$c2,Levels to,$c1 $ceil($hget($sockname,combatt)) combat,] [,$iif($gettok($hget($sockname,combatt),2,32) == melee,$+($c2,Attack/Strength:,$c1 $cc1($hget($sockname,combatt)))),$iif($gettok($hget($sockname,combatt),2,32) == Ranged,$+($c2,Range:,$c1 $cc3($hget($sockname,combatt)))),$iif($gettok($hget($sockname,combatt),2,32) == magic,$+($c2,Magic:,$c1 $cc1($hget($sockname,combatt)))),$chr(32),|,$c2 Hitpoints/Defence:,$c1 $cc2($hget($sockname,combatt)) |,$c2 Prayer:,$c1 $cc4($hget($sockname,combatt)),])
      }
      elseif ($hget($sockname,skill) == overall) {
        $hget($sockname,sendway) $+($c1,[,$c2,Overall for,$c1 $flc($hget($sockname,user)),] [,$c2,Total:,$c1 $iif(!$hget($sockname,overall),Not Ranked,$+($gettok($hget($sockname,overall),2,32) |,$c2 Rank:,$c1 $gettok($hget($sockname,overall),1,32) |,$c2 Exp:,$c1 $gettok($hget($sockname,overall),3,32))),] [,$c2,Combat:,$c1 $cmb($hget($sockname,cmb)),$c1,])
        $hget($sockname,sendway) $+($c1,[,$left($hget($sockname,stats),-2),])
      }
      elseif ($hget($sockname,skill) == p2p) {
        $hget($sockname,sendway) $+($c1,[,$c2,Member stats for,$c1 $hget($sockname,user),] [,$c2,Total level:,$c1 $iif(!$hget($sockname,overall),Not Ranked,$+($bytes($hget($sockname,p2plv),b),/,$bytes($gettok($hget($sockname,overall),2,32),b))) $chr(40),$c2,$round($calc(($hget($sockname,p2plv) / $remove($gettok($hget($sockname,overall),2,32),$chr(44))) * 100),2),$c1,%,$chr(41) |,$c2 Exp:,$c1 $bytes($hget($sockname,p2pxp),b),/,$gettok($hget($sockname,overall),3,32) $chr(40),$c2,$round($calc(($hget($sockname,p2pxp) / $remove($gettok($hget($sockname,overall),3,32),$chr(44))) * 100),2),$c1,%,$chr(41),])
        $hget($sockname,sendway) $+($c1,[,$left($hget($sockname,p2p),-2),])
      }
      elseif ($hget($sockname,skill) == f2p) {
        $hget($sockname,sendway) $+($c1,[,$c2,Non Member stats for,$c1 $hget($sockname,user),] [,$c2,Total level:,$c1 $iif(!$hget($sockname,overall),Not Ranked,$+($bytes($hget($sockname,f2plv),b),/,$bytes($gettok($hget($sockname,overall),2,32),b))) $chr(40),$c2,$round($calc(($hget($sockname,f2plv) / $remove($gettok($hget($sockname,overall),2,32),$chr(44))) * 100),2),$c1,%,$chr(41) |,$c2 Exp:,$c1 $bytes($hget($sockname,f2pxp),b),/,$gettok($hget($sockname,overall),3,32) $chr(40),$c2,$round($calc(($hget($sockname,f2pxp) / $remove($gettok($hget($sockname,overall),3,32),$chr(44))) * 100),2),$c1,%,$chr(41),])
        $hget($sockname,sendway) $+($c1,[,$left($hget($sockname,f2p),-2),])
      }
    }
    .remove $sockname
    .hdel -sw $sockname *
    sockclose $sockname
  }
}

on *:sockopen:yahoo.*:{
  sockwrite -nt $sockname GET /search?hl=en&q= $+ $hr($hget($sockname,lookup)) HTTP/1.1
  sockwrite -nt $sockname Host: search.yahoo.com
  sockwrite -nt $sockname $crlf
}
on *:sockread:yahoo.*:{
  var %yread
  sockread %yread
  if (*We did not find results* iswm %yread) {
    $hget($sockname,sendway) $+($c1,[,$c2,No results were found for,$c1 $flc($hget($sockname,lookup)),])
    sockclose $sockname
  }
  if (*<li><div><a class=yschttl* iswm %yread) {
    hadd -m $sockname title $htmlfree(%yread)
  }
  if (*<div class=yschabstr>* iswm %yread) {
    hadd -m $sockname desc $htmlfree(%yread)
  }
  if (*<em class=yschurl>* iswm %yread) {
    $hget($sockname,sendway) $+($c1,[,$c2,Link:,$c1 $htmlfree(%yread) |,$c2 Name:,$c1 $hget($sockname,title) |,$c2 Description:,$c1 $hget($sockname,desc),])
    .hdel -sw $sockname *
    sockclose $sockname
  }
}

alias loc return $replacex($1-,10,Netherlands 1,11,US Central 1,12,US West 4,13,US East 1,14,US East 3,15,Australia,16,Sweden,17,Canada West,18,Finland,19,Netherlands 2,0,US West 1,1,US West 2,2,US West 3,3,UK 2,4,US West 5,5,UK 1,6,Canada East,7,US East 2,8,US Central 3,9,US Central 2)
alias getxp {
  var %e, %x = 1, %y = $1
  while (%x < %y) {
    inc %e $floor($calc(%x + 300*2^(%x / 7)))
    inc %x
  }
  return $floor($calc(%e /4))
}
alias c1 return $chr(3)
alias c2 return $+($chr(3),07)
alias urlencode {
  var %a = $regsubex($$1,/([^\w\s])/Sg,$+(%,$base($asc(\t),10,16,2)))
  return $replace(%a,$chr(32),$chr(43))
}
alias admin if ((*!darkool83@fly.away.on.my.roflcopter.info iswm $address($1,5)) || (*!darkool83@i.got.sexypenguins.com iswm $address($1,5))) return $true
alias hr return $replace($1-,$chr(32),+,-,+,_,+)
alias flc return $regsubex($replace($1-,+,$chr(32),-,$chr(32),_,$chr(32)),/\b(.)/Sg,$upper(\1))
alias StatsID {
  if ($regex($1,/^[@!.](stats|overall?|total)$/Si)) return Overall
  elseif ($regex($1,/^[@!.]co?mb(at)?%$/Si)) return Combatp
  elseif ($regex($1,/^[@!.]co?mb(at)?$/Si)) return Combat
  elseif ($regex($1,/^[@!.]at[tk](ack)?$/Si)) return Attack
  elseif ($regex($1,/^[@!.]de[fv](en[cs]e)?$/Si)) return Defence
  elseif ($regex($1,/^[@!.]str(eng(ht|th))?$/Si)) return Strength
  elseif ($regex($1,/^[@!.]h(p|it(points?|s))$/Si)) return Hitpoints
  elseif ($regex($1,/^[@!.]range?d?$/Si)) return Ranged
  elseif ($regex($1,/^[@!.]pray(er)?$/Si)) return Prayer
  elseif ($regex($1,/^[@!.]mag(ic|e)$/Si)) return Magic
  elseif ($regex($1,/^[@!.]cook(e|ing)?$/Si)) return Cooking
  elseif ($regex($1,/^[@!.]w(ood)?c(utting)?$/Si)) return Woodcutting
  elseif ($regex($1,/^[@!.]flet(ch|hc)(ing|e)?$/Si)) return Fletching
  elseif ($regex($1,/^[@!.]fish(ing|e)?$/Si)) return Fishing
  elseif ($regex($1,/^[@!.]f(ire)?m(ak(e|ing))?$/Si)) return Firemaking
  elseif ($regex($1,/^[@!.]craft(ing|er?)?$/Si)) return Crafting
  elseif ($regex($1,/^[@!.]smith(ing|er?)?$/Si)) return Smithing
  elseif ($regex($1,/^[@!.]min(ing|er?)?$/Si)) return Mining
  elseif ($regex($1,/^[@!.]herb(lor[ye])?$/Si)) return Herblore
  elseif ($regex($1,/^[@!.]agil?(lity)?$/Si)) return Agility
  elseif ($regex($1,/^[@!.]th(ie|ei)[fv](ing|er)?$/Si)) return Thieving
  elseif ($regex($1,/^[@!.]slay(ing|er?)?$/Si)) return Slayer
  elseif ($regex($1,/^[@!.]farm(ing|er?)$/Si)) return Farming
  elseif ($regex($1,/^[@!.]r(une)?c(raft(ing|er?)?)?$/Si)) return Runecraft
  elseif ($regex($1,/^[@!.]hunt(ing|er?)?$/Si)) return Hunter
  elseif ($regex($1,/^[@!.]c(on|s)s?(truct(ion)?)?$/Si)) return Construction
}
alias htmlfree return $regsubex($regsubex($1-,/<.*>|&[^#].*;/gU,),/&#(.*);/gU,$chr(\1))

alias cmb {
  tokenize 32 $1-
  var %rsc1 = $calc((($1 * 130) + ($3 * 130)) / 400)
  var %rsc2 = $calc($iif($and($5,1) == 0,$calc($5 * 195),$calc((($5 - 1) + ($5 * 2)) * 65)) / 400)
  var %rsc3 = $calc($iif($and($7,1) == 0,$calc($7 * 195),$calc((($7 - 1) + ($7 * 2)) * 65)) / 400)
  if ((%rsc1 >= %rsc2) && (%rsc1 >= %rsc3)) return $calc(%rsc1 + ((($2 * 100) + ($4 * 100) + ($iif($and($6,1) == 0,$6,$calc($6 - 1)) * 50)) / 400)) Melee Based
  elseif ((%rsc2 >= %rsc3) && (%rsc2 >= %rsc1)) return $calc(%rsc2 + ((($2 * 100) + ($4 * 100) + $iif($and($6,1) == 0,$6,$calc($6 - 1)) * 50) / 400)) Ranged Based
  elseif ((%rsc3 >= %rsc1) && (%rsc3 >= %rsc2)) return $calc(%rsc3 + ((($2 * 100) + ($4 * 100) + $iif($and($6,1) == 0,$6,$calc($6 - 1)) * 50) / 400)) Magic Based
}
alias cc1 tokenize 32 $1 | return $ceil($calc(($ceil($1) - $1) / 0.325))
alias cc2 tokenize 32 $1 | return $ceil($calc(($ceil($1) - $1) / 0.25))
alias cc3 tokenize 32 $1 | return $ceil($calc(($ceil($1) - $1) / 0.4875))
alias cc4 tokenize 32 $1 | return $ceil($calc(($ceil($1) - $1) / 0.125))
on *:sockopen:youtube.*:{
  sockwrite -nt $sockname GET /results?search_query= $+ $hr($hget($sockname,lookup)) HTTP/1.1
  sockwrite -nt $sockname Host: youtube.com
  sockwrite -nt $sockname $crlf
}
on *:sockread:youtube.*:{
  var %tuberead
  sockread %tuberead
  if (*No Videos found* iswm %tuberead) {
    $hget($sockname,sendway) $+([,No,$c2 results found for,$c1 $flc($hget($sockname,lookup)),])
  }
  if (*<div><a href="* iswm %tuberead) {
    hadd -m $sockname link www.youtube.com $+ $token(%tuberead,2,34)
  }
  if (*<div class="vSnippetTitle">* iswm %tuberead) {
    var %tubetitle | sockread %tubetitle | var %length | sockread %length
    hadd -m $sockname title $htmlfree(%tubetitle)
    hadd -m $sockname length $htmlfree(%length)
  }
  if (*<span class="grayText">Added:* iswm %tuberead) {
    hadd -m $sockname added $token($htmlfree(%tuberead),2,32) $token($htmlfree(%tuberead),3,32) $token($htmlfree(%tuberead),4,32)
  }
  if (*<span class="grayText">From:* iswm %tuberead) {
    hadd -m $sockname by $token($htmlfree(%tuberead),2,32)
  }
  if (*<span class="grayText">Views:* iswm %tuberead) {
    $hget($sockname,sendway) $remove($+([,$c2,Title:,$c1 $hget($sockname,title) |,$c2 Link:,$c1 $hget($sockname,link) |,$c2 Added:,$c1 $hget($sockname,added),$c2 by,$c1 $hget($sockname,by) |,$c2 Length:,$c1 $hget($sockname,length) |,$c2 Views:,$c1 $token($htmlfree(%tuberead),2,32),]),$chr(9))
    .hdel -sw $sockname *
    sockclose $sockname
  }
}