Notepad2 Replace Restore For Wi

@echo off
REM ------------------------------------------------------------------
REM Notepad2 Replace & Restore For Windows 32bit & 64bit Batch Script
REM v1.0 2011-05-16 By: /underlines/@/gmail/./com/
REM ------------------------------------------------------------------

REM ------------------------------------------------------------------
REM ----------------------Kill Notepad Process

    taskkill /F /IM notepad.exe

REM ------------------------------------------------------------------
REM ----------------------Plattform Check

    if exist checkOS.txt del /F /Q checkOS.txt
    if exist StringCheck.txt del /F /Q StringCheck.txt

    Set RegQry=HKLM\Hardware\Description\System\CentralProcessor\0
    REG.exe Query %RegQry% > checkOS.txt
    Find /i "x86" < CheckOS.txt > StringCheck.txt
    If %ERRORLEVEL% == 0 (
      goto INSTALL32
    ) ELSE (
      goto INSTALL64
    )



REM ------------------------------------------------------------------
REM ----------------------64 Bit Install
:INSTALL64

    if exist c:\windows\syswow64\notepad.exe.backup goto RESTORE64

    echo Notepad2.exe for 64Bit Windows will be installed
    echo Press any key to continue
    pause

    takeown /f c:\windows\syswow64\notepad.exe
    ECHO Y| cacls c:\windows\syswow64\notepad.exe /G Administrators:F

    takeown /f c:\windows\system32\notepad.exe
    ECHO Y| cacls c:\windows\system32\notepad.exe /G Administrators:F

    takeown /f c:\windows\notepad.exe
    ECHO Y| cacls c:\windows\notepad.exe /G Administrators:F

    copy c:\windows\syswow64\notepad.exe c:\windows\syswow64\notepad.exe.backup
    copy c:\windows\system32\notepad.exe c:\windows\system32\notepad.exe.backup
    copy c:\windows\notepad.exe c:\windows\notepad.exe.backup

    copy Notepad2.exe c:\windows\syswow64\notepad.exe
    copy Notepad2.exe c:\windows\system32\notepad.exe
    copy Notepad2.exe c:\windows\notepad.exe

    goto END

REM ------------------------------------------------------------------
REM ----------------------64 Bit Restore
:RESTORE64

    echo Restore original notepad.exe for 64Bit Windows
    echo Press any key to continue
    pause

    takeown /f c:\windows\syswow64\notepad.exe
    takeown /f c:\windows\system32\notepad.exe
    takeown /f c:\windows\notepad.exe

    copy /Y c:\windows\syswow64\notepad.exe.backup c:\windows\syswow64\notepad.exe
    copy /Y c:\windows\system32\notepad.exe.backup c:\windows\system32\notepad.exe
    copy /Y c:\windows\notepad.exe.backup c:\windows\notepad.exe

    del /F /Q c:\windows\syswow64\notepad.exe.backup
    del /F /Q c:\windows\system32\notepad.exe.backup
    del /F /Q c:\windows\notepad.exe.backup

    goto END

REM ------------------------------------------------------------------
REM ----------------------32 Bit Install
:INSTALL32

    if exist c:\windows\system32\notepad.exe.backup goto RESTORE32

    echo Notepad2.exe for 32Bit Windows will be installed
    echo Press any key to continue
    pause


    takeown /f c:\windows\system32\notepad.exe
    ECHO Y| cacls c:\windows\system32\notepad.exe /G Administrators:F

    takeown /f c:\windows\notepad.exe
    ECHO Y| cacls c:\windows\notepad.exe /G Administrators:F

    copy c:\windows\system32\notepad.exe c:\windows\system32\notepad.exe.backup
    copy c:\windows\notepad.exe c:\windows\notepad.exe.backup

    copy Notepad2.exe c:\windows\system32\notepad.exe
    copy Notepad2.exe c:\windows\notepad.exe

    goto END

REM ------------------------------------------------------------------
REM ----------------------32 Bit Restore
:RESTORE32

    echo Restore original notepad.exe for 32Bit Windows
    echo Press any key to continue
    pause


    takeown /f c:\windows\system32\notepad.exe
    takeown /f c:\windows\notepad.exe

    copy /Y c:\windows\system32\notepad.exe.backup c:\windows\system32\notepad.exe
    copy /Y c:\windows\notepad.exe.backup c:\windows\notepad.exe
    del /F /Q c:\windows\system32\notepad.exe.backup
    del /F /Q c:\windows\notepad.exe.backup

    goto END

REM ------------------------------------------------------------------
REM ----------------------End
:END

    if exist checkOS.txt del /F /Q checkOS.txt
    if exist StringCheck.txt del /F /Q StringCheck.txt

    echo Done
    pause