Something

alias gt_autotrade {
  if (%gt_debug) echo -dt gt_autotrade Release $1 Section $2 Pretime $3 Site $4 Type $5
  if ($hget(gt_rules,$1) == $null) { gt_rules_writehash $1 $2 }
  if ($readini(gt\autotrade. $+ $2 $+ .ini, $4,disabledn) == 1) { return }
  if ((($5 == new) || ($5 == com)) && ($gt_rules_preallowed($1,$2,$4) == 1)) {
    if ($5 == com) {
      if (!$readini($+(gt\autotrade.,$2,.ini),$4,disableup)) {
        aline -h @GT_Info $chr(91) $+ $asctime(HH:nn:ss) $+ $chr(93) 2Complete: $1 on $4
      }
      dll Rushmirc.dll RushScript RushApp.FTP.RemoveQueue('',' $+ $4 $+ ',' $+ $1 $+ ',RS_TRANSFER or RS_NORMAL or RS_WAITING)
    }
    var %s = $readini(gt\autotrade. $+ $2 $+ .ini,$4,tosite)
    var %i = 1
    while ($gettok(%s,%i,32) != $null) {
      if ($left($gettok(%s,%i,32),1) == +) { inc %i | continue }
      if ($gt_rules_preallowed($1,$2,$gettok(%s,%i,32)) == 1) {
        if ($findtok(com.nuke.pre,$gt_rlsstatus($2,$1,$gettok(%s,%i,32)),1,46) == $null) {
          if ($readini(gt\autotrade. $+ $2 $+ .ini, $gettok(%s,%i,32),disableup) == 1) { inc %i | continue }
          gt_trade $4 $gettok(%s,%i,32) $2 $1
        }
      }
      inc %i
    }
  }
  elseif ($5 == pre) {
    var %s = $readini(gt\autotrade. $+ $2 $+ .ini,$4,tosite)
    var %i = 1
    while ($gettok(%s,%i,32) != $null) {
      var %gt_sitename = $remove($gettok(%s,%i,32),+)
      if ($gt_rules_preallowed($1,$2,%gt_sitename) == 1) {
        if ($findtok(com.nuke.pre,$gt_rlsstatus($2,$1,%gt_sitename),1,46) == $null) {
          if ($readini(gt\autotrade. $+ $2 $+ .ini, %gt_sitename,disableup) == 1) { inc %i | continue }
          gt_trade $4 %gt_sitename $2 $1
        }
      }
      inc %i
    }
  }
  elseif (($5 == nuke) || ($5 == del)) {
    dll Rushmirc.dll RushScript RushApp.FTP.RemoveQueue(' $+ $4 $+ ','',' $+ $1 $+ ',RS_TRANSFER or RS_NORMAL or RS_WAITING)
    dll Rushmirc.dll RushScript RushApp.FTP.RemoveQueue('',' $+ $4 $+ ',' $+ $1 $+ ',RS_TRANSFER or RS_NORMAL or RS_WAITING)
    if (!$readini($+(gt\autotrade.,$2,.ini),$4,disableup)) {
      aline -h @GT_Info $chr(91) $+ $asctime(HH:nn:ss) $+ $chr(93) $replace($5,nuke,4Nuke:    ,del,12Deleted: ) $+  $1 on $4 
    }
  }
}