rendered paste body<CsoundSynthesizer>
<CsOptions>
</CsOptions>
<CsInstruments>
sr=44100
ksmps=25
nchnls=2
garvbl init 0
garvbr init 0
instr 11
anoise noise 2000, .4
kfc expseg 6000, p3, 120
anfiltl butterlp anoise, kfc, 5
anfiltr butterlp anoise, kfc*1.01, 6
knoisel downsamp anfiltl
knoiser downsamp anfiltr
knfmfql = 300 + knoisel
knfmfqr = 300 + knoiser
anfml oscil 1, knfmfql, 1
anfmr oscil 1, knfmfqr, 1
aenv linseg 0, .002, 0dbfs*.8, .008, 0dbfs*.4, p3-2.01, 0dbfs*.3, 2, 0
kjit jitter .1, 10, 25
kjitmod = kjit + 1
arawl = anfml * aenv *kjitmod
arawr = anfmr * aenv * kjitmod
acompl compress arawl, arawl, 0, 84, 90, 25, .003, .004, .06
acompr compress arawr, arawr, 0, 84, 90, 25, .003, .004, .06
asigl = acompl
asigr = acompr
garvbl = garvbl + asigl * .3
garvbr = garvbr + asigr * .3
outs asigl, asigr
endin
instr 99
arvbl reverb garvbl, .1
arvbr reverb garvbr, .1
outs arvbl, arvbr
garvbl = 0
garvbr = 0
endin
</CsInstruments>
<CsScore>
f1 0 16384 10 1
i11 0 20
i99 0 40
e
</CsScore>
</CsoundSynthesizer>