Someone

; #################################################################
; ## Custom Whois                                                ##
; ## Written by Urza (Urza23@hotmail.com)                        ##
; ## Appearance taken from a screenshot by an unknown author     ##
; ## Written and tested in mIRC 6.16/6.17                        ##
; #################################################################

menu * {
  $iif($group(#whois) == on,disable,enable) Custom Whois: {
    var %status = $iif($group(#whois) == on,Disable,Enable)
    $+(.,%status) #whois
    echo -ta 3» Custom whois has been $+(%status,d)
  }
}
alias whoisnumerics return 301|307|310|311|312|313|314|317|318|319|320|330|335|338|369|378|379|401|406|671|536
#whois on
raw *:*: { 
  if ($istok($whoisnumerics,$numeric,124)) haltdef
  if ($numeric == 301) echo -a 3» Away: Yes: ( $+ $3- $+ ) 
  elseif ($numeric == 307) echo -a 3» Registered Nickname: Yes.
  elseif ($numeric == 310) echo -a 3» IRC Helper: Yes.  
  elseif ($numeric == 311) {
    echo -a 03-----14<10whois14>03---------------------------- 
    echo -a 3» Nick: $2 
    echo -a 3» Real Name: $6- 
    echo -a 3» Hostmask:10 $3 $+ 3 $+ @ $+ 07 $+ $4
  }
  elseif ($numeric == 312) echo -a 3» Server: $3 
  elseif ($numeric == 313) echo -a 3» Network Functions: $5-9
  elseif ($numeric == 314) {
    echo -a 15-----14<15whowas14>15---------------------------- 
    echo -a 3» Nick: $2 
    echo -a 3» Name: $6- 
    echo -a 3» Hostmask: $3 $+ 4 $+ @ $+ $4 
  }
  elseif ($numeric == 317) {
    echo -a 3» Signed on at: $asctime($4,dddd dd/mm/yyyy HH:nn:ss) 
    echo -a 3» Time idle: $duration($3) 
    echo -a 3» Time online: $duration($calc($ctime - $4)) 
  }
  elseif ($numeric == 318) echo -a 03-----14<03/whois14>03--------------------------- 
  elseif ($numeric == 319) echo -a 3» Channels: $replacex($3-,@,$chr(3) $+ 4@ $+ $chr(3),%, $chr(3) $+ 7% $+ $chr(3),+, $chr(3) $+ 2+ $+ $chr(3))
  elseif ($numeric == 320) echo -a 3» Swhois: $2- 
  elseif ($numeric == 330) echo -a 3» Authname: $3 
  elseif ($numeric == 335) echo -a 3» Bot: Yes
  elseif ($numeric == 338) {
    echo -a 3» Real Hostmask: $3 
    echo -a 3» Real IP: $4 
  }
  elseif ($numeric == 369) echo -a 15-----14<15/whowas14>15--------------------------- 
  elseif ($numeric == 378) echo -a 3» Connecting from: $6-  
  elseif ($numeric == 379) echo -a 3» Modes: $6-
  elseif ($numeric == 401) echo -a 3» The nickname " $+ $2 $+ " is 4NOT 3online!
  elseif ($numeric == 406) echo -a 3» The nickname " $+ $2 $+ " has 4NOT 3been online recently.
  elseif ($numeric == 671) echo -a 3» Secure Connection: Yes
  elseif ($numeric == 536) echo -a 3» Filtering Messages: Yes
} 
#whois end