Miscellany

alias F10 startaltscripts
alias startaltscripts dialog -m altscripts altscripts
dialog altscripts {
  title "AltScripts Info"
  size -1 -1 150 111
  option dbu
  text "AltScripts Information", 1, 1 3 148 9, center
  tab "  Stats  ", 2, 1 10 149 100
  text "", 5, 4 25 140 8, tab 2
  text "", 6, 4 34 140 8, tab 2
  text "", 7, 4 43 140 8, tab 2
  text "", 8, 4 52 140 8, tab 2
  text "", 9, 4 61 140 8, tab 2
  text "", 10, 4 70 140 8, tab 2
  text "", 14, 4 79 140 8, tab 2
  tab "   News  ", 3
  edit "", 12, 4 25 140 69, tab 3, read multi autovs vsbar
  link "Newest Post", 13, 58 95 30 6, tab 3
  tab "Users Online", 4
  text "", 15, 4 25 140 8, tab 4 center
  list 16, 4 45 143 69, tab 4
  text "Active Users", 17, 4 34 140 10, tab 4 center
  tab "Top Posters", 18
  text "", 11, 25 30 71 75, tab 18
  text "", 19, 102 30 30 75, tab 18, right
  text "All information here-in is gathered from AltScripts", 20, 4 95 142 8, tab 2,center
}

on *:DIALOG:altscripts:init:*:{
  sockopen altstats www.altscripts.trap17.com 80
  sockopen bnews www.altscripts.trap17.com 80
}
on *:DIALOG:altscripts:sclick:13:{
  run %temp.link.4.da.script
}
on *:SOCKOPEN:altStats:{
  sockwrite -n $sockname GET /forum/index.php?action=stats  HTTP/1.1
  sockwrite -n $sockname Host: www.altscripts.trap17.com $+ $crlf $+ $crlf
}
on *:SOCKREAD:altStats:{
  var %result | sockread -f %result
  set %pers.result $remove($htmlfree(%result),$chr(9))
  if (Average registrations per day: == %pers.result) {
    sockread -f %pers.result
    did -ra altscripts 5 Average registrations per day: $remove($htmlfree(%pers.result),$chr(9))
  }
  if (Average online per day: == %pers.result) {
    if (%pers.online != done) {
      sockread -f %pers.result
      did -ra altscripts 6 Average online per day: $remove($htmlfree(%pers.result),$chr(9))
      set %pers.online done
    }
  }
  if (Average posts per day: == %pers.result) {
    sockread -f %pers.result
    did -ra altscripts 7 Average posts per day: $remove($htmlfree(%pers.result),$chr(9))
  }
  if (Average topics per day: == %pers.result) {
    sockread -f %pers.result
    did -ra altscripts 8 Average topics per day: $remove($htmlfree(%pers.result),$chr(9))
  }
  if (Latest Member: == %pers.result) {
    sockread -f %pers.result
    did -ra altscripts 9 Latest Member: $remove($htmlfree(%pers.result),$chr(9))
  }
  if (Male to Female Ratio: == %pers.result) {
    sockread -f %pers.result
    did -ra altscripts 10 Male to Female Ratio: $remove($htmlfree(%pers.result),$chr(9))
  }
  if (*<td width="60%" valign="top">* iswm %result) {
    if (%pers.counter != $null) { inc %pers.counter 1 | set %pers.mem.line %pers.mem.line %pers.counter $+ $chr(41) $remove($htmlfree(%result),$chr(9)) $crlf }
    if (%pers.counter == $null) { set %pers.counter 1 | set %pers.mem.line Top Posters: $crlf %pers.counter $+ $chr(41) $remove($htmlfree(%result),$chr(9)) $crlf }
    if (%pers.counter == 10) {
      tokenize 32 %pers.mem.line
      var %o = 0
      while (%o < $0) {
        inc %o 1
        if (%o == $0) {
          set %pers.mem.done %pers.mem.done $replace($ [ $+ [ %o ] ],$chr(44),.)
          continue
        }
        set %pers.mem.done %pers.mem.done $ [ $+ [ %o ] ]
      }
    }
  }
  if (*<td width="20%" align="right" valign="top">*</td>* iswm %result) {
    if (%post.counter != $null) { inc %post.counter 1 | set %pers.post.line %pers.post.line $remove($htmlfree(%result),$chr(9)) $crlf }
    if (%post.counter == $null) { set %post.counter 1 | set %pers.post.line Posts: $crlf $remove($htmlfree(%result),$chr(9)) $crlf }
    if (%post.counter == 10) {
      tokenize 32 %pers.post.line
      var %p = 0
      while (%p < $0) {
        inc %p 1
        if (%p == $0) {
          set %pers.post.done %pers.post.done $replace($ [ $+ [ %p ] ],$chr(44),.)
          continue
        }
        set %pers.post.done %pers.post.done $ [ $+ [ %p ] ]
      }

      did -ra altscripts 11 %pers.mem.done 
      did -ra altscripts 19 %pers.post.done 
      unset %pers.* 
      unset %post.*
      sockclose $sockname
    }
  }
}




alias htmlfree {
  var %x, %i = $regsub($1-,/(^[^<]*>|<[^>]*>|<[^>]*$)/g,$null,%x), %x = $remove(%x,&nbsp;)
  return %x
}




on *:SOCKOPEN:bnews:{
  sockwrite -n $sockname GET /forum/index.php  HTTP/1.1
  sockwrite -n $sockname Host: www.altscripts.trap17.com $+ $crlf $+ $crlf
}
on *:SOCKREAD:bnews:{
  var %result | sockread -f %result
  set %bnews.result $htmlfree(%result)
  set %mem1.result $remove($htmlfree(%result),$chr(9))
  if (function smfFooterHighlight(element, value) isin %mem1.result) { sockclose $sockname | unset %mem1.* | unset %bnews.* | halt }
  if ((%mem1.goahead == on) && (*Guest* iswm %mem1.result)) { did -ra altscripts 15 People Browsing AltScripts: %mem1.result $+ . }
  if ((%mem1.goahead == on) && (Users active in past 15 minutes:* iswm %mem1.result)) {
    set %mem1.result $replace(%mem1.result,:,$chr(32))
    tokenize 32 %mem1.result
    set %mem1.list $replace($7-,$chr(32),¿)
    tokenize 44 %mem1.list
    var %o = 0
    while (%o < $0) {
      inc %o 1
      did -a altscripts 16 $replace($ [ $+ [ %o ] ],¿,$chr(32))
    }
  }
  if (users online isin %mem1.result) { set %mem1.goahead on }
  var %sresult = $remove(%result,$chr(9))
  tokenize 32 %sresult
  if ($1-2 == Latest Post:) {
    set %bnews.link $remove(%sresult,Latest Post: &quot;<a href=")
    tokenize $asc(") %bnews.link
    set %temp.link.4.da.script $1
  }
  tokenize 32 %bnews.result
  if (*Posts in* iswm $1-3) {
    if (%bnews.goahead != $null) {
      did -ra altscripts 14 Overall: $remove($1,$chr(9)) posts, $4 topics, $7 members.
      tokenize 32 %bnews.var
      unset %bnews.goahead
      did -ra altscripts 12 Announcements: $qt($remove($1,$chr(32)) $2-)
    }
  } 
  if (%bnews.goahead == on) { set %bnews.var %bnews.var $replace(%bnews.result,$chr(9),$chr(32)) }
  if (Advanced search isin %bnews.result) { set %bnews.goahead on }
}