Untitled

on *:TEXT:.unb *:#:{
  if ($site != tyler.users.swiftirc.net) halt
  if ($address($2,5)) {
    set %unb.mask $v1
    .enable #unb
    mode $chan b
  }
  else {
    set %unb.chan $chan
    .enable #unb.lookup
    userhost $2
  }
}
raw *:*:{
  if ($istok(302 367 368,$numeric,32)) haltdef
  if ($numeric == 302) && ($group(#unb.lookup).status == on) {
    if ($2) {
      set %unb.mask $replace($2,=+,!,=-,!,*,$null)
      .enable #unb
      mode %unb.chan b
    }
    .disable #unb.lookup
  }
  if ($numeric == 367) && ($group(#unb).status == on) {
    if ($3 iswm %unb.mask) {
      set %unb.string %unb.string $3
      if ($numtok(%unb.string,32) == $modespl) {
        mode $2 $+(-,$str(b,$v1)) %unb.string
        unset %unb.string
      }
    }
  }
  if ($numeric == 368) && ($group(#unb).status == on) {
    if (%unb.string) mode $2 $+(-,$str(b,$numtok($v1,32))) $v1
    .disable #unb
    cleanup
  }
}
alias -l cleanup { unset %unb.* }
#unb off
#unb end
#unb.lookup off
#unb.lookup end