Miscellany

# Copyright 1999-2006 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2
# $Header: /var/cvsroot/gentoo-x86/net-libs/libtorrent/libtorrent-0.10.1.ebuild,v 1.1 2006/08/31 07:36:40 flameeyes Exp $

inherit eutils toolchain-funcs flag-o-matic libtool

DESCRIPTION="LibTorrent is a BitTorrent library written in C++ for *nix."
HOMEPAGE="http://libtorrent.rakshasa.no/"
SRC_URI="http://libtorrent.rakshasa.no/downloads/${P}.tar.gz"
SLOT="0"
LICENSE="GPL-2"
KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"

IUSE="debug"

RDEPEND=">=dev-libs/libsigc++-2"

DEPEND="${RDEPEND}
        >=dev-util/pkgconfig-0.11"

src_unpack() {
        unpack ${A}
        cd "${S}"

        epatch "${FILESDIR}/new_peer_id.patch"
}

src_compile() {
        [[ $(tc-arch) = "x86" ]] && filter-flags -fomit-frame-pointer
        replace-flags -Os -O2

        elibtoolize
        econf \
                $(use_enable debug) \
                --disable-dependency-tracking \
                || die "econf failed"

        emake || die "emake failed"
}

src_install() {
        emake DESTDIR="${D}" install || die "make install failed"
        dodoc AUTHORS ChangeLog NEWS README TODO
}