Miscellany

public text v1 · immutable
#260980
·published 2006-11-28 20:57 UTC
on *:text:*:#: {
  VAR %lvlto = $Remove($MatchTok($2-,$Chr(35),1,32),$Chr(35))
  tokenize 32 $strip($deltok($1-,$findtok($1-,$matchtok($1-,$chr(35),1,32),1,32),32))
  if ($left($1,1) !isin @!.) halt
  if ($right($1,-1) == stats) var %style = astats
  elseif ($regex($1,/co?mb(at)?/Si)) var %style = combat
  elseif ($setskill($remove($1,@,!,.))) var %style = istat, %skill = $setskill($remove($1,@,!,.))
  elseif ($right($1,-1) == setrsn) && ($2) {
    if ($2 == -h) {
      writeini DefRSN.ini RSNs $mask($fulladdress,3) $replace($3-,$chr(32),-)
      .notice $nick You're default RSN for the host $mask($fulladdress,3) has been set to $3-
    }
    else {
      writeini DefRSN.ini RSNs $nick $replace($2-,$chr(32),-)
      .notice $nick You're default RSN for the nick $nick has been set to $2-
    }
    halt
  }
  else halt
  inc %ID

  if ($len($2-) > 12) {
    $($+(%,stats.display.,%ID),2) $c1(The nick) $c2($2-) $c1(is too long)
    cleanup %ID
    halt
  }
  elseif ($2) set $+(%,stats.rsn.,%ID) $replace($2-,$chr(32),-)
  elseif ($readini(DefRSN.ini,RSNs,$mask($fulladdress,3))) set $+(%,stats.rsn.,%ID) $ifmatch
  elseif ($readini(DefRSN.ini,RSNs,$nick)) set $+(%,stats.rsn.,%ID) $ifmatch
  elseif ($readini(DefRSN.ini,RSNs,$2 $+ *)) set $+(%,stats.rsn.,%ID) $ifmatch
  else set $+(%,stats.rsn.,%ID) $nick

  set $+(%,stats.style.,%ID) %style
  set $+(%,stats.skill.,%ID) %skill
  set $+(%,stats.display.,%ID) $iif($left($1,1) == @,msg $chan,notice $nick)
  if (%lvlto) set $+(%,stats.lvlto.,%ID) %lvlto

  sockopen $+(stats.,%ID) hiscore.runescape.com 80
}

on *:sockopen:stats.*: {
  var %id = $gettok($sockname,2,46)
  sockwrite -n $sockname GET /lang/en/aff/runescape/hiscorepersonal.ws?user1= $+ $($+(%,stats.rsn.,%ID),2) HTTP/1.0
  sockwrite -n $sockname Host: hiscore.runescape.com $+ $crlf $+ $crlf
}
on *:sockread:stats.*: {
  sockread &Incoming
  bwrite $sockname -1 -1 &Incoming
  if ($bfind(&Incoming, 1, </html>).text) makehash $sockname
  elseif ($bfind(&Incoming, 1, does not feature in the hiscores.).text) {
    $($+(%,stats.display.,%ID),2) $c1(The nick) $c2($($+(%,stats.rsn.,%ID),2)) $c1(Does not appear in the hiscores)
    cleanup $gettok($sockname,2,46)
  }
}

