Something

alias notepad {
  dialog -dm mnp mnp
  if ($1) {
    if ($exists($1)) {
      loadbuf 0 -o mnp 1 $1
      dialog -t mnp $1 - mIRC Notepad  
      did -a mnp 2 $1
    }
    else { 
      write $1 $chr(32)
      loadbuf 0 -o mnp 1 $1
      .remove $1  
      dialog -t mnp $1 - mIRC Notepad
      did -a mnp 2 $1  
    }
  }
}

dialog mnp {
  title "mIRC Notepad"
  size -1 -1 300 175
  option dbu 

  edit "" 1, 0 0 300 164, multi return autovs autohs hsbar vsbar 
  edit "" 2, 28 165 108 9
  edit "" 3, 174 165 124 9, disable
  text "File Name:" 4, 2 166 25 7
  text "File Extension:" 5, 138 166 35 7
  radio ".ini" 6, 176 166 15 7
  radio ".mrc" 7, 194 166 18 7
  radio ".txt" 8, 215 166 17 7
  radio ".doc" 9, 235 166 18 7
  radio ".log" 10, 256 166 17 7
  radio "none" 11, 276 166 20 7

  menu "File", 12
  item "New", 13
  item "Open...", 14
  item "Save", 15
  item "Save As...", 16
  item "Close", 17, ok

  menu "Name", 18
  item "Unlock", 19
  item "Lock", 20

  menu "Help", 21
  item "About", 22 
}

on *:dialog:mnp:edit:2:{
  dialog -t $dname $iif(!$did(2),mIRC Notepad,$did(2) - mIRC Notepad)
}

on *:dialog:mnp:sclick:6,7,8,9,10,11:{
  if ($did(2).enabled) { 
    var %ext = .ini,.mrc,.txt,.doc,.log 
    did -ra $dname 2 $rext($did(2)) $+ $gettok(%ext,$calc($did -5),44)
    dialog -t $dname $iif($did(2),$did(2) -) mIRC Notepad
  }
}

alias -l rext {
  return $remove($1-,.ini,.mrc,.txt,.doc,.log)
}

on *:dialog:mnp:menu:13:{
  did -ru $dname 1,2
  did -u $dname 6,7,8,9,10,11
  dialog -t $dname mIRC Notepad
}

on *:dialog:mnp:menu:14:{
  var %x = $$sfile(*.txt)
  did -r $dname 1
  did -a $dname 2 $nopath(%x)
  loadbuf 0 -o $dname 1 $qt(%x)
  dialog -t $dname $nopath(%x) - mIRC Notepad
}

on *:dialog:mnp:menu:15:{
  if (!$did(2)) { 
    var %x = $$sfile(*.txt)
    savebuf -o 1 $dname 1 $qt(%x)
    dialog -t $dname $nopath(%x) - mIRC Notepad
  }
  else { 
    savebuf -o 0 $dname 1 $qt($did(2))
  }
}

on *:dialog:mnp:menu:16:{
  var %x = $$sfile(*)
  savebuf -o 0 $dname 1 $qt(%x)
  dialog -t $dname $nopath(%x)
}

on *:dialog:mnp:menu:19:{
  did -e $dname 2
} 

on *:dialog:mnp:menu:20:{
  did -b $dname 2
}

on *:dialog:mnp:menu:22:{
  dialog -am mnph mnph
}

dialog mnph {
  title "Help"
  size -1 -1 62 35
  option dbu

  tab "About", 1, 0 0 62 35
  tab "Help", 2

  text "By Remy @ SwiftIRC" 3, 2 15 50 7, tab 1
  link "Join #Remy on SwiftIRC" 4, 2 22 59 7, tab 1

  link "Click Here For Help" 5, 2 15 50 7, tab 2
}

on *:dialog:mnph:sclick:4:{
  dialog -x $dname $dname 
  var %x = 1
  while (%x <= $scon(0)) {
    scon %x 
    if ($network == SwiftIRC) {
      join #remy
      halt 
    }
    inc %x 
  } 
  server -m irc.swiftirc.net -j #remy
}

on *:dialog:mnph:sclick:5:{
  did -r $left($dname,-1) 1
  loadbuf 0 -o $left($dname,-1) 1 mnpreadme.txt
  dialog -t $left($dname,-1) mnpreadme.txt - mIRC Notepad
  did -a mnp 2 mnpreadme.txt
  dialog -x $dname $dname
}