Something

menu * {
  $iif($group(#whois) == on,disable,enable) Custom Whois: {
    var %status = $iif($group(#whois) == on,Disable,Enable)
    $+(.,%status) #whois
    echo -ta » Custom whois has been $+(%status,d)
  }
}
alias whoisnumerics return 301|307|310|311|312|313|314|317|318|319|320|330|335|338|369|378|379|401|406|671
#whois on
raw *:*: {
  if ($istok($whoisnumerics,$numeric,124)) haltdef
  if ($numeric == 301) echo -a » Away: Yes: ( $+ $3- $+ )
  elseif ($numeric == 307) echo -a » Registered Nickname: Yes.
  elseif ($numeric == 310) echo -a » IRC Helper: Yes.  
  elseif ($numeric == 311) {
    echo -a -----<whois>----------------------------
    echo -a » Nick: $2
    echo -a » Real Name: $6-
    echo -a » Hostmask: $3 $+  $+ @ $+  $+ $4
  }
  elseif ($numeric == 312) echo -a » Server: $3
  elseif ($numeric == 313) echo -a » Network Functions: $5-9
  elseif ($numeric == 314) {
    echo -a -----<whowas>----------------------------
    echo -a » Nick: $2
    echo -a » Name: $6-
    echo -a » Hostmask: $3 $+  $+ @ $+ $4
  }
  elseif ($numeric == 317) {
    echo -a » Signed on at: $asctime($4,dddd dd/mm/yyyy HH:nn:ss)
    echo -a » Time idle: $duration($3)
    echo -a » Time online: $duration($calc($ctime - $4))
  }
  elseif ($numeric == 318) echo -a -----</whois>---------------------------
  elseif ($numeric == 319) echo -a » Channels: $3-
  elseif ($numeric == 320) echo -a » Swhois: $2-
  elseif ($numeric == 330) echo -a » Authname: $3
  elseif ($numeric == 335) echo -a » Bot: Yes
  elseif ($numeric == 338) {
    echo -a » Real Hostmask: $3
    echo -a » Real IP: $4
  }
  elseif ($numeric == 369) echo -a -----</whowas>---------------------------
  elseif ($numeric == 378) echo -a » Connecting from: $6-  
  elseif ($numeric == 379) echo -a » Modes: $6-
  elseif ($numeric == 401) echo -a » The nickname " $+ $2 $+ " is NOT online!
  elseif ($numeric == 406) echo -a » The nickname " $+ $2 $+ " has NOT been online recently.
  elseif ($numeric == 671) echo -a » Secure Connection: Yes
}
#whois end