Someone

alias -l c1 return $+($chr(3),12,$1-)
alias -l c2 return $+($chr(3),01,$1-)
on $*:TEXT:/^[@!]closest(lvl)?/Si:#:{
  var %sock = $+(statsn,.,$ticks)
  hadd -m %sock disp $iif($left($1,1) == !,.notice $nick,msg $chan)
  hadd -m %sock name $iif($2,$2-,$iif($readini(defrsn.ini,defname,$nick),$v1,$nick))
  sockopen %sock parsers.freehostia.com 80
}
on *:SOCKOPEN:statsn.*:{
  sockwrite -nt $sockname GET /parsers/statsoww.php?rsname= $+ $replace($hget($sockname,name),$chr(32),+)  HTTP/1.1
  sockwrite -nt $sockname Host: parsers.freehostia.com $+ $crlf $+ $crlf
}
on *:SOCKREAD:statsn.*:{
  var %read | sockread -f %read
  tokenize 32 %read
  if (*is not featured* iswm %read) {
    $hget($sockname,disp) $hget($sockname,name) $c2(isn't featured in the high scores.) 
    hfree $sockname
    sockclose $sockname
    halt
  }
  if ($istok(Attack:Strength:Defence:Hitpoints:Prayer:Magic:Ranged:Cooking:Woodcutting:Fletching:Fishing:Firemaking:Crafting:Smithing:Mining:Herblore:Agility:Thieving:Slayer:Farming:Hunter:Runecraft:Construction,$1,58)) {
    if ($3 isnum) writeini lookups.ini $sockname $1 $xp2Next($3,$4) $calc($3 + 1)
  }
  if ($1 == END) {
    var %a = 0
    while (%a < $ini(lookups.ini,$sockname,0)) var %a = %a + 1, %line = %line $gettok($readini(lookups.ini,$sockname,$ini(lookups.ini,$sockname,%a)),1,32)
    var %line = $sorttok(%line,32,n), %low = $gettok(%line,1,32), %count = $count(%line,%low), %c = 0
    while (%c < $ini(lookups.ini,$sockname,0)) var %c = %c + 1, %info = $readini(lookups.ini,$sockname,$ini(lookups.ini,$sockname,%c)), %newline = %newline $iif($gettok(%info,1,32) == %low,$c1($+($ini(lookups.ini,$sockname,%c),:)) $c2($+(%low,xp) to lvl) $c1($gettok(%info,2,32)))
    $hget($sockname,disp) $c1($hget($sockname,name) $+ 's) $c2(nearest $iif(%count > 1,skills,skill) to level $iif(%count == 1,is:,are:)) %newline
    hfree $sockname
    remini lookups.ini $sockname
    sockclose $sockname
  }
}