rendered paste body@echo off
mkdir files
if exist sample.flac codecs\flac sample.flac -d sample.wav
if exist sample.wav goto BEGIN
goto END
:BEGIN
set file=sample.wav
CLS
ECHO.
ECHO 1. FLAC
ECHO 2. Wavpack
ECHO 3. LAME (MP3)
ECHO 4. Musepack
ECHO 5. Vorbis
ECHO 6. Nero (AAC)
ECHO 7. WMA
ECHO 8. All
ECHO 9. Exit
ECHO.
set choice=
set /p choice=Type the number choose the encoder:
if not '%choice%'=='' set choice=%choice:~0,1%
if '%choice%'=='1' goto FLAC
if '%choice%'=='2' goto WV
if '%choice%'=='3' goto LAME
if '%choice%'=='4' goto MPC
if '%choice%'=='5' goto OGG
if '%choice%'=='6' goto NERO
if '%choice%'=='7' goto WMA
if '%choice%'=='8' goto FLAC
if '%choice%'=='9' goto END
ECHO "%choice%" is not valid please try again
ECHO.
goto BEGIN
:FLAC
codecs\flac %file% -5 -o files/flac_5.flac
codecs\flac %file% -8 -o files/flac_8.flac
if '%choice%'=='8' goto WV
GOTO BEGIN
:WV
codecs\wavpack -fx3 %file% files/wv_fastx3.wv
codecs\wavpack -x4 %file% files/wv_normx4.wv
if '%choice%'=='8' goto LAME
GOTO BEGIN
:LAME
codecs\lame -V 7 --vbr-new %file% files/lame_096.mp3
codecs\lame -V 5 --vbr-new %file% files/lame_128.mp3
codecs\lame -V 2 --vbr-new %file% files/lame_192.mp3
codecs\lame -V 0 --vbr-new %file% files/lame_256.mp3
codecs\lame -b 320 %file% files/lame_320.mp3
if '%choice%'=='8' goto MPC
GOTO BEGIN
:MPC
codecs\mppenc --thumb %file% files/mpc_096.mpc
codecs\mppenc --radio %file% files/mpc_128.mpc
codecs\mppenc --standard %file% files/mpc_170.mpc
codecs\mppenc --xtreme %file% files/mpc_224.mpc
codecs\mppenc --insane %file% files/mpc_300.mpc
codecs\mppenc --braindead %file% files/mpc_350.mpc
if '%choice%'=='8' goto OGG
GOTO BEGIN
:OGG
codecs\oggenc2 -q 2 %file% -o files/vorbis_096.ogg
codecs\oggenc2 -q 4 %file% -o files/vorbis_128.ogg
codecs\oggenc2 -q 6 %file% -o files/vorbis_192.ogg
codecs\oggenc2 -q 8 %file% -o files/vorbis_256.ogg
codecs\oggenc2 -q 9 %file% -o files/vorbis_350.ogg
codecs\oggenc2 -q 10 %file% -o files/vorbis_500.ogg
if '%choice%'=='8' goto NERO
GOTO BEGIN
:NERO
codecs\neroaacenc -q 0.34 -if %file% -of files/nero_096.m4a
codecs\neroaacenc -q 0.4 -if %file% -of files/nero_128.m4a
codecs\neroaacenc -q 0.53 -if %file% -of files/nero_192.m4a
codecs\neroaacenc -q 0.66 -if %file% -of files/nero_256.m4a
codecs\neroaacenc -q 0.79 -if %file% -of files/nero_320.m4a
codecs\neroaacenc -q 1.00 -if %file% -of files/nero_400.m4a
if '%choice%'=='8' goto WMA
GOTO BEGIN
:WMA
cscript.exe codecs/WMCmd.vbs -a_settings 96_44_2 -input %file% -output files/wma_96.wma
cscript.exe codecs/WMCmd.vbs -a_settings 128_44_2 -input %file% -output files/wma_128.wma
cscript.exe codecs/WMCmd.vbs -a_settings 192_44_2 -input %file% -output files/wma_192.wma
cscript.exe codecs/WMCmd.vbs -a_settings 256_44_2 -input %file% -output files/wma_256.wma
cscript.exe codecs/WMCmd.vbs -a_settings 320_44_2 -input %file% -output files/wma_320.wma
GOTO BEGIN
:END
ECHO.
ECHO You have either exited the program, or no input file could be found.
ECHO There must be a sample.flac or sample.wav in the 'codec_pack' dir.
ECHO You can now close the window.