Someone

on $*:TEXT:/^[!@]ls$/Si:#teamscripty: {
  var %x 1
  while ($sock(ls. $+ %x)) inc %x
  sockopen $+(ls.,%x) runescape.com 80
  sockmark $+(ls.,%x) $iif($left($1,1) $+(=,=) @ && $istok($readini(botinfo.ini,n,IgnoreChannel,Channels),$chan,32) $+(=,=) $false,msg $chan,notice $nick) $+ ~ $+ $nick $+ ~ $+ : $+ ~ $+ :
}
on *:SOCKOPEN:ls.*: {
  sockwrite -nt $sockname GET /slj.ws?plugin=0&hires.x=106&hires.y=78 HTTP/1.1
  sockwrite -nt $sockname Host: runescape.com
  sockwrite -nt $sockname $crlf
}
on *:SOCKREAD:ls.*: {
  tokenize 126 $sock($sockname).mark
  var %read
  sockread %read
  if (LootShare isin %read) {
    if ($gettok(%read,2,44) == 0) {
      sockmark $sockname $gettok($sock($sockname).mark,1-3,126) $remove($gettok(%read,1,44),$+(e,$chr(40))) $+ ~ $+ $4
    }
    else {
      sockmark $sockname $sock($sockname).mark $remove($gettok(%read,1,44),$+(e,$chr(40)))
    }
  }
  elseif (</html> isin %read) {
    $1 *** $+([,$c1($2,LOOTSHARE),]:) $c2($2,F2P) $+ : $+ $remove($c1($3,$sorttok($3,32,n)),:) $chr(124) $c2($2,P2P) $+ : $+ $remove($c1($3,$sorttok($4,32,n)),:)
    sockclose $sockname
  }
}
on $*:TEXT:/^[!@]ge\b/Si:#teamscripty: {
  if ($chan == #godbot) && ($me != Godbot) { halt } 
  var %x 1
  while ($sock(ge. $+ %x)) inc %x
  sockopen $+(ge.,%x) itemdb-rs.runescape.com 80
  sockmark $+(ge.,%x) $iif($left($1,1) $+(=,=) @ && $istok($readini(botinfo.ini,n,IgnoreChannel,Channels),$chan,32) $+(=,=) $false,msg $chan,notice $nick) $+ ~ $+ $2- $+ ~ $+ $nick
}
on *:SOCKOPEN:ge.*: {
  tokenize 126 $sock($sockname).mark
  sockwrite -nt $sockname GET /results.ws?query=%22 $+ $2 $+ $+(%,22) $+ &price=all&members= HTTP/1.1
  sockwrite -nt $sockname Host: itemdb-rs.runescape.com
  sockwrite -nt $sockname $crlf
}
on *:SOCKREAD:ge.*: {
  tokenize 126 $sock($sockname).mark
  var %read
  sockread %read
  if (*items*matched*the*search*term* iswm %read) {
    if (*0 items matched the search term* iswm %read) {
      $1 *** $+([,$c1($3,GE),]:) $c2($3,There were no results found for) $qt($c1($3,$2)) $+ .
      sockclose $sockname
    }
    sockmark $sockname $sock($sockname).mark $+ ~ $+ $gettok(%read,2,32)
  }
  if ((create.gif isin %read) || (membership_benefits.gif isin %read)) && (!$9) {
    var %type $iif(Free game item !isin %read,[M])
    sockread %read
    sockread %read
    sockread %read
    var %name $htmlfree(%read)
    sockread %read
    var %price $htmlfree(%read)
    sockread %read
    var %change $htmlfree(%read)
    sockmark $sockname $sock($sockname).mark $+ ~ $+ $iif(%type,$+([,$c1($3,M),])) $c1($3,%Name) $+ : $c1($3,%price) $+($chr(40),$c2($3,Today) $+ : $c1($3,$iif(%change == 0,No gain/loss,$v1)),$chr(41)) $chr(124)
  }
  if (</body> isin %read) $1 *** $+([,$c1($3,GE),]:) $c2($3,Results) $+ : $c1($3,$4) $chr(124) $left($5-,-1)
}

on $*:TEXT:/^[!@]urban/Si:#teamscripty: {
  if ($chan == #godbot) && ($me != Godbot) { halt } 
  if ($2 == $null) {
    $iif($left($1,1) $+(=,=) @ && $istok($readini(botinfo.ini,n,IgnoreChannel,Channels),$chan,32) $+(=,=) $false,msg $chan,notice $nick) $+($chr(91),$c1($nick,Error),$chr(93),:) $c2($nick,You must specify a term to search for.)
    halt
  }
  var %x 1
  while ($sock(urban. $+ %x)) {
    inc %x
  }
  sockopen $+(urban.,%x) www.urbandictionary.com 80
  sockmark $+(urban.,%x) $iif($left($1,1) $+(=,=) @ && $istok($readini(botinfo.ini,n,IgnoreChannel,Channels),$chan,32) $+(=,=) $false,msg $chan,notice $nick) $+ ~ $+ $replace($2-,$chr(32),$chr(43)) $+ ~ $+ $nick
}
on *:SOCKOPEN:urban.*: {
  sockwrite -n $sockname GET /define.php?term= $+ $gettok($sock($sockname).mark,2,126) HTTP/1.1
  sockwrite -n $sockname Host: www.urbandictionary.com
  sockwrite -n $sockname $crlf
}
on *:SOCKREAD:urban.*: {
  var %read
  sockread %read
  if (*<div class='definition'>* iswm %read) {
    sockread %read
    $gettok($sock($sockname).mark,1,126) *** $+($chr(91),$c1($gettok($sock($sockname).mark,3,126),Urban),$chr(93),:) $c2($gettok($sock($sockname).mark,3,126),$replace($htmlfree(%read),&quot;,"))
    sockclose $sockname
  }
  if (*isn't defined* iswm %read) {
    $gettok($sock($sockname).mark,1,126) *** $+($chr(91),$c1($gettok($sock($sockname).mark,3,126),Error),$chr(93),:) $c2($gettok($sock($sockname).mark,3,126),The search) $qt($c1($gettok($sock($sockname).mark,3,126),$replace($gettok($sock($sockname).mark,2,126),+,$chr(32)))) $c2($gettok($sock($sockname).mark,3,126),returned no results.)
    sockclose $sockname
  }
}