rendered paste body[script]
n0=dialog QM {
n1= title "Bladex QueryManager [/QM] v2.2.7"
n2= size -1 -1 124 133
n3= option dbu
n4= tab "Configuration", 100, 2 1 120 130
n5= box "basic configuration", 5, 4 17 115 58, tab 100
n6= check "block all incoming messeges", 6, 7 26 82 10, tab 100 flat
n7= check "use Whitelist", 7, 7 53 41 10, tab 100 flat
n8= check "use Blacklist", 8, 7 44 43 10, tab 100 flat
n9= check "accept all incoming messeges", 9, 7 35 87 10, tab 100 flat
n10= text "Auto Block messeges after:", 26, 7 64 70 8, tab 100
n11= edit "0", 27, 75 62 16 10, tab 100 autohs right
n12= text "sec.", 28, 93 64 13 8, tab 100
n13= button "reset", 33, 80 86 37 12, tab 100 flat
n14= edit "", 34, 5 100 112 10, tab 100 autohs
n15= button "change", 32, 41 86 37 12, tab 100 flat
n16= box "edit text", 30, 4 76 115 38, tab 100
n17= combo 31, 6 86 33 37, tab 100 size drop
n18= link "mIRCboard.de", 25, 44 122 36 8, tab 100
n19= text "by Salz`", 24, 51 115 22 8, tab 100
n20= button "Ok", 2, 4 116 37 12, tab 100 flat ok
n21= button "Cancel", 3, 82 116 37 12, tab 100 flat cancel
n22= tab "White/Black List", 10
n23= box "Whitelist", 11, 4 26 116 49, tab 10
n24= list 12, 6 34 72 38, tab 10 size
n25= button "remove", 13, 80 60 37 12, tab 10 flat
n26= button "edit", 14, 80 46 37 12, tab 10 flat
n27= button "add", 15, 80 32 37 12, tab 10 flat
n28= box "Blacklist", 22, 4 77 116 49, tab 10
n29= list 19, 6 85 72 38, tab 10 size
n30= button "add", 18, 80 83 37 12, tab 10 flat
n31= button "edit", 20, 80 97 37 12, tab 10 flat
n32= button "remove", 21, 80 111 37 12, tab 10 flat
n33= text "Note: add and edit will open a input dialog", 1, 5 16 114 10, tab 10
n34=}
n35=on *:dialog:qm:init:0:{
n36= if ($qm.config(blockall)) did -c $dname 6
n37= if ($qm.config(allowall)) did -c $dname 9
n38= if ($qm.config(blacklist)) did -c $dname 8
n39= if ($qm.config(whitelist)) did -c $dname 7
n40= if ($qm.config(autoclose)) did -ra $dname 27 $ifmatch
n41= var %x = 0
n42= while (%x < $qm.text(0).title) {
n43= inc %x
n44= did -a $dname 31 $qm.text(%x).title
n45= }
n46= did -fc $dname 31 1
n47= did -ra $dname 34 $qm.text($did($dname,31))
n48= qm.list $dname
n49=}
n50=on *:dialog:qm:edit:27:{
n51= if ($did($dname,$did) isnum) { qm.config autoclose $ifmatch }
n52=}
n53=on *:dialog:qm:sclick:14:{
n54= var %know = $did($dname,12).sel
n55= if ($input(Please enter the nickname here:,e,edit nick from whitelist,$did($dname,12).seltext,)) {
n56= var %known = $ifmatch
n57= did -d $dname 12 %know
n58= did -a $dname 12 %known
n59= qm.white -r %know
n60= qm.white %known
n61= }
n62=}
n63=on *:dialog:qm:sclick:20:{
n64= var %know = $did($dname,19).sel
n65= if ($input(Please enter the nickname here:,e,edit nick from blacklist,$did($dname,19).seltext,)) {
n66= var %known = $ifmatch
n67= did -d $dname 19 %know
n68= did -a $dname 19 %known
n69= qm.white -r %know
n70= qm.white %known
n71= }
n72=}
n73=on *:dialog:qm:sclick:15:{
n74= qm.white $input(Please enter the nickname here:,e,add nick to whitelist,,)
n75= qm.list $dname
n76=}
n77=on *:dialog:qm:sclick:18:{
n78= qm.black $input(Please enter the nickname here:,e,add nick to blacklist,,)
n79= qm.list $dname
n80=}
n81=on *:dialog:qm:sclick:13:{
n82= qm.white -r $did($dname,12).seltext
n83= qm.list $dname
n84=}
n85=on *:dialog:qm:sclick:21:{
n86= qm.black -r $did($dname,19).seltext
n87= qm.list $dname
n88=}
n89=on *:dialog:qm:sclick:6:{
n90= qm.config blockall $did($dname,$did).state
n91=}
n92=on *:dialog:qm:sclick:7:{
n93= qm.config whitelist $did($dname,$did).state
n94=}
n95=on *:dialog:qm:sclick:8:{
n96= qm.config blacklist $did($dname,$did).state
n97=}
n98=on *:dialog:qm:sclick:9:{
n99= qm.config allowall $did($dname,$did).state
n100=}
n101=on *:dialog:qm:sclick:31:{
n102= did -ra $dname 34 $qm.text($did($dname,31))
n103=}
n104=on *:dialog:qm:sclick:32:{
n105= qm.text $did($dname,31) $did($dname,34)
n106=}
n107=on *:dialog:qm:sclick:33:{
n108= qm.text -d $did($dname,31)
n109= did -ra $dname 34 $qm.text($did($dname,31))
n110=}
n111=on *:dialog:qm:sclick:25:{ run http://mircboard.de }
n112=dialog qminform {
n113= title "Query, autoblock in: 900sec"
n114= size -1 -1 160 71
n115= option dbu
n116= text "Name:", 2, 14 11 19 9, right
n117= box "Information", 3, 3 2 154 53
n118= text "$nick", 5, 35 11 119 8
n119= text "ComChan:", 4, 8 20 25 8
n120= text "$comchan", 6, 35 20 119 14
n121= button "allow", 1, 3 57 37 12, flat ok
n122= button "block", 7, 42 57 37 12, flat cancel
n123= button "blacklist", 8, 120 57 37 12, flat
n124= button "whitelist", 9, 81 57 37 12, flat
n125= text "Message:", 10, 8 35 25 8, right
n126= text "", 11, 35 35 119 17
n127=}
n128=on ^*:open:?:{
n129= echo $color(info2 text) -ts * Incomming query: $nick
n130= .timer -h 1 20 window -h $nick
n131= if (($qm.config(blacklist)) && ($qm.black($nick))) {
n132= .msg $nick $qm.text(blacklist)
n133= .timer $+ $nick 1 20 close -m $nick
n134= haltdef
n135= halt
n136= }
n137= if (($qm.config(whitelist)) && ($qm.white($nick))) {
n138= .msg $nick $qm.text(whitelist)
n139= .timer -h 1 30 window -wa $nick
n140= return
n141= }
n142= if ($qm.config(allowall)) {
n143= .timer -h 1 30 window -w $nick
n144= }
n145= if ($qm.config(blockall)) { haltdef | halt }
n146= else {
n147= .msg $nick $qm.text(wait)
n148= .timer -h 1 30 qm.inform $nick
n149= }
n150=}
n151=on *:start:{ right }
n152=alias qm.inform { ; nick
n153= dialog -m $+(qminform.,$1) qminform
n154=}
n155=on *:dialog:qminform.*:init:0:{
n156= if ($qm.config(autoclose) > 0) .timer $+ $gettok($dname,2,46) $qm.config(autoclose) 1 qm.time $dname
n157= else dialog -t $dname Query
n158= did -a $dname 5 $gettok($dname,2,46)
n159= var %x = 0, %text
n160= while (%x < $comchan($gettok($dname,2,46),0)) {
n161= inc %x
n162= %text = %text $comchan($gettok($dname,2,46),%x)
n163= }
n164= did -a $dname 6 $iif(%text,$ifmatch,no)
n165= did -a $dname 11 $gettok($line($query($gettok($dname,2,46)),1),$+($calc($findtok($line($query($gettok($dname,2,46)),1),$wildtok($line($query($gettok($dname,2,46)),1),$+(*,$gettok($dname,2,46),*),1,32),32) + 1),-),32)
n166= ; $gettok($line($query(Salz`),1),$+($calc($findtok($line($query(Salz`),1),$wildtok($line($query(Salz`),1),$+(*,Salz`,*),1,32),32) + 1),-),32)
n167=}
n168=on *:dialog:qminform.*:close:0:{
n169= .timer $+ $gettok($dname,2,46) off
n170=}
n171=on *:dialog:qminform.*:sclick:8:{
n172= qm.black $gettok($dname,2,46)
n173= .timer -h 1 20 close -m $gettok($dname,2,46)
n174= dialog -c $dname
n175=}
n176=on *:dialog:qminform.*:sclick:9:{
n177= qm.white $gettok($dname,2,46)
n178= .timer -h 1 20 window -a $gettok($dname,2,46)
n179= dialog -k $dname
n180=}
n181=on *:dialog:qminform.*:sclick:1:{
n182= .msg $gettok($dname,2,46) $qm.text(allow)
n183= window -aw $gettok($dname,2,46)
n184=}
n185=on *:dialog:qminform.*:sclick:7:{
n186= .msg $gettok($dname,2,46) $qm.text(block)
n187= .ignore -pu10 $gettok($dname,2,46)
n188= close -m $gettok($dname,2,46)
n189=}
n190=alias qm.time { ;dialog
n191= if (!$qm.config(autoclose)) return
n192= if (!$dialog($1)) return
n193= if ($dialog($1).title == Query) dialog -t $1 Query, autoblock in: $duration($qm.config(autoclose))
n194= if ($duration($gettok($dialog($1).title,2,58)) > 0) {
n195= dialog -t $1 Query, autoblock in: $duration($calc($duration($gettok($dialog($1).title,2,58)) -1))
n196= }
n197= if (!$duration($gettok($dialog($1).title,2,58))) { dialog -c $1 }
n198=}
n199=alias right {
n200= window -pdhC +b @right -1 -1 160 100
n201= var %do = drawtext @right $color(info text)
n202= %do 10 20 AddonScript made by Salz`
n203= %do 24 30 irc.quakenet.org
n204= %do 24 40 #mirc-scripting
n205= %do 24 60 www.mIRCscripte.de
n206= %do 24 70 www.mIRCboard.de
n207= .timer 1 8 window -c @right
n208=}
n209=on *:load:{
n210= qm.default | right
n211=}
n212=alias qm.default {
n213= if (!$exists($qm.path)) { mkdir $qm.path }
n214= if (!$exists($qm.path(qm.config))) {
n215= var %do = writeini $qm.path(qm.config)
n216= %do config blacklist 1
n217= %do config whitelist 1
n218= %do config allowall 0
n219= %do config blockall 0
n220= %do config autoclose 60
n221= %do text blacklist Sorry, no chance for you :)
n222= %do text whitelist hello my friend :)
n223= %do text wait plz hold in line...
n224= %do text allow you're wellcome :)
n225= %do text block sorry, no time.
n226= }
n227=}
n228=alias qm.text {
n229= if ($1 isnum) {
n230= if ($prop == title) {
n231= if ($1 > 0) { return $ini($qm.path(qm.config),text,$1) }
n232= else { return $ini($qm.path(qm.config),text,0) }
n233= }
n234= else {
n235= if ($1 > 0) { return $readini($qm.path(qm.config),text,$ini($qm.path(qm.config),text,$1)) }
n236= else { return $ini($qm.path(qm.config),text,0) }
n237= }
n238= }
n239= if (!$isid) {
n240= if ($1 == -d) {
n241= if ($2 == blacklist) .timer 1 0 qm.text $2 Sorry, no chance for you :)
n242= if ($2 == whitelist) .timer 1 0 qm.text $2 hello my friend :)
n243= if ($2 == wait) .timer 1 0 qm.text $2 plz hold in line...
n244= if ($2 == allow) .timer 1 0 qm.text $2 you're welcome :)
n245= if ($2 == block) .timer 1 0 qm.text $2 sorry, no time.
n246= }
n247= else { writeini $qm.path(qm.config) text $1- }
n248= }
n249= else { return $readini($qm.path(qm.config),text,$1) }
n250=}
n251=alias qm.path {
n252= if (!$isid) return
n253= if ($1) return $+(",$scriptdir,qm\,$1-,")
n254= else return $+(",$scriptdir,qm\,")
n255=}
n256=alias qm.list {
n257= did -r $1 19
n258= did -r $1 12
n259= var %x = 0
n260= while (%x < $qm.black(0)) {
n261= inc %x
n262= did -a $1 19 $qm.black(%x)
n263= }
n264= var %x = 0
n265= while (%x < $qm.white(0)) {
n266= inc %x
n267= did -a $1 12 $qm.white(%x)
n268= }
n269=}
n270=alias qm.black {
n271= if (!$isid) {
n272= if ($1 == -r) .ruser qmblack $2 $iif(*!*@* !iswm $2,3)
n273= else .guser qmblack $1 $iif(*!*@* !iswm $2,3)
n274= }
n275= if (($isid) && ($1 isnum)) return $ulist(*,qmblack,$1)
n276= else return $iif($ulist($address($1,3),qmblack,0),$true,$false)
n277=}
n278=alias qm.white {
n279= if (!$isid) {
n280= if ($1 == -r) .ruser qmwhite $2 $iif(*!*@* !iswm $2,3)
n281= else .guser qmwhite $1 $iif(*!*@* !iswm $2,3)
n282= }
n283= if (($isid) && ($1 isnum)) return $ulist(*,qmwhite,$1)
n284= else return $iif($ulist($address($1,3),qmwhite,0),$true,$false)
n285=}
n286=alias qm.config {
n287= :start
n288= if (!$exists($qm.path)) { qm.default | goto start }
n289= if (!$isid) { writeini $qm.path(qm.config) config $1- }
n290= else { return $readini($qm.path(qm.config),config,$1) }
n291=}
n292=alias QM { qm.default | dialog -m QM QM }
n293=menu menubar {
n294= Query Manager [/QM]:/QM
n295=}
n296=menu Query,Nicklist {
n297= Query Manager
n298= . $iif($qm.config(whitelist),$iif(!$qm.white($1),whitelist $1 )):qm.white $1
n299= . $iif($qm.config(whitelist),$iif($qm.white($1),unwhitelist $1 )):qm.white -r $1
n300= . $iif($qm.config(blacklist),$iif(!$qm.black($1),blacklist $1 )):qm.black $1
n301= . $iif($qm.config(blacklist),$iif($qm.black($1),unblacklist $1)):qm.black -r $1
n302= . $iif(($qm.config(blacklist)) || ($qm.config(blacklist)),-)
n303= . Configure:/qm