# Contributor: kasa <biuta.jr@gmail.com>

pkgname=networkmanager-git
pkgver=20101215
pkgrel=1
pkgdesc="Network Management daemon"
arch=('i686' 'x86_64')
license=('GPL')
url="http://www.gnome.org/projects/NetworkManager/"
depends=('wireless_tools' 'iproute' 'hal>=0.5.12git20090421.4fc367' 'libnl>=1.1' 'ppp' 'dhcpcd>=4.0' 'wpa_supplicant>=0.6.9' 'iptables' 'nss>=3.12.3')
makedepends=('pkgconfig' 'intltool' 'git' 'gtk-doc')
options=('!libtool' '!makeflags')
backup=('etc/NetworkManager/nm-system-settings.conf')
replaces=('networkmanager')
provides=("networkmanager-git=${pkgver}")
conflicts=('networkmanager')
source=(nm-system-settings.conf)
md5sums=('1653159d6634fb62d3a5c548b7a56151')

_gitroot="git://anongit.freedesktop.org/NetworkManager/NetworkManager.git"
_gitname="NetworkManager"

build() {
  cd ${srcdir}

  msg "Connecting to git.freedesktop.org GIT server...."

  if [ -d ${srcdir}/$_gitname ] ; then
    cd $_gitname && git pull origin
    msg "The local files are updated."
  else
    git clone $_gitroot
  fi

  msg "GIT checkout done or server timeout"
  msg "Starting make..."

  cp -r ${srcdir}/$_gitname ${srcdir}/$_gitname-build
  cd ${srcdir}/$_gitname-build
  sed -e 's/"\/sbin\/iptables/"\/usr\/sbin\/iptables/g' -i src/nm-activation-request.c || return 1
  ./autogen.sh --prefix=/usr --sysconfdir=/etc \
      --with-distro=arch --localstatedir=/var \
      --libexecdir=/usr/lib/networkmanager \
      --disable-static --with-dhcp-client=dhcpcd \
      --with-crypto=nss || return 1
  
  make || return 1
  make DESTDIR="${pkgdir}" install || return 1
  install -m644 "${srcdir}/nm-system-settings.conf" "${pkgdir}/etc/NetworkManager/" || return 1

  rm -rf ${srcdir}/$_gitname-build
}