Mine

on *:TEXT:*:#:{
  if ($1 == !setgreet) {
    if (!$2) {
      if (!$hget(Greets,$nick)) {
        .notice $nick $c1(You do not currently have a greet set.)
      }
      else {
        hdel Greets $nick
        .notice $nick $c1(Your greet has been unset.)
      }
    }
    else {
      hadd Greets $nick $2-
      .notice $nick $c1(Your greet has been set to) $2-
    }
  }
  elseif ($1 == !greets) && ($istok(on off,$2,32)) && ($nick($chan,$nick,ho)) {
    if ($hget(Channels,$chan) == $2) {
      .notice $nick $c1(Greets are already) $c2($2) $c1(for) $c2($chan) $+ $c1(.)
    }
    else {
      hadd Channels $chan $2
      .notice $nick $c1(Greets are now) $c2($2) $c1(for) $c2($chan) $+ $c1(.)
    }
  }
}
on *:JOIN:#:{
  if ($nick == $me) {
    if (!$hget(Channels,$chan)) {
      hadd Channels $chan on
    }
  }
  else {
    if ($hget(Greets,$nick)) && ($hget(Channels,$chan) == on) {
      msg $chan $+($c2([),$c1($nick),$c2(])) $hget(Greets,$nick)
    }
  }
}
alias -l c1 { return $+(14,$1-,) }
alias -l c2 { return $+(07,$1-,) }
on *:START:{
  if (!$hget(Greets)) hmake Greets 100 | hload Greets Greets.tmp
  if (!$hget(Channels)) hmake Channels 100 | hload Channels Channels.tmp
}
on *:EXIT:{
  hsave -o Greets Greets.tmp
  hsave -o Channels Channels.tmp
}