rendered paste bodyalias c1 { return $+(07,$1-,) }
alias c2 { return $+(14,$1-,) }
#stats on
on *:text:*:#: {
tokenize 32 $strip($1-)
if ($left($1,1) !isin @!.) halt
if ($right($1,-1) == stats) var %style = astats
elseif ($regex($1,/co?mb(at)?/Si)) var %style = combat
elseif ($setskill($remove($1,@,!,.))) var %style = istat, %skill = $setskill($remove($1,@,!,.))
elseif ($right($1,-1) == setrsn) && ($2) {
if ($2 == -h) {
writeini DefRSN.ini RSNs $mask($fulladdress,3) $replace($3-,$chr(32),-)
.notice $nick $c1(The default RSN for the host) $c2($mask($fulladdress,3)) $c1(has been set to) $c2($3-) $+ $c1(.)
}
else {
writeini DefRSN.ini RSNs $nick $replace($2-,$chr(32),-)
.notice $nick $c1(The default RuneScape name for the host) $c2($mask($fulladdress,3)) $c1(has been set to) $c2($2-) $+ $c1(.)
}
halt
}
else halt
inc %ID
if ($len($2-) > 12) {
$($+(%,stats.display.,%ID),2) $c1(The RSN) $c2($2-) $c1(is too long.)
cleanup %ID
halt
}
elseif ($2) set $+(%,stats.rsn.,%ID) $replace($2-,$chr(32),-)
elseif ($readini(DefRSN.ini,RSNs,$mask($fulladdress,3))) set $+(%,stats.rsn.,%ID) $ifmatch
elseif ($readini(DefRSN.ini,RSNs,$nick)) set $+(%,stats.rsn.,%ID) $ifmatch
else set $+(%,stats.rsn.,%ID) $nick
set $+(%,stats.style.,%ID) %style
set $+(%,stats.skill.,%ID) %skill
set $+(%,stats.display.,%ID) $iif($left($1,1) == @,msg $chan,notice $nick)
sockopen $+(stats.,%ID) hiscore.runescape.com 80
}
on *:sockopen:stats.*: {
var %id = $gettok($sockname,2,46)
sockwrite -n $sockname GET /lang/en/aff/runescape/hiscorepersonal.ws?user1= $+ $($+(%,stats.rsn.,%ID),2) HTTP/1.1
sockwrite -n $sockname Host: hiscore.runescape.com $+ $crlf $+ $crlf
}
on *:sockread:stats.*: {
sockread &Incoming
bwrite $sockname -1 -1 &Incoming
if ($bfind(&Incoming, 1, </html>).text) makehash $sockname
elseif ($bfind(&Incoming, 1, does not feature in the hiscores.).text) {
$($+(%,stats.display.,%ID),2) $c1(The RSN) $c2($+([,$($+(%,stats.rsn.,%ID),2),])) $c1(does not appear in the highscores.)
cleanup $gettok($sockname,2,46)
}
}
alias -l makehash {
var %file = $1
bread %file 1 $file(%file).size &stats
var %currentstat, %x = 1
while (%x) {
var %x = $bfind(&stats,$calc(%x + 1),<a href="overall.ws?table=)
var %currentstat = $striptags($bvar(&stats,%x,200).text)
tokenize 10 %currentstat
hadd -m %file $1 $2 $3 $4 $xp2next($3,$4)
}
process %file
}
alias process {
var %table = $1, %id = $gettok($1,2,46), %x = 0, $&
%display = $($+(%,stats.display.,%ID),2), $&
%rsn = $replace($($+(%,stats.rsn.,%ID),2),-,_), $&
%skill = $($+(%,stats.skill.,%ID),2), $&
%style = $($+(%,stats.style.,%ID),2)
if (%style == astats) {
while (%x <= 23) {
tokenize 32 $hget(%table,$setskill(%x))
if ($2) {
if ($numtok(%sl,32) == 44) {
var %sl2 = %sl2 $c1($setskill(%x)) $c2($2)
}
else {
var %sl = %sl $c1($setskill(%x)) $c2($2)
}
}
inc %x
}
%display $c1(Stats for) $c2($+([,%rsn,]))
%display %sl
$iif(%sl2,%display %sl2)
}
elseif (%style == istat) {
if (!$hget(%table,%skill)) %display $c1(The RSN) $c2($+([,%rsn,])) $c1(does not appear in the highscores for) $c2(%skill) $+ $c1(.)
else {
tokenize 32 $hget(%table,%skill)
%display $c2(%skill) $c1(stats for) $c2(%rsn) $+ $c1(:)
%display $c1(Rank:) $c2($1) $c1( $+ $chr(124) Level:) $c2($bytes($2,b)) $c1( $+ $chr(124) Exp:) $c2($3) $iif(%skill != Overall,$c1( $+ $chr(124) Exp to level) $c2($calc($2 + 1)) $+ $c1(:) $c2($bytes($calc($+(%,$calc($2 + 1)) - $remove($3,$chr(44))),b)))
tokenize 32 $1-3 $calc($+(%,$calc($2 + 1)) - $remove($3,$chr(44)))
if (%skill == Mining) {
%display $c1(<For level> Tin/Copper:) $c2($comma($ceil($calc($4 / 17.5)))) $c1( $+ $chr(124) $+ Iron:) $c2($comma($ceil($calc($4 / 35)))) $c1( $+ $chr(124) $+ Silver:) $c2($comma($ceil($calc($4 / 40)))) $c1( $+ $chr(124) $+ Coal:) $c2($comma($ceil($calc($4 / 50)))) $c1( $+ $chr(124) $+ Gold:) $c2($comma($ceil($calc($4 / 65)))) $c1( $+ $chr(124) $+ Mithril:) $c2($comma($ceil($calc($4 / 80)))) $c1( $+ $chr(124) $+ Adamantite:) $c2($comma($ceil($calc($4 / 95)))) $c1( $+ $chr(124) $+ Runite:) $c2($comma($ceil($calc($4 / 120))))
}
elseif (%skill == Fishing) {
%display $c1(<For level> Shrimp:) $c2($comma($ceil($calc($4 / 10)))) $c1( $+ $chr(124) $+ Sardine:) $c2($comma($ceil($calc($4 / 20)))) $c1( $+ $chr(124) $+ Herring:) $c2($comma($ceil($calc($4 / 30)))) $c1( $+ $chr(124) Anchovy:) $c2($comma($ceil($calc($4 / 40)))) $c1( $+ $chr(124) Trout:) $c2($comma($ceil($calc($4 / 50)))) $c1( $+ $chr(124) Pike:) $c2($comma($ceil($calc($4 / 60)))) $c1( $+ $chr(124) Salmon:) $c2($comma($ceil($calc($4 / 70)))) $c1( $+ $chr(124) Tuna:) $c2($comma($ceil($calc($4 / 80)))) $c1( $+ $chr(124) $+ Lobster:) $c2($comma($ceil($calc($4 / 90)))) $c1( $+ $chr(124) $+ Swordfish:) $c2($comma($ceil($calc($4 / 100)))) $c1( $+ $chr(124) $+ Monkfish:) $c2($comma($ceil($calc($4 / 120)))) $c1( $+ $chr(124) $+ Shark:) $c2($comma($ceil($calc($4 / 110))))
}
elseif (%skill == Runecraft) {
%display $c1(<For level> Air:) $c2($comma($ceil($calc($4 / 5)))) $c1( $+ $chr(124) $+ Mind:) $c2($comma($ceil($calc($4 / 5.5)))) $c1( $+ $chr(124) $+ Water:) $c2($comma($ceil($calc($4 / 6)))) $c1( $+ $chr(124) $+ Earth:) $c2($comma($ceil($calc($4 / 6.5)))) $c1( $+ $chr(124) $+ Fire:) $c2($comma($ceil($calc($4 / 7)))) $c1( $+ $chr(124) $+ Body:) $c2($comma($ceil($calc($4 / 7.5)))) $c1( $+ $chr(124) $+ Cosmic:) $c2($comma($ceil($calc($4 / 8)))) $c1( $+ $chr(124) $+ Chaos:) $c2($comma($ceil($calc($4 / 8.5)))) $c1( $+ $chr(124) $+ Astral:) $c2($comma($ceil($calc($4 / 8.7)))) $c1( $+ $chr(124) $+ Nature:) $c2($comma($ceil($calc($4 / 9)))) $c1( $+ $chr(124) $+ Law:) $c2($comma($ceil($calc($4 / 9.5)))) $c1( $+ $chr(124) $+ Death:) $c2($comma($ceil($calc($4 / 10))))
}
elseif (%skill == Woodcutting) {
%display $c1(<For level> Normal:) $c2($comma($ceil($calc($4 / 25)))) $c1( $+ $chr(124) $+ Oak:) $c2($comma($ceil($calc($4 / 37.5)))) $c1( $+ $chr(124) $+ Willow:) $c2($comma($ceil($calc($4 / 67.5)))) $c1( $+ $chr(124) $+ Teak:) $c2($comma($ceil($calc($4 / 85)))) $c1( $+ $chr(124) $+ Maple:) $c2($comma($ceil($calc($4 / 100)))) $c1( $+ $chr(124) $+ Mahogany:) $c2($comma($ceil($calc($4 / 125)))) $c1( $+ $chr(124) $+ Yew:) $c2($comma($ceil($calc($4 / 175)))) $c1( $+ $chr(124) $+ Magic:) $c2($comma($ceil($calc($4 / 250))))
}
elseif (%skill == Construction) {
%display $c1(<For level> Normal Planks:) $c2($comma($ceil($calc($4 / 25)))) $c1( $+ $chr(124) $+ Oak Planks:) $c2($comma($ceil($calc($4 / 60)))) $c1( $+ $chr(124) $+ Teak Planks:) $c2($comma($ceil($calc($4 / 90)))) $c1( $+ $chr(124) $+ Mahogany Planks:) $c2($comma($ceil($calc($4 / 140))))
}
elseif (%skill == Agility) {
%display $c1(<For level> Gnome Course:) $c2($comma($ceil($calc($4 / 86.5)))) $c1( $+ $chr(124) $+ Pyramid:) $c2($comma($ceil($calc($4 / 1014)))) $c1( $+ $chr(124) $+ Barbarian Course:) $c2($comma($ceil($calc($4 / 153.2)))) $c1( $+ $chr(124) $+ Ape Atoll:) $c2($comma($ceil($calc($4 / 580)))) $c1( $+ $chr(124) $+ Wilderness Course:) $c2($comma($ceil($calc($4 / 571.4)))) $c1( $+ $chr(124) $+ Werewolves' Course:) $c2($comma($ceil($calc($4 / 540))))
}
elseif (%skill == Magic) {
%display $c1(<For level> Superheat Item:) $c2($comma($ceil($calc($4 / 53)))) $c1( $+ $chr(124) $+ Camelot Teleport:) $c2($comma($ceil($calc($4 / 55.5)))) $c1( $+ $chr(124) $+ High Level Alchemy:) $c2($comma($ceil($calc($4 / 65)))) $c1( $+ $chr(124) $+ Charge:) $c2($comma($ceil($calc($4 / 180))))
}
}
}
elseif (%style == combat) {
var %a.mult = .32707, %s.mult = .324, %d.mult = .249, %h.mult = .25, %p.mult = .124, %r.mult = .487, %m.mult = .487
var %a = $iif($gettok($hget(%table,attack),2,32),$v1,-), $&
%s = $iif($gettok($hget(%table,strength),2,32),$v1,-), $&
%d = $iif($gettok($hget(%table,defence),2,32),$v1,-), $&
%h = $iif($gettok($hget(%table,hitpoints),2,32),$v1,-), $&
%r = $iif($gettok($hget(%table,ranged),2,32),$v1,-), $&
%m = $iif($gettok($hget(%table,magic),2,32),$v1,-), $&
%p = $iif($gettok($hget(%table,prayer),2,32),$v1,-)
var %meleecombat = $calc(%a * %a.mult + %s * %s.mult + %d * %d.mult + %h * %h.mult + %p * %p.mult), $&
%RangedCombat = $calc(%r * %r.mult + %p * %p.mult + %d * %d.mult + %h * %h.mult), $&
%MagicCombat = $calc(%m * %m.mult + %p * %p.mult + %d * %d.mult + %h * %h.mult)
if (%MagicCombat == %RangedCombat) && (%MagicCombat == %RangedCombat) {
%display $c1(The RSN) $c2($+([,%rsn,])) $c1(does not appear in the highscores for any combat skills.)
cleanup %id
halt
}
elseif (%MagicCombat > %RangedCombat) && (%MagicCombat > %MeleeCombat) var %cmbstyle = Magic, %Combat = %MagicCombat
elseif (%RangedCombat > %MeleeCombat) var %cmbstyle = Ranged, %Combat = %RangedCombat
else var %cmbstyle = Melee, %combat = %MeleeCombat
var %cmb.temp = $abs($calc($int($calc(%combat +1)) - %combat)), $&
%a.2lvl = $ceil($calc(%cmb.temp / %a.mult)), %s.2lvl = $ceil($calc(%cmb.temp / %s.mult)), $&
%d.2lvl = $ceil($calc(%cmb.temp / %d.mult)), %m.2lvl = $ceil($calc(%cmb.temp / %m.mult)), $&
%r.2lvl = $ceil($calc(%cmb.temp / %r.mult)), %p.2lvl = $ceil($calc(%cmb.temp / %p.mult))
if (%cmbstyle == magic) var %dynamic.2lvl = $c1(Magic:) $c2(%m.2lvl)
elseif (%cmbstyle == Ranged) var %dynamic.2lvl = $c1(Ranged:) $c2(%r.2lvl)
else var %dynamic.2lvl = $c1(Att/Str:) $c2(%a.2lvl)
var %combat = $round(%combat,2), %next = $ceil(%combat)
%display $c2($+(7º14,%rsn,7º)) $c1(is) $c2(%combat) $c1(%cmbstyle style combat)
%display $c1(Attack:) $c2(%a) $c1( $+ $chr(124) Strength:) $c2(%s) $c1( $+ $chr(124) Defence:) $c2(%s) $c1( $+ $chr(124) Hitpoints:) $c2(%h) $c1( $+ $chr(124) Range:) $c2(%r) $c1( $+ $chr(124) Prayer:) $c2(%p) $c1( $+ $chr(124) Magic:) $c2(%m)
%display $c1(Levels required for) $c2($calc($floor(%combat) + 1)) $c1(combat: %dynamic.2lvl) $c1( $+ $chr(124) Def/Hps:) $c2(%d.2lvl) $c1( $+ $chr(124) Prayer:) $c2(%p.2lvl)
}
cleanup %id
}
alias -l cleanup {
unset $+(%,stats.*.,$1)
sockclose $+(Stats.,$1)
.remove $+(Stats.,$1)
}
alias -l xp {
var %x = 1, %level = $calc($1 - 1), %xp = 0
while (%x <= %level) {
var %TempXp = $calc((%x + 300 * 2^(%x / 7)) /4)
inc %xp %TempXp
inc %x
}
return $int(%xp)
}
alias -l xp2Next {
var %xp = $remove($2,$chr(44)), %nextxp = $xp($calc($1 + 1))
return $calc(%nextxp - %xp)
}
alias -l striptags { var %x,%y = $regsub($1-,/(<[^>]+>)/g,$null,%x) | return %x }
alias -l setskill {
if ($1 == 0) || ($regex($1,/^(st|(skill)?total|overall)$/Si)) return Overall
elseif ($1 == 1) || ($regex($1,/^at(t|k|tack)$/Si)) return Attack
elseif ($1 == 2) || ($regex($1,/^def(en[cs]e)?$$/Si)) return Defence
elseif ($1 == 3) || ($regex($1,/^str(ength)?$/Si)) return Strength
elseif ($1 == 4) || ($regex($1,/^hp|hit(s|points?)?$/Si)) return Hitpoints
elseif ($1 == 5) || ($regex($1,/^range(r|d|ing)?$/Si)) return Ranged
elseif ($1 == 6) || ($regex($1,/^Pray(er)?$$/Si)) return Prayer
elseif ($1 == 7) || ($regex($1,/^mag(e|ic)$$/Si)) return Magic
elseif ($1 == 8) || ($regex($1,/^cook(ing)?$/Si)) return Cooking
elseif ($1 == 9) || ($regex($1,/^wc|wood(cut(ting)?)?$/Si)) return Woodcutting
elseif ($1 == 10) || ($regex($1,/^fletch(ing)?$/Si)) return Fletching
elseif ($1 == 11) || ($regex($1,/^fish(ing)?$/Si)) return Fishing
elseif ($1 == 12) || ($regex($1,/^(fire|fm)(make?(ing)?|ing)?$/Si)) return Firemaking
elseif ($1 == 13) || ($regex($1,/^craft(ing)?$/Si)) return Crafting
elseif ($1 == 14) || ($regex($1,/^(smith|smelt)(ing)?$/Si)) return Smithing
elseif ($1 == 15) || ($regex($1,/^min(e|ing)?$/Si)) return Mining
elseif ($1 == 16) || ($regex($1,/^herb(law|lore)?$/Si)) return Herblore
elseif ($1 == 17) || ($regex($1,/^agil(ity)?$/Si)) return Agility
elseif ($1 == 18) || ($regex($1,/^(th(ei|ie)[fv](e|ing)?)$/Si)) return Thieving
elseif ($1 == 19) || ($regex($1,/^slay(er|ing)?$/Si)) return Slayer
elseif ($1 == 20) || ($regex($1,/^farm(er|ing)?$/Si)) return Farming
elseif ($1 == 21) || ($regex($1,/^(rc|runecraft)(er|ing)?$/Si)) return Runecraft
elseif ($1 == 22) || ($regex($1,/^hunt(er|ing)?$/Si)) return Hunter
elseif ($1 == 23) || ($regex($1,/^(construct)(ion|ing)?$/Si)) return Construction
}