Stuff

alias -l c1 { return $+($chr(3),14,$1-) } 
alias -l c2 { return $+($chr(3),04,$1-) } 
alias -l c3 { return $+($chr(3),13,$1-) } 

menu channel,menubar,nicklist { 
  Address Tracking 
  .$iif($group(#Addtrack) == on,$style(1)) Show used nicks on join: { 
    var %status = $iif($group(#Addtrack) == on,Disable,Enable) 
    $+(.,%status) #Addtrack 
    msg $chan * Users previous nicks will $iif(%status == Disable,no longer,now) be shown when they join 
  } 
  .- 
  .$iif($1,Check nicks for $1):CheckNicks $1 
  .Check nicks for an address: { 
    CheckNicks $+(*!,$$?="Enter the hostmask you want to check in the format NICK!IDENT@HOST*") 
  } 
} 

on *:start: { 
  hmake Addtrack 100 
  if ($isfile(Addtrack.hsh)) hload Addtrack Addtrack.hsh 
} 
on *:exit: if ($hget(Addtrack)) hsave -o Addtrack Addtrack.hsh 

#Addtrack off
on *:join:#: { 
  if ($wildsite iswm $address($me,5)) return 
  var %mask = $mask($fulladdress,3) 
  if ($hget(Addtrack,%mask)) { 
    var %usednicks = $ifmatch 
    if (%usednicks != $nick) && ($group(#Addtrack) == on) msg $chan $c1([¤) $c2(Poser Track) $c1(¤]) $c2($nick has also used the nicks:) $c3($remtok(%usednicks,$nick,1,44)) 
    if (!$istok(%usednicks,$nick,44)) hadd -m Addtrack %mask $addtok(%usednicks,$nick,44) 
    if ($numtok(%usednicks,44) > 10) hadd -m Addtrack %mask $deltok(%usednicks,1,44) 
  } 
  else { 
    hadd -m Addtrack %mask $nick 
  } 
} 
on *:nick: { 
  if ($wildsite iswm $address($me,5)) return 
  var %mask = $mask($fulladdress,3) 
  if ($hget(Addtrack,%mask)) { 
    var %usednicks = $ifmatch 
    if (!$istok(%usednicks,$newnick,44)) hadd -m Addtrack %mask $addtok(%usednicks,$newnick,44) 
    if ($numtok(%usednicks,44) > 10) hadd -m Addtrack %mask $deltok(%usednicks,1,44) 
  } 
  else { 
    hadd -m Addtrack %mask $newnick 
  } 
} 
#addtrack end 

alias CheckNicks { 
  if (*!*@* iswm $1) { 
    var %mask = $mask($1,3) 
    if (!$hget(Addtrack,%mask)) echo 4 -ta No entry found for $1 
    else msg $chan Address $1 has used the nicks: $hget(Addtrack,$1) 
  } 
  elseif (!$hget(Addtrack,$address($1,3))) echo 4 -ta No Entry found for $1 
  elseif ($hget(Addtrack,$address($1,3)) != $1) { 
    var %usednicks = $ifmatch 
    msg $chan $1 has also used the nicks $remtok(%usednicks,$1,1,43) 
  } 
  else msg $chan $1 has not been seen on any other nicks 
}