Someone

alias timestamp { !timestamp $1- | saveini }
on ^*:TEXT:*:#:{
  var %i = 0
  var %line = $1-
  if ($nick isop $chan) {
    var %nick = <4@ $+ $nick $+ >
  }
  elseif ($nick ishop $chan) {
    var %nick = <7% $+ $nick $+ >
  }
  elseif ($nick isvoice $chan) {
    var %nick = <2+ $+ $nick $+ >
  }
  else {
    var %nick = <10 $+ $nick $+ >
  }
  if ($gettok($readini(mirc.ini,options,n4),12,44) == 0) {
    .echo -m $chan %nick %line
  }
  elseif ($gettok($readini(mirc.ini,options,n4),12,44) == 1) {
    .echo -m $chan $timestamp %nick %line
  }
  haltdef
}
on *:INPUT:#:{
  if (/* iswm $1) && (/say != $1) { return }
  if ($1 == /say) tokenize 32 $2-
  var %nick = $+(<,$iif($left($nick($chan,$me).pnick,1) isin @%+,$replace($v1,@,04@,%,07%,+,02+),10),$me,>)
  if ($1 ison $chan && $chan != #IRCHelp) tokenize 32 $+(15»14»02[,$iif($left($nick($chan,$1).pnick,1) isin @%+,$replace($v1,@,04@,%,07%,+,02+),10),$1,02]14«15«) $2-
  echo $iif($gettok($readini(mirc.ini,options,n4),12,44) == 1,-t) $chan %nick $1-
  .msg $chan $1-
  halt
}


on ^*:JOIN:#:{
  haltdef
  .echo $chan 3 $+ $timestamp * $nick ( $+ $right($address($nick,0),-2) $+ ) has joined $chan
}
on ^*:PART:#:{
  haltdef
  .echo $chan 3 $+ $timestamp * $nick ( $+ $right($address($nick,0),-2) $+ ) has left $chan
}
on ^*:RAWMODE:#:{
  haltdef
  .echo $chan 3 $+ $timestamp * $nick sets mode: $1-
}
on ^*:NICK:{
  haltdef
  var %nicka $chan(0)
  var %nickb 1
  while (%nickb <= %nicka) {
    if ($newnick ison $chan(%nickb)) .echo $chan(%nickb) 3 $+ $timestamp * $nick is now known as $newnick
    inc %nickb
  }
}
on ^*:QUIT:{
  haltdef
  var %quita $chan(0)
  var %quitb 1
  while (%quitb <= %quita) {
    if ($nick ison $chan(%quitb)) .echo $chan(%quitb) 2 $+ $timestamp * $nick ( $+ $right($address($nick,0),-2) $+ ) has quit IRC ( $+ $1- $+ )
    inc %quitb
  }
}
on ^*:KICK:#:{
  haltdef
  .echo $chan 3 $+ $timestamp * $knick was kicked by $nick ( $+ $1- $+ )
}
raw 332:*:{
  haltdef
  .echo $2 3 $+ $timestamp * Topic is ' $+ $3- $+ 3'
}
raw 333:*:{
  haltdef
  .echo $2 3 $+ $timestamp * Set by $3 on $asctime($4,ddd mmm dd HH:nn:ss)
}
alias joinall {
  enable #joinall
  list
}
#joinall off
raw 322:*:{
  if ($2 !ischan) join $2
}
raw 323:*:{
  disable #joinall
}
#joinall end