alias -l makehash {
  var %file = $1
  bread %file 1 $file(%file).size &stats
  var %currentstat, %x = 1
  while (%x) {
    var %x = $bfind(&stats,$calc(%x + 1),<a href="overall.ws?table=)
    var %currentstat = $striptags($bvar(&stats,%x,200).text)
    tokenize 10 %currentstat
    hadd -m %file $1 $2 $3 $4 $xp2next($3,$4)
  }
  process %file
}

alias -l process {
  var %table = $1, %id = $gettok($1,2,46), %x = 0, $&
    %display = $($+(%,stats.display.,%ID),2), $&
    %rsn = $($+(%,stats.rsn.,%ID),2), $&
    %skill = $($+(%,stats.skill.,%ID),2), $&
    %style = $($+(%,stats.style.,%ID),2), $&
    %lvlto = $($+(%,stats.lvlto.,%ID),2)

  if (%style == astats) {
    while (%x <= 23) {
      tokenize 32 $hget(%table,$setskill(%x))
      if ($2) var %statline = %statline $c1($setskill(%x)) $c2($2)
      inc %x
    }
    %display $c1(Stats for) $c2(%rsn) $+
    %display $c1(Combat) $c2 $calc($iif($gettok($hget(%table,attack),2,32),$v1,-) * .32707 + $iif($gettok($hget(%table,strength),2,32),$v1,-) * .324 + $iif($gettok($hget(%table,defence),2,32),$v1,-) * .25 + $iif($gettok($hget(%table,hitpoints),2,32),$v1,-) * .25 + $iif($gettok($hget(%table,prayer),2,32),$v1,-) * .124)
    %display %statline
  }
  elseif (%style == istat) {
    if (!$hget(%table,%skill)) %display $c1(The nick) $c2(%rsn) $c1(does not appear in the hiscores for) $c2(%skill)
    else {
      tokenize 32 $hget(%table,%skill)
      if (%lvlto) VAR %lvltoexp = $calc($xp(%lvlto) - $Remove($3,$Chr(44)))
      %display $c2(%skill) $c1(stats for) $c2(%rsn) $+
      %display $c1(Rank:) $c2($1) $c1(Level:) $c2($bytes($2,b)) $c1(Exp:) $c2($3) $&
        $iif(%skill != Overall,$c1(Exp to lvl) $c2($calc($2 + 1)) $+ $c1(:) $c2($bytes($4,b))) $&
        $iif(%lvlto,$c1(Exp to lvl) $c2(%lvlto) $+ $c1(:) $c2($bytes(%lvltoexp,b)))
      if ($istok(ranged strength defence attack,%skill,32)) %display $c1(Pc Points:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / ($calc(($bytes($2,b)) * ($bytes($2,b)))/6))),db)) $c1(Rock crabs:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 200)),db)) $c1(Fire Giants:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 444)),db)) $c1(Blue Dragons:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 428)),db))
      if (%skill == magic) %display $c1(Pc Points:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / ($calc(($bytes($2,b)) * ($bytes($2,b)))/6))),db)) $c1(Camelot telle:)  $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 55)),db)) $c1(stun:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 90)),db)) $c1(High Alch:)  $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 65)),db)) $c1(Crumble Undead:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 32)),db))
      if (%skill == prayer) %display $c1(Pc Points:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / ($calc(($bytes($2,b)) * ($bytes($2,b)))/12))),db)) $c1(Normal/Burnt/Wolf:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 4.5)),db)) $c1(BabyDragonBones:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 30)),db)) $c1(Dragonbones:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 72)),db)) $c1(Dragonbones (G):) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 252)),db)) $c1(Dragonbones (E):) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 288)),db)) $c1(Wyvern Bones:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 50)),db)) $c1(Daggonoth Bones:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 125)),db))
      if (%skill == Hitpoints) %display $c1(Pc Points:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / ($calc(($bytes($2,b)) * ($bytes($2,b)))/6))),db))
      if (%skill == Fishing) %display $c1(Lobsters:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 90)),db)) $c1(Swordfish:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 100)),db)) $c1(Monkfish:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 120)),db)) $c1(Sharks:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 110)),db))
      if (%skill == Mining) %display $c1(Coal:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 50)),db)) $c1(Mithril Ore:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 80)),db)) $c1(Adamant Ore:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 95)),db)) $c1(Runite Ore:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 125)),db))
      if (%skill == Woodcutting) %display $c1(Maples:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 100)),db)) $c1(Yews:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 175)),db)) $c1(Magicks:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 250)),db)) 
      if (%skill == Cooking) %display $c1(Lobsters:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 120)),db)) $c1(Swordies:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 140)),db)) $c1(Monkfish:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 150)),db)) $c1(Sharks:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 210)),db))     
      if (%skill == Fletching) %display $c1(Maple Short:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 100)),db)) $c1(Maple Long:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 116.6)),db)) $c1(Yew Short:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 137)),db)) $c1(Yew Long:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 150)),db)) $c1(Magic Short:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 166.6)),db)) $c1(Magic Long:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 183)),db))
      if (%skill == Construction) %display $c1(Oak Planks:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 60)),db)) $c1(Teak Planks:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 90)),db)) $c1(Mahogany Planks:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 140)),db))
      if (%skill == Firemaking) %display $c1(Normal:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 40)),db)) $c1(Oak:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 60)),db)) $c1(Willow:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 90)),db)) $c1(Teak:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 105)),db)) $c1(Maple:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 135)),db)) $c1(Mahogany:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 157.5)),db)) $c1(Yew:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 202.5)),db)) $c1(Magic:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 303.8)),db)) 
      if (%skill == Agility) %display $c1(Gnome:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 86.5)),db)) $c1(Barbarian:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 139.5)),db)) $c1(Wildy:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 571)),db)) $c1(Werewolf:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 540)),db)) $c1(Monkey:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 580)),db))
      if (%skill == Herblore) %display $c1(Prayer:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 87.5)),db)) $c1(Super Attack:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 100)),db)) $c1(Super Strength:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 125)),db)) $c1(Super Restore:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 142.5)),db)) $c1(Super Defense:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 150)),db))
      if (%skill == Smithing) %display $c1(Bronze Bars:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 6)),db)) $c1(Iron Bars:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 12.5)),db)) $c1(Steel Bars:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 17.5)),db)) $c1(Mithril Bars:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 30)),db)) $c1(Adamantite Bars:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 37.5)),db)) $c1(Runite Bars:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 50)),db))
      if (%skill == Runecraft) %display $c1(Airs:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 5)),db)) $c1(Minds:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 5.5)),db)) $c1(Waters:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 6)),db)) $c1(Earths:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 6.5)),db)) $c1(Fires:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 7)),db)) $c1(Bodies:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 7.5)),db)) $c1(Cosmics:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 8)),db)) $c1(Chaos:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 8.5)),db)) $c1(Astrals:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 8.7)),db)) $c1(Natures:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 9)),db)) $c1(Laws:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 9.5)),db)) $c1(Deaths:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 10)),db))
      if (%skill == Crafting) %display $c1(Green Leather:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 62)),db)) $c1(Blue Leather:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 70)),db))  $c1(Red Leather:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 78)),db)) $c1(Black Leather:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 86)),db))
      if (%skill == Thieving) %display $c1(Man/Woman:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 8)),db)) $c1(Farmer:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 14)),db)) $c1(Master Farmer:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 43)),db)) $c1(Guard:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 46.8)),db)) $c1(Paladin:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 151.8)),db)) $c1(Heroes:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 273.3)),db)) $c1(Elf:) $c2($bytes($ceil($calc($iif(%lvlto,%lvltoexp,$4) / 353.3)),db))
    }
  }
  elseif (%style == combat) {
    var %a.mult = .32707, %s.mult = .324, %d.mult = .25, %h.mult = .25, %p.mult = .124, %r.mult = .487, %m.mult = .487
    var %a = $iif($gettok($hget(%table,attack),2,32),$v1,-), $&
      %s = $iif($gettok($hget(%table,strength),2,32),$v1,-), $&
      %d = $iif($gettok($hget(%table,defence),2,32),$v1,-), $&
      %h = $iif($gettok($hget(%table,hitpoints),2,32),$v1,-), $&
      %r = $iif($gettok($hget(%table,ranged),2,32),$v1,-), $&
      %m = $iif($gettok($hget(%table,magic),2,32),$v1,-), $&
      %p = $iif($gettok($hget(%table,prayer),2,32),$v1,-)

    var %meleecombat  = $calc(%a * %a.mult + %s * %s.mult + %d * %d.mult + %h * %h.mult + %p * %p.mult), $&
      %RangedCombat = $calc(%r * %r.mult + %p * %p.mult + %d * %d.mult + %h * %h.mult), $&
      %MagicCombat  = $calc(%m * %m.mult + %p * %p.mult + %d * %d.mult + %h * %h.mult)

    if (%MagicCombat == %RangedCombat) && (%MagicCombat == %RangedCombat) {
      %display $c1(The nick) $c2(%rsn) $c1(does not appear in the hiscores for any combat skills)
      cleanup %id
      halt
    }
    elseif (%MagicCombat > %RangedCombat) && (%MagicCombat > %MeleeCombat) var %cmbstyle = Magic, %Combat = %MagicCombat
    elseif (%RangedCombat > %MeleeCombat) var %cmbstyle = Ranged, %Combat = %RangedCombat
    else var %cmbstyle = melee, %combat = %MeleeCombat

    var %cmb.temp = $abs($calc($int($calc(%combat +1)) - %combat)), $&
      %a.2lvl = $ceil($calc(%cmb.temp / %a.mult)), %s.2lvl = $ceil($calc(%cmb.temp / %s.mult)), $&
      %d.2lvl = $ceil($calc(%cmb.temp / %d.mult)), %m.2lvl = $ceil($calc(%cmb.temp / %m.mult)), $&
      %r.2lvl = $ceil($calc(%cmb.temp / %r.mult)), %p.2lvl = $ceil($calc(%cmb.temp / %p.mult))

    if (%cmbstyle == magic) var %dynamic.2lvl = $c1(Magic:) $c2(%m.2lvl)
    elseif (%cmbstyle == Ranged) var %dynamic.2lvl = $c1(Ranged:) $c2(%r.2lvl)
    else var %dynamic.2lvl = $c1(Att:) $c2(%a.2lvl) $c1(Str:) $c2(%s.2lvl)
    var %combat = $round(%combat,2), %next = $ceil(%combat)

    %display $c2(%rsn) $c1(is) $c2(%combat) $c1(%cmbstyle style combat)
    %display $c1(Attack:) $c2(%a) $c1(Defence:) $c2(%d) $c1(Strength:) $c2(%s) $c1(Hits:) $c2(%h) $&
      $c1(Mage:) $c2(%m) $c1(Range:) $c2(%r) $c1(Pray:) $c2(%p)
    %display $c1(Levels for) $c2(%next) $+ $c1(:) %dynamic.2lvl $&
      $c1(Def/Hp:) $c2(%d.2lvl) $c1(Prayer:) $c2(%p.2lvl)
  }
  cleanup %id
}

