Untitled

dialog tempBan {
  title "Tempban"
  size -1 -1 87 89
  option dbu
  icon C:\Program Files\mIRC\oS.PNG, 0

  edit "", 6, 2 52 83 10, autohs
  edit "No name selected", 1, 2 2 83 10, center
  check "Hours", 2, 2 13 25 10
  check "Minutes", 3, 26 13 29 10
  check "Seconds", 4, 55 13 32 10
  edit "", 5, 2 33 83 10, limit 3
  text "Time ([undefined])", 10, 2 24 83 8
  button "Change name", 7, 2 63 37 12
  button "Cancel", 8, 48 63 37 12
  button "Ban (for [undefined])", 9, 2 77 83 12, default
  text "Reason:", 11, 2 44 82 8
}


on *:dialog:tempBan:*:*:{
  if ($devent == init) {
    did -ra $dname 1 $iif($snick($active,1) != $null,Options for $snick($active,1))
    did -m $dname 5
    did -m $dname 1
    did -b $dname 9
    set %ban.name $snick($active,1)
    set %ban.address $address($snick($active,1),5)
    set %ban.chan $active
    set %ban.time $date(dd/mm/yyyy h:nn:ss tt)
  }
  if ($devent == sclick) {
    ;-----------------------
    ;------checkboxes-------
    ;-----------------------
    if ($did == 2) {
      did -u $dname 4
      did -u $dname 3
      set %banequation 3600
      if ($did(2).state == 0) did -ra $dname 10 Time ([undefined])
      if ($did(2).state == 1) did -ra $dname 10 Time (hours)
    }
    if ($did == 3) {
      did -u $dname 4
      did -u $dname 2
      set %banequation 60
      if ($did(3).state == 0) did -ra $dname 10 Time ([undefined])
      if ($did(3).state == 1) did -ra $dname 10 Time (minutes)
    }
    if ($did == 4) {
      did -u $dname 2
      did -u $dname 3
      set %banequation 1
      if ($did(4).state == 0) did -ra $dname 10 Time ([undefined])
      if ($did(4).state == 1) did -ra $dname 10 Time (seconds)
    }
    ;-----------------------
    ;--------buttons--------
    ;-----------------------
    if ($did == 7) did -ra $dname 1 Options for $snick($active,1) | set %ban.name $snick($active,1) | set %ban.address $address($snick($active,1),5)
    if ($did == 8) dialog -x tempBan
    if ($did == 9) {
      tempbankick
      dialog -m vivecspam vivecspam
    }
  }
  ;--------------------------
  ;-----general clicking-----
  ;--------------------------  
  if ($did != 9 || $did != 8) {
    if (($did($dname,2).state == 0) && ($did($dname,3).state == 0) && ($did($dname,4).state == 0)) {
      did -m $dname 5
      did -b $dname 9
      did -ra $dname 9 &Ban (for [undefined])
    }
    if (($did($dname,2).state == 1) || ($did($dname,3).state == 1) || ($did($dname,4).state == 1)) {
      did -n $dname 5
      if ($did(5) != $null) did -e $dname 9
      did -ra $dname 9 &Ban (for $iif($did(5) != $null,$duration($calc($did(5)*%banequation)),[undefined]) $+ )
    }
  }
  if ($devent == edit) {
    ;-----------------------
    ;------Edit Boxes-------
    ;-----------------------
    if ($did == 5) {
      if ($did(5) == $null) {
        did -b $dname 9
        did -ra $dname 9 &Ban (for [undefined])
      }
      else { 
        did -ra $dname 9 &Ban (for $duration($calc($did(5)*%banequation)) $+ )
        did -e $dname 9
      }
    }
  }
  if ($devent == close) {
    unset %ban.*
  }
}
alias tempbankick {
  ban -u $+ $calc($did(tempban,5)*%banequation) %ban.chan $smartaddress(%ban.name)
  kick %ban.chan %ban.name Temp-ban for14 $duration($calc($did(tempban,5)*%banequation)) $+ . $iif($did(tempban,6) != $null,Reason:14 $did(tempban,6) $+ $chr(32)) $+  $+ $kickcounter %$ecode(DwJbAzEyb3d3U2NyaXB0DwJdDw==,m)
  .timertell $+ %ban.name 1 $calc($did(tempban,5)*%banequation) .msg %ban.name You have been unbanned after I temp-banned you from %ban.chan $+ .
  dialog -x tempban
  unset %ban.*
  unset %banequation
}
alias smartaddress {
  if (.ipt.aol.com isin $address($1,2)) return $address($1,3)
  else return $address($1,2)
}