Anonymous

on *:sockread:game.mp.client: {
  ;-----------Skirtukas butu 0x0a (10)-------------------
  :reread
  sockread -n &packet
  if (!$sockbr) { drawpic @game_mp | return }
  ;#  
  ;---------------daroma kas norima su gautu packetu &packet--------------------
  ;#
  goto $bvar(&packet,1)

  ;-------------------------------------------------------------------------------
  ;                 1  2  3   4  5    6   7
  ;1 - Add Object: 01-uID[2]-tID[2]-locX-locY
  :1
  var %tid $calc($bvar(&packet,4) * 256 + $bvar(&packet,5))
  var %uid $calc($bvar(&packet,2) * 256 + $bvar(&packet,3))
  drawpic -nc @game_mp $game.rt.coord($bvar(&packet,6),$bvar(&packet,7)) $game.mp.obj.id.rep(%tid) 
  ;##surasom i db info apie naujus objektus##
  hadd game_mp_cl_obj_type %uid %tid
  hadd game_mp_cl_obj_locx %uid $bvar(&packet,6)
  hadd game_mp_cl_obj_locy %uid $bvar(&packet,7)
  goto reread

  ;------------------------------------------------------------------------------
  ;                 1  2  3    4     5     6   7
  ;2: Move Object: 02-uID[2]-nLocX-nLocY-underObj[2]
  :2
  var %uid $calc($bvar(&packet,2) * 256 + $bvar(&packet,3))
  var %uoid $calc($bvar(&packet,6) * 256 + $bvar(&packet,7))
  drawpic -nc @game_mp $game.rt.coord($bvar(&packet,4),$bvar(&packet,5)) $game.mp.obj.id.rep($hget(game_mp_cl_obj_type,%uid))
  drawpic -nc @game_mp $game.rt.coord($hget(game_mp_cl_obj_locx,%uid),$hget(game_mp_cl_obj_locy,%uid)) $game.mp.obj.id.rep(%uoid)
  hadd game_mp_cl_obj_locx %uid $bvar(&packet,4)
  hadd game_mp_cl_obj_locy %uid $bvar(&packet,5)
  goto reread

  ;-------------------------------------------------------------------------------
  ;                        1  2  3    4  5    6     7     8   9
  ;3: Player Push Object: 03-puID[2]-uID[2]-nLocX-nLocY-underPL[2]
  :3
  var %uid $calc($bvar(&packet,4) * 256 + $bvar(&packet,5))
  var %pid $calc($bvar(&packet,2) * 256 + $bvar(&packet,3))
  var %uoid $calc($bvar(&packet,8) * 256 + $bvar(&packet,9))
  drawpic -nc @game_mp $game.rt.coord($bvar(&packet,6),$bvar(&packet,7)) $game.mp.obj.id.rep($hget(game_mp_cl_obj_type,%uid))
  drawpic -nc @game_mp $game.rt.coord($hget(game_mp_cl_obj_locx,%uid),$hget(game_mp_cl_obj_locy,%uid)) $game.mp.obj.id.rep($hget(game_mp_cl_obj_type,%pid))
  drawpic -nc @game_mp $game.rt.coord($hget(game_mp_cl_obj_locx,%pid),$hget(game_mp_cl_obj_locy,%pid)) $game.mp.obj.id.rep(%uid)
  hadd game_mp_cl_obj_locx %pid $hget(game_mp_cl_obj_locx,%uid)
  hadd game_mp_cl_obj_locy %pid $hget(game_mp_cl_obj_locy,%uid)
  hadd game_mp_cl_obj_locx %uid $bvar(&packet,6)
  hadd game_mp_cl_obj_locy %uid $bvar(&packet,7)
  goto reread

  ;-------------------------------------------------------------------------------
  ;                   1  2  3    4    5
  ;4: Change Object: 04-oID[2]-newtID[2]
  :4
  var %uid $calc($bvar(&packet,2) * 256 + $bvar(&packet,3))
  var %tid $calc($bvar(&packet,4) * 256 + $bvar(&packet,5))
  drawpic -nc @game_mp $game.rt.coord($hget(game_mp_cl_obj_locx,%uid),$hget(game_mp_cl_obj_locy,%uid)) $game.mp.obj.id.rep(%tid)
  hadd game_mp_cl_obj_type %uid %tid
  goto reread

  ;-------------------------------------------------------------------------------
  ;                   1  2  3   4   5 
  ;5: Delete Object: 05-oID[2]-underObj[2]
  :5
  var %uid $calc($bvar(&packet,2) * 256 + $bvar(&packet,3))
  var %uobj $calc($bvar(&packet,4) * 256 + $bvar(&packet,5))
  drawpic -nc @game_mp $game.rt.coord($hget(game_mp_cl_obj_locx,%uid),$hget(game_mp_cl_obj_locy,%uid)) $game.mp.obj.id.rep(%uobj)
  hdel game_mp_cl_obj_locx %uid
  hdel game_mp_cl_obj_locx %uid
  hdel game_mp_cl_obj_type %uid
  goto reread

  ;-------------------------------------------------------------------------------
  ;                 1
  ;6: Clear Arena: 06
  :6
  set %game.mp.myscore 0
  set %game.mp.moves 0
  if (!$window(@game_mp)) {
    window -pdk0 +t @game_mp -1 -1 650 516 
    game.increse.move
    game.mp.draw.connected.gui
  }
  game.set.loading
  var %x = 0
  while (%x < 480) {
    var %y = 0 
    while (%y < 480) {
      drawpic -nc @game_mp %x %y " $+ $scriptdirimg\bcg.png"
      var %y = %y + 30
    }
    var %x = %x + 30
  }
  goto reread

  ;-----------------------------------------------------------------------
  ;                   1
  ;7: Ball Selected: 07
  :7
  drawpic -c @game_mp 544 25 $game.mp.obj.id.rep($bvar(&packet,2))
  set %game.ball.id $bvar(&packet,2)
  goto reread

  ;-----------------------------------------------------------------------
  ;                      1            2-11
  ;Requesting User Info: 08-UsedBalls[0-10]
  :8
  game.mp.sellect.ball
  .enable #Select_Ball
  var %balls = $calc($bvar(&packet,0) - 1)
  var %curr = 2
  unset %game.mp.cl.used.balls
  while (%balls >= %curr) {
    drawpic -cn @selectball_mp $calc($calc($bvar(&packet,%curr) - 20) * 30) 1 $game.mp.obj.id.rep(0) 
    inc %curr
  }
  drawpic @selectball_mp
  goto reread

  ;-----------------------------------------------------------------------
  ;             1     2-901
  ;9: Message: 09-msg[1-900]
  :9
  echo -s $bvar(&packet,2,$bvar(&packet,0)).text
  goto reread

  ;-----------------------------------------------------------------------
  ;           1  2-?
  ;10: PING: 10-ctime
  :10
  bset -t &ping 1 $bvar(&packet,1,$bvar(&packet,0)).text $+ $lf
  sockwrite $sockname &ping
  goto reread

  ;-----------------------------------------------------------------------
  ;           1   2
  ;11: BEEP: 11-times
  :11
  beep $bvar(&packet,2)
  goto reread

  ;-----------------------------------------------------------------------
  ;                1  2  3
  ;12 Play Sound: 12-sid[2]
  12:
  splay " $+ $scriptdirsounds\ $+  $+ .wav"
  goto reread

  ;#
  ;-----------------------------------------------------------------------------
  ;# 

  goto reread  
}