Mine

; Channel access listing
#list_all_channels off
; Ignore messages from AuthServ about the account details; they are irrelevant
on ^99:NOTICE:*Account information for*:?:{ halt }
on ^99:NOTICE:*Registered on*:?:{ halt }
on ^99:NOTICE:*Last seen*:?:{ halt }
on ^99:NOTICE:*Infoline*:?:{ halt }
on ^99:NOTICE:*Do-not-register*:?:{ halt }
on ^99:NOTICE:*Email address*:?:{ halt }
on ^99:NOTICE:*Flags*:?:{ halt }
on ^99:NOTICE:*Epithet*:?:{ halt }
on ^99:NOTICE:*Fake host*:?:{ halt }
on ^99:NOTICE:*Last quit hostmask*:?:{ halt }
on ^99:NOTICE:*Hostmask*:?:{ halt }
on ^99:NOTICE:*Current nickname(s)*:?:{ 
  ; This is the last message in the run; disable the group here
  .disable #list_all_channels
  .timerDisabler off
  halt
}

on ^99:NOTICE:*Channel(s)*:?:{
  /var %x = 1
  /var %the_chan = $null

  while (%x <= $numtok($2-,32)) {
    %the_chan = $gettok($2-,%x,32)
    if ($len($gettok(%the_chan,1,$asc(:))) != 3) { set -u5 %peon-in %peon-in $gettok(%the_chan,2,$asc(:)) }
    elseif ($left($gettok(%the_chan,1,$asc(:)),1) == 1) { set -u5 %peon-in %peon-in $gettok(%the_chan,2,$asc(:)) }
    elseif ($left($gettok(%the_chan,1,$asc(:)),1) == 2) { set -u5 %op-in %op-in $gettok(%the_chan,2,$asc(:)) }
    elseif ($left($gettok(%the_chan,1,$asc(:)),1) == 3) { set -u5 %master-in %master-in $gettok(%the_chan,2,$asc(:)) }
    elseif ($left($gettok(%the_chan,1,$asc(:)),1) == 4) { set -u5 %coowner-in %coowner-in $gettok(%the_chan,2,$asc(:)) }
    elseif ($left($gettok(%the_chan,1,$asc(:)),1) == 5) { set -u5 %owner-in %owner-in $gettok(%the_chan,2,$asc(:)) }
    else { echo -at *** Script error on chan $gettok(%the_chan,2,$asc(:)) }

    inc %x
  }

  echo $hget(Global-Config,trkr-colour-header) -at <--This user has access in the following channels-->
  echo $hget(Global-Config,trkr-colour-item) -at *** Owner ( $+ $numtok(%owner-in,32) $+ ):  $+ $hget(Global-Config,trkr-colour-text) $+ %owner-in
  echo $hget(Global-Config,trkr-colour-item) -at *** Coowner ( $+ $numtok(%coowner-in,32) $+ ):  $+ $hget(Global-Config,trkr-colour-text) $+ %coowner-in
  echo $hget(Global-Config,trkr-colour-item) -at *** Master ( $+ $numtok(%master-in,32) $+ ):  $+ $hget(Global-Config,trkr-colour-text) $+ %master-in
  echo $hget(Global-Config,trkr-colour-item) -at *** Op ( $+ $numtok(%op-in,32) $+ ):  $+ $hget(Global-Config,trkr-colour-text) $+ %op-in
  echo $hget(Global-Config,trkr-colour-item) -at *** Peon ( $+ $numtok(%peon-in,32) $+ ):  $+ $hget(Global-Config,trkr-colour-text) $+ %peon-in

  unset %owner-in
  unset %coowner-in
  unset %master-in
  unset %op-in
  unset %peon-in

  haltdef
}
#list_all_channels end