alias -l cleanup {
  unset $+(%,stats.*.,$1)
  sockclose $+(Stats.,$1)
  .remove $+(Stats.,$1)
}

alias xp {
  var %x = 1, %level = $calc($1 - 1), %xp = 0
  while (%x <= %level) {
    var %TempXp = $calc((%x + 300 * 2^(%x / 7)) /4)
    inc %xp %TempXp
    inc %x
  }
  return $int(%xp)
}

alias -l xp2Next {
  var %xp = $remove($2,$chr(44)), %nextxp = $xp($calc($1 + 1))
  return $calc(%nextxp - %xp)
}

alias -l striptags { var %x,%y = $regsub($1-,/(<[^>]+>)/g,$null,%x) | return %x }
alias -l setskill {
  if ($1 == 0) || ($regex($1,/^(st|(skill)?total|overall)$/Si)) return Overall
  elseif ($1 == 1) || ($regex($1,/^at(t|k|tack)$/Si)) return Attack
  elseif ($1 == 2) || ($regex($1,/^def(en[cs]e)?$$/Si)) return Defence
  elseif ($1 == 3) || ($regex($1,/^str(ength)?$/Si)) return Strength
  elseif ($1 == 4) || ($regex($1,/^hp|hit(s|points?)?$/Si)) return Hitpoints
  elseif ($1 == 5) || ($regex($1,/^range(r|d|ing)?$/Si)) return Ranged
  elseif ($1 == 6) || ($regex($1,/^Pray(er)?$$/Si)) return Prayer
  elseif ($1 == 7) || ($regex($1,/^mag(e|ic)$$/Si)) return Magic
  elseif ($1 == 8) || ($regex($1,/^cook(ing)?$/Si)) return Cooking
  elseif ($1 == 9) || ($regex($1,/^wc|wood(cut(ting)?)?$/Si)) return Woodcutting
  elseif ($1 == 10) || ($regex($1,/^fletch(ing)?$/Si)) return Fletching
  elseif ($1 == 11) || ($regex($1,/^fish(ing)?$/Si)) return Fishing
  elseif ($1 == 12) || ($regex($1,/^(fire|fm)(make?(ing)?|ing)?$/Si)) return Firemaking
  elseif ($1 == 13) || ($regex($1,/^craft(ing)?$/Si)) return Crafting
  elseif ($1 == 14) || ($regex($1,/^(smith|smelt)(ing)?$/Si)) return Smithing
  elseif ($1 == 15) || ($regex($1,/^mine(ing)?$/Si)) return Mining
  elseif ($1 == 16) || ($regex($1,/^herb(law|lore)?$/Si)) return Herblore
  elseif ($1 == 17) || ($regex($1,/^agil(ity)?$/Si)) return Agility
  elseif ($1 == 18) || ($regex($1,/^(th(ei|ie)[fv](e|ing)?)$/Si)) return Thieving
  elseif ($1 == 19) || ($regex($1,/^slay(er|ing)?$/Si)) return Slayer
  elseif ($1 == 20) || ($regex($1,/^farm(er|ing)?$/Si)) return Farming
  elseif ($1 == 21) || ($regex($1,/^(rc|runecraft)(er|ing)?$/Si)) return Runecraft
  elseif ($1 == 22) || ($regex($1,/^poh|con(s|struct[ion]|ing)?$/Si)) return Construction
  elseif ($1 == 23) || ($regex($1,/^hunt(er|ing)?$/Si)) return Hunter